cd5a05a426a63cc1a4873b5f632e67e577f0e3ce
[urcu.git] / configure.ac
1 AC_PREREQ(2.59)
2 AC_INIT([userspace-rcu],[0.9.0],[mathieu dot desnoyers at efficios dot com], [], [http://liburcu.org/])
3
4 # Following the numbering scheme proposed by libtool for the library version
5 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
6 AC_SUBST([URCU_LIBRARY_VERSION], [5:0:1])
7
8 AC_CONFIG_HEADERS([include/config.h include/urcu/config.h])
9 AC_CONFIG_AUX_DIR([config])
10 AC_CONFIG_MACRO_DIR([m4])
11
12 AC_CANONICAL_TARGET
13 AC_CANONICAL_HOST
14
15 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip nostdinc])
16 AM_MAINTAINER_MODE([enable])
17
18 # Enable silent rules if available (Introduced in AM 1.11)
19 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
20
21 AH_TEMPLATE([CONFIG_RCU_SMP], [Enable SMP support. With SMP support enabled, uniprocessors are also supported. With SMP support disabled, UP systems work fine, but the behavior of SMP systems is undefined.])
22 AH_TEMPLATE([CONFIG_RCU_HAVE_FENCE], [Defined when on a system that has memory fence instructions.])
23 AH_TEMPLATE([CONFIG_RCU_HAVE_FUTEX], [Defined when on a system with futex support.])
24 AH_TEMPLATE([CONFIG_RCU_COMPAT_ARCH], [Compatibility mode for i386 which lacks cmpxchg instruction.])
25 AH_TEMPLATE([CONFIG_RCU_ARM_HAVE_DMB], [Use the dmb instruction if available for use on ARM.])
26 AH_TEMPLATE([CONFIG_RCU_TLS], [TLS provided by the compiler.])
27 AH_TEMPLATE([CONFIG_RCU_HAVE_CLOCK_GETTIME], [clock_gettime() is detected.])
28
29 # Allow overriding storage used for TLS variables.
30 AC_ARG_ENABLE([compiler-tls],
31 AS_HELP_STRING([--disable-compiler-tls], [Use pthread_getspecific() to emulate Thread Local Storage (TLS) variables.]),
32 [def_compiler_tls=$enableval],
33 [def_compiler_tls="yes"])
34
35 # If not overridden, use ax_tls.m4 to check if TLS is available.
36 AS_IF([test "x$def_compiler_tls" = "xyes"],
37 [AX_TLS([def_tls_detect=$ac_cv_tls], [:])],
38 [:])
39
40 AS_IF([test "x$def_tls_detect" = "x"],
41 [:],
42 [AC_DEFINE_UNQUOTED([CONFIG_RCU_TLS], $def_tls_detect)])
43
44 # Checks for C compiler
45 AC_USE_SYSTEM_EXTENSIONS
46 AC_PROG_CC
47 AC_PROG_CC_STDC
48
49 # Checks for programs.
50 AC_PROG_AWK
51 AC_PROG_MAKE_SET
52 AC_CHECK_PROGS(NPROC, [nproc gnproc])
53 AC_CHECK_PROGS(GETCONF, [getconf])
54 AS_IF([test "x$NPROC" != "x"],
55 [NPROC_CMD=$NPROC],
56 [AS_IF([test "x$GETCONF" != "x"],
57 [NPROC_CMD="$GETCONF _NPROCESSORS_ONLN"],
58 [NPROC_CMD="echo 1"]
59 )]
60 )
61 AC_SUBST([NPROC_CMD], [$NPROC_CMD])
62
63 LT_INIT
64
65 # Checks for typedefs, structures, and compiler characteristics.
66 AC_C_INLINE
67 AC_TYPE_PID_T
68 AC_TYPE_SIZE_T
69 AC_TYPE_SSIZE_T
70 AC_TYPE_UINT16_T
71 AC_TYPE_INT32_T
72 AC_TYPE_UINT32_T
73 AC_TYPE_UINT64_T
74 AC_TYPE_UINT8_T
75
76 AX_C___ATTRIBUTE__
77 AS_IF([test "x$ax_cv___attribute__" = "xyes"],
78 [:],
79 [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])
80
81 AX_PTHREAD(,[AC_MSG_ERROR([Could not configure pthreads support])])
82 LIBS="$PTHREAD_LIBS $LIBS"
83 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
84 CC="$PTHREAD_CC"
85
86 # Checks for library functions.
87 AC_FUNC_MMAP
88 AC_FUNC_FORK
89 AC_CHECK_FUNCS([ \
90 atexit \
91 getcpuid \
92 gettid \
93 gettimeofday \
94 memeset \
95 memset \
96 munmap \
97 rand_r \
98 sched_getcpu \
99 strerror \
100 strtoul \
101 sysconf \
102 ])
103
104 # AC_FUNC_MALLOC causes problems when cross-compiling.
105 #AC_FUNC_MALLOC
106
107 # Check for headers
108 AC_HEADER_STDBOOL
109 AC_CHECK_HEADERS([ \
110 limits.h \
111 stddef.h \
112 sys/param.h \
113 sys/time.h \
114 ])
115
116 # Find arch type
117 AS_CASE([$host_cpu],
118 [k1om], [ARCHTYPE="x86"],
119 [i386], [ARCHTYPE="x86" && SUBARCHTYPE="x86compat"],
120 [i486], [ARCHTYPE="x86"],
121 [i586], [ARCHTYPE="x86"],
122 [i686], [ARCHTYPE="x86"],
123 [amd64], [ARCHTYPE="x86"],
124 [x86_64], [ARCHTYPE="x86"],
125 [powerpc], [ARCHTYPE="ppc"],
126 [ppc64], [ARCHTYPE="ppc"],
127 [powerpc64], [ARCHTYPE="ppc"],
128 [powerpc64le], [ARCHTYPE="ppc"],
129 [ppc], [ARCHTYPE="ppc"],
130 [s390], [ARCHTYPE="s390"],
131 [s390x], [ARCHTYPE="s390"],
132 [sparc], [ARCHTYPE="sparc64"],
133 [sparc64], [ARCHTYPE="sparc64"],
134 [alpha*], [ARCHTYPE="alpha"],
135 [ia64], [ARCHTYPE="ia64"],
136 [arm*], [ARCHTYPE="arm"],
137 [aarch64*], [ARCHTYPE="aarch64"],
138 [mips*], [ARCHTYPE="mips"],
139 [nios2*], [ARCHTYPE="nios2"],
140 [tile*], [ARCHTYPE="tile"],
141 [hppa*], [ARCHTYPE="hppa"],
142 [ARCHTYPE="unknown"]
143 )
144
145 AS_CASE([$host],[*-cygwin*],
146 [AM_CONDITIONAL(USE_CYGWIN, true)],
147 [AM_CONDITIONAL(USE_CYGWIN, false)]
148 )
149
150 AC_SUBST(ARCHTYPE)
151 AC_SUBST(SUBARCHTYPE)
152
153 UATOMICSRC=include/urcu/uatomic/$ARCHTYPE.h
154 ARCHSRC=include/urcu/arch/$ARCHTYPE.h
155
156 AS_IF([test "x$SUBARCHTYPE" = xx86compat],[
157 AC_DEFINE([CONFIG_RCU_COMPAT_ARCH], [1])
158 ])
159
160 AS_IF([test "$host_cpu" = "armv7l"],[
161 CFLAGS="$CFLAGS -mcpu=cortex-a9 -mtune=cortex-a9 -O1"
162 ])
163
164 # ARM-specific checks
165 AS_IF([test "x$ARCHTYPE" = "xarm"],[
166 AC_MSG_CHECKING([for dmb instruction])
167 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
168 int main()
169 {
170 asm volatile("dmb":::"memory");
171 return 0;
172 }
173 ]])
174 ],[
175 AC_MSG_RESULT([yes])
176 AC_DEFINE([CONFIG_RCU_ARM_HAVE_DMB], [1])
177 ],[
178 AC_MSG_RESULT([no])
179 ])
180 ])
181
182 # Tile-specific checks
183 AS_IF([echo "$host_cpu" | grep "^tile"],[
184 AC_MSG_CHECKING([for Tile architecture type])
185 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
186 #ifndef __tilegx__
187 #error
188 #endif
189 ]])
190 ],[
191 AC_MSG_RESULT([ok])
192 ],[
193 AC_MSG_FAILURE([URCU has only been tested on the TileGx architecture. For other Tile* architectures, please run the tests first and report the results to the maintainer so that proper support can be added.])
194 ])
195 ])
196
197 # x86-specific checks
198 AS_IF([test "x$ARCHTYPE" = "xx86"],[
199 AC_MSG_CHECKING([if architecture really supports the mfence instruction])
200 #For now, using lock; addl compatibility mode even for i686, because the
201 #Pentium III is seen as a i686, but lacks mfence instruction.
202 #Only using fence for x86_64.
203 #
204 #k1om is the name for the Intel MIC family (Xeon Phi). It is an x86_64
205 #variant but lacks fence instructions.
206 AS_IF([test "x$host_cpu" != "xi386" -a "x$host_cpu" != "xi486" -a "x$host_cpu" != "xi586" -a "x$host_cpu" != "xi686" -a "x$host_vendor" != "xk1om" -a "x$host_cpu" != "xk1om"],[
207 AC_MSG_RESULT([yes])
208 AC_DEFINE([CONFIG_RCU_HAVE_FENCE], [1])
209 ],[
210 AC_MSG_RESULT([no])
211 ])
212 ])
213
214 # Check if sys_futex() is available
215 AC_MSG_CHECKING([for sys_futex()])
216 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
217 #include <sys/syscall.h>
218 #ifndef __NR_futex
219 #error "futexes not available"
220 #endif
221 ]])
222 ],[
223 AC_MSG_RESULT([yes])
224 AC_DEFINE([CONFIG_RCU_HAVE_FUTEX], [1])
225 compat_futex_test=0
226 ],[
227 AC_MSG_RESULT([no])
228 compat_futex_test=1
229 ])
230
231 # Search for clock_gettime
232 AC_SEARCH_LIBS([clock_gettime], [rt], [
233 AC_DEFINE([CONFIG_RCU_HAVE_CLOCK_GETTIME], [1])
234 ], [])
235
236 AM_CONDITIONAL([COMPAT_FUTEX], [test "x$compat_futex_test" = "x1"])
237 AM_CONDITIONAL([COMPAT_ARCH], [test "x$SUBARCHTYPE" = "xx86compat"])
238 AM_CONDITIONAL([NO_SHARED], [test "x$enable_shared" = "xno"])
239
240 # smp-support configure option
241 AC_ARG_ENABLE([smp-support],
242 AS_HELP_STRING([--disable-smp-support], [Disable SMP support. Warning: only use this on uniprocessor systems. [default=enabled]]),
243 [def_smp_support=$enableval],
244 [def_smp_support="yes"])
245 AS_IF([test "x$def_smp_support" = "xyes"], [AC_DEFINE([CONFIG_RCU_SMP], [1])])
246
247
248 # From the sched_setaffinity(2)'s man page:
249 # ~~~~
250 # The CPU affinity system calls were introduced in Linux kernel 2.5.8.
251 # The library interfaces were introduced in glibc 2.3. Initially, the
252 # glibc interfaces included a cpusetsize argument. In glibc 2.3.3,
253 # the cpuset size argument was removed, but this argument was
254 # restored in glibc 2.3.4.
255 # ~~~~
256
257 # In addition to that, some vendors ported the system call to 2.4
258 # kernels.
259
260 # Furthermore, when the function first appeared, the MASK argument was
261 # an unsigned long pointer, while later it was made into a cpu_set_t
262 # pointer. Systems that have the cpu_set_t version also should have
263 # the CPU_ZERO, CPU_SET, etc. macros.
264
265 # All this mess means we have to cater for at least 3 different
266 # sched_setaffinity prototypes:
267
268 # ~~~~
269 # int sched_setaffinity (pid_t pid, unsigned int len, unsigned long *mask);
270 # int sched_setaffinity (pid_t __pid, size_t __cpusetsize, const cpu_set_t *__cpuset);
271 # int sched_setaffinity (pid_t __pid, const cpu_set_t *__mask);
272 # ~~~~
273
274 AC_CHECK_TYPES([cpu_set_t],
275 [have_cpu_set_t="yes"],
276 [have_cpu_set_t="no"],
277 [#include <sched.h>])
278
279 # Confirm that we have CPU_ZERO, and it actually works.
280 AC_MSG_CHECKING([whether CPU_ZERO works])
281 AH_TEMPLATE([HAVE_CPU_ZERO], [Defined to 1 if we have CPU_ZERO and it works])
282 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
283 #include <sched.h>
284 int main()
285 {
286 cpu_set_t foo; CPU_ZERO(&foo);
287 return 0;
288 }
289 ]])
290 ],[
291 AC_DEFINE(HAVE_CPU_ZERO, 1)
292 AC_MSG_RESULT([yes])
293 ],[
294 AC_MSG_RESULT([no])
295 ])
296
297 # Confirm that we have CPU_SET, and it actually works.
298 AC_MSG_CHECKING([whether CPU_SET works])
299 AH_TEMPLATE([HAVE_CPU_SET], [Defined to 1 if we have CPU_SET and it works])
300 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
301 #include <sched.h>
302 int main()
303 {
304 cpu_set_t foo, mask; CPU_SET(0, &foo);
305 return 0;
306 }
307 ]])
308 ],[
309 AC_DEFINE(HAVE_CPU_SET, 1)
310 AC_MSG_RESULT([yes])
311 ],[
312 AC_MSG_RESULT([no])
313 ])
314
315 # First check if the function is available at all.
316 AC_CHECK_FUNCS([sched_setaffinity],[
317 # Okay, we have it. Check if also have cpu_set_t. If we don't,
318 # then we have the first version using unsigned long, and no
319 # CPU_ZERO, etc. macros. If we do have cpu_set_t, we may have the
320 # version with 2 or 3 arguments. In that case, CPU_ZERO, etc.,
321 # should also be present, but we confirm nonetheless.
322
323 AS_IF([test "x$have_cpu_set_t" = "xyes"], [
324 # We do have it.
325 # Check how many arguments does sched_setaffinity take.
326 # Should be 3 or 2.
327 AC_MSG_CHECKING([how many arguments sched_setaffinity takes])
328 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
329 #include <sched.h>
330 int main()
331 {
332 cpu_set_t foo;
333 sched_setaffinity(0, sizeof (foo), &foo);
334 return 0;
335 }
336 ]])
337 ],
338 [sched_set_affinity_args=3],
339 [sched_set_affinity_args=2])
340 AC_DEFINE_UNQUOTED(SCHED_SETAFFINITY_ARGS,
341 $sched_set_affinity_args,
342 [Defined to sched_setaffinity's number of arguments.])
343 AC_MSG_RESULT([$sched_set_affinity_args])
344 ],[
345 # No cpu_set_t, always 3 args.
346 AC_DEFINE(SCHED_SETAFFINITY_ARGS, 3)
347 ])
348 ])
349
350 DEFAULT_INCLUDES="-include config.h"
351 AC_SUBST(DEFAULT_INCLUDES)
352
353 AC_CONFIG_LINKS([
354 include/urcu/arch.h:$ARCHSRC
355 include/urcu/uatomic.h:$UATOMICSRC
356 ])
357 AC_CONFIG_FILES([
358 Makefile
359 doc/Makefile
360 doc/examples/Makefile
361 include/Makefile
362 src/Makefile
363 tests/Makefile
364 tests/common/Makefile
365 tests/unit/Makefile
366 tests/benchmark/Makefile
367 tests/regression/Makefile
368 tests/regression/regression_tests
369 tests/utils/Makefile
370 src/liburcu.pc
371 src/liburcu-bp.pc
372 src/liburcu-cds.pc
373 src/liburcu-qsbr.pc
374 src/liburcu-mb.pc
375 src/liburcu-signal.pc
376 ])
377 AC_OUTPUT
378
379 # Report on selected configure options
380 AS_IF([test "x$def_smp_support" = "xyes"],[
381 AS_ECHO("SMP support enabled.")
382 ],[
383 AS_ECHO("SMP support disabled.")
384 ])
385
386 AS_IF([test "x$def_tls_detect" = "x"],[
387 AS_ECHO("Thread Local Storage (TLS): pthread_getspecific().")
388 ],[
389 AS_ECHO("Thread Local Storage (TLS): $def_tls_detect.")
390 ])
This page took 0.053366 seconds and 3 git commands to generate.