Allow forcing the use of sys membarrier
[urcu.git] / configure.ac
1 AC_PREREQ(2.59)
2 AC_INIT([userspace-rcu],[0.10.0-pre],[mathieu dot desnoyers at efficios dot com], [], [http://liburcu.org/])
3
4 # Following the numbering scheme proposed by libtool for the library version
5 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
6 AC_SUBST([URCU_LIBRARY_VERSION], [5:0:1])
7
8 AC_CONFIG_HEADERS([include/config.h include/urcu/config.h])
9 AC_CONFIG_AUX_DIR([config])
10 AC_CONFIG_MACRO_DIR([m4])
11
12 AC_CANONICAL_TARGET
13 AC_CANONICAL_HOST
14
15 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip nostdinc])
16 AM_MAINTAINER_MODE([enable])
17
18 # Enable silent rules if available (Introduced in AM 1.11)
19 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
20
21 AH_TEMPLATE([CONFIG_RCU_SMP], [Enable SMP support. With SMP support enabled, uniprocessors are also supported. With SMP support disabled, UP systems work fine, but the behavior of SMP systems is undefined.])
22 AH_TEMPLATE([CONFIG_RCU_HAVE_FENCE], [Defined when on a system that has memory fence instructions.])
23 AH_TEMPLATE([CONFIG_RCU_HAVE_FUTEX], [Defined when on a system with futex support.])
24 AH_TEMPLATE([CONFIG_RCU_COMPAT_ARCH], [Compatibility mode for i386 which lacks cmpxchg instruction.])
25 AH_TEMPLATE([CONFIG_RCU_ARM_HAVE_DMB], [Use the dmb instruction if available for use on ARM.])
26 AH_TEMPLATE([CONFIG_RCU_TLS], [TLS provided by the compiler.])
27 AH_TEMPLATE([CONFIG_RCU_HAVE_CLOCK_GETTIME], [clock_gettime() is detected.])
28 AH_TEMPLATE([CONFIG_RCU_FORCE_SYS_MEMBARRIER], [Require the operating system to support the membarrier system call for default and bulletproof flavors.])
29
30 # Allow requiring the operating system to support the membarrier system
31 # call. Applies to default and bulletproof flavors.
32 AC_ARG_ENABLE([sys-membarrier-fallback],
33 AS_HELP_STRING([--disable-sys-membarrier-fallback], [Abort if sys-membarrier is needed but not available rather than using a fallback.]),
34 [def_sys_membarrier_fallback=$enableval],
35 [def_sys_membarrier_fallback="yes"])
36 AS_IF([test "x$def_sys_membarrier_fallback" != "xyes"], [AC_DEFINE([CONFIG_RCU_FORCE_SYS_MEMBARRIER], [1])])
37
38 # Allow overriding storage used for TLS variables.
39 AC_ARG_ENABLE([compiler-tls],
40 AS_HELP_STRING([--disable-compiler-tls], [Use pthread_getspecific() to emulate Thread Local Storage (TLS) variables.]),
41 [def_compiler_tls=$enableval],
42 [def_compiler_tls="yes"])
43
44 # If not overridden, use ax_tls.m4 to check if TLS is available.
45 AS_IF([test "x$def_compiler_tls" = "xyes"],
46 [AX_TLS([def_tls_detect=$ac_cv_tls], [:])],
47 [:])
48
49 AS_IF([test "x$def_tls_detect" = "x"],
50 [:],
51 [AC_DEFINE_UNQUOTED([CONFIG_RCU_TLS], $def_tls_detect)])
52
53 # Checks for C compiler
54 AC_USE_SYSTEM_EXTENSIONS
55 AC_PROG_CC
56 AC_PROG_CC_STDC
57
58 # Checks for programs.
59 AC_PROG_AWK
60 AC_PROG_MAKE_SET
61 AC_CHECK_PROGS(NPROC, [nproc gnproc])
62 AC_CHECK_PROGS(GETCONF, [getconf])
63 AS_IF([test "x$NPROC" != "x"],
64 [NPROC_CMD=$NPROC],
65 [AS_IF([test "x$GETCONF" != "x"],
66 [NPROC_CMD="$GETCONF _NPROCESSORS_ONLN"],
67 [NPROC_CMD="echo 1"]
68 )]
69 )
70 AC_SUBST([NPROC_CMD], [$NPROC_CMD])
71
72 LT_INIT
73
74 # Checks for typedefs, structures, and compiler characteristics.
75 AC_C_INLINE
76 AC_TYPE_PID_T
77 AC_TYPE_SIZE_T
78 AC_TYPE_SSIZE_T
79 AC_TYPE_UINT16_T
80 AC_TYPE_INT32_T
81 AC_TYPE_UINT32_T
82 AC_TYPE_UINT64_T
83 AC_TYPE_UINT8_T
84
85 AX_C___ATTRIBUTE__
86 AS_IF([test "x$ax_cv___attribute__" = "xyes"],
87 [:],
88 [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])
89
90 AX_PTHREAD(,[AC_MSG_ERROR([Could not configure pthreads support])])
91 LIBS="$PTHREAD_LIBS $LIBS"
92 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
93 CC="$PTHREAD_CC"
94
95 # Checks for library functions.
96 AC_FUNC_MMAP
97 AC_FUNC_FORK
98 AC_CHECK_FUNCS([ \
99 atexit \
100 getcpuid \
101 gettid \
102 gettimeofday \
103 memeset \
104 memset \
105 munmap \
106 rand_r \
107 sched_getcpu \
108 strerror \
109 strtoul \
110 sysconf \
111 ])
112
113 # AC_FUNC_MALLOC causes problems when cross-compiling.
114 #AC_FUNC_MALLOC
115
116 # Check for headers
117 AC_HEADER_STDBOOL
118 AC_CHECK_HEADERS([ \
119 limits.h \
120 stddef.h \
121 sys/param.h \
122 sys/time.h \
123 ])
124
125 # Find arch type
126 AS_CASE([$host_cpu],
127 [k1om], [ARCHTYPE="x86"],
128 [i386], [ARCHTYPE="x86" && SUBARCHTYPE="x86compat"],
129 [i486], [ARCHTYPE="x86"],
130 [i586], [ARCHTYPE="x86"],
131 [i686], [ARCHTYPE="x86"],
132 [amd64], [ARCHTYPE="x86"],
133 [x86_64], [ARCHTYPE="x86"],
134 [powerpc], [ARCHTYPE="ppc"],
135 [ppc64], [ARCHTYPE="ppc"],
136 [powerpc64], [ARCHTYPE="ppc"],
137 [powerpc64le], [ARCHTYPE="ppc"],
138 [ppc], [ARCHTYPE="ppc"],
139 [s390], [ARCHTYPE="s390"],
140 [s390x], [ARCHTYPE="s390"],
141 [sparc], [ARCHTYPE="sparc64"],
142 [sparc64], [ARCHTYPE="sparc64"],
143 [alpha*], [ARCHTYPE="alpha"],
144 [ia64], [ARCHTYPE="ia64"],
145 [arm*], [ARCHTYPE="arm"],
146 [aarch64*], [ARCHTYPE="aarch64"],
147 [mips*], [ARCHTYPE="mips"],
148 [nios2*], [ARCHTYPE="nios2"],
149 [tile*], [ARCHTYPE="tile"],
150 [hppa*], [ARCHTYPE="hppa"],
151 [ARCHTYPE="unknown"]
152 )
153
154 AS_CASE([$host],[*-cygwin*],
155 [AM_CONDITIONAL(USE_CYGWIN, true)],
156 [AM_CONDITIONAL(USE_CYGWIN, false)]
157 )
158
159 AC_SUBST(ARCHTYPE)
160 AC_SUBST(SUBARCHTYPE)
161
162 UATOMICSRC=include/urcu/uatomic/$ARCHTYPE.h
163 ARCHSRC=include/urcu/arch/$ARCHTYPE.h
164
165 AS_IF([test "x$SUBARCHTYPE" = xx86compat],[
166 AC_DEFINE([CONFIG_RCU_COMPAT_ARCH], [1])
167 ])
168
169 AS_IF([test "$host_cpu" = "armv7l"],[
170 CFLAGS="$CFLAGS -mcpu=cortex-a9 -mtune=cortex-a9 -O1"
171 ])
172
173 # ARM-specific checks
174 AS_IF([test "x$ARCHTYPE" = "xarm"],[
175 AC_MSG_CHECKING([for dmb instruction])
176 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
177 int main()
178 {
179 asm volatile("dmb":::"memory");
180 return 0;
181 }
182 ]])
183 ],[
184 AC_MSG_RESULT([yes])
185 AC_DEFINE([CONFIG_RCU_ARM_HAVE_DMB], [1])
186 ],[
187 AC_MSG_RESULT([no])
188 ])
189 ])
190
191 # Tile-specific checks
192 AS_IF([echo "$host_cpu" | grep "^tile"],[
193 AC_MSG_CHECKING([for Tile architecture type])
194 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
195 #ifndef __tilegx__
196 #error
197 #endif
198 ]])
199 ],[
200 AC_MSG_RESULT([ok])
201 ],[
202 AC_MSG_FAILURE([URCU has only been tested on the TileGx architecture. For other Tile* architectures, please run the tests first and report the results to the maintainer so that proper support can be added.])
203 ])
204 ])
205
206 # x86-specific checks
207 AS_IF([test "x$ARCHTYPE" = "xx86"],[
208 AC_MSG_CHECKING([if architecture really supports the mfence instruction])
209 #For now, using lock; addl compatibility mode even for i686, because the
210 #Pentium III is seen as a i686, but lacks mfence instruction.
211 #Only using fence for x86_64.
212 #
213 #k1om is the name for the Intel MIC family (Xeon Phi). It is an x86_64
214 #variant but lacks fence instructions.
215 AS_IF([test "x$host_cpu" != "xi386" -a "x$host_cpu" != "xi486" -a "x$host_cpu" != "xi586" -a "x$host_cpu" != "xi686" -a "x$host_vendor" != "xk1om" -a "x$host_cpu" != "xk1om"],[
216 AC_MSG_RESULT([yes])
217 AC_DEFINE([CONFIG_RCU_HAVE_FENCE], [1])
218 ],[
219 AC_MSG_RESULT([no])
220 ])
221 ])
222
223 # Check if sys_futex() is available
224 AC_MSG_CHECKING([for sys_futex()])
225 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
226 #include <sys/syscall.h>
227 #ifndef __NR_futex
228 #error "futexes not available"
229 #endif
230 ]])
231 ],[
232 AC_MSG_RESULT([yes])
233 AC_DEFINE([CONFIG_RCU_HAVE_FUTEX], [1])
234 compat_futex_test=0
235 ],[
236 AC_MSG_RESULT([no])
237 compat_futex_test=1
238 ])
239
240 # Search for clock_gettime
241 AC_SEARCH_LIBS([clock_gettime], [rt], [
242 AC_DEFINE([CONFIG_RCU_HAVE_CLOCK_GETTIME], [1])
243 ], [])
244
245 AM_CONDITIONAL([COMPAT_FUTEX], [test "x$compat_futex_test" = "x1"])
246 AM_CONDITIONAL([COMPAT_ARCH], [test "x$SUBARCHTYPE" = "xx86compat"])
247 AM_CONDITIONAL([NO_SHARED], [test "x$enable_shared" = "xno"])
248
249 # smp-support configure option
250 AC_ARG_ENABLE([smp-support],
251 AS_HELP_STRING([--disable-smp-support], [Disable SMP support. Warning: only use this on uniprocessor systems. [default=enabled]]),
252 [def_smp_support=$enableval],
253 [def_smp_support="yes"])
254 AS_IF([test "x$def_smp_support" = "xyes"], [AC_DEFINE([CONFIG_RCU_SMP], [1])])
255
256
257 # From the sched_setaffinity(2)'s man page:
258 # ~~~~
259 # The CPU affinity system calls were introduced in Linux kernel 2.5.8.
260 # The library interfaces were introduced in glibc 2.3. Initially, the
261 # glibc interfaces included a cpusetsize argument. In glibc 2.3.3,
262 # the cpuset size argument was removed, but this argument was
263 # restored in glibc 2.3.4.
264 # ~~~~
265
266 # In addition to that, some vendors ported the system call to 2.4
267 # kernels.
268
269 # Furthermore, when the function first appeared, the MASK argument was
270 # an unsigned long pointer, while later it was made into a cpu_set_t
271 # pointer. Systems that have the cpu_set_t version also should have
272 # the CPU_ZERO, CPU_SET, etc. macros.
273
274 # All this mess means we have to cater for at least 3 different
275 # sched_setaffinity prototypes:
276
277 # ~~~~
278 # int sched_setaffinity (pid_t pid, unsigned int len, unsigned long *mask);
279 # int sched_setaffinity (pid_t __pid, size_t __cpusetsize, const cpu_set_t *__cpuset);
280 # int sched_setaffinity (pid_t __pid, const cpu_set_t *__mask);
281 # ~~~~
282
283 AC_CHECK_TYPES([cpu_set_t],
284 [have_cpu_set_t="yes"],
285 [have_cpu_set_t="no"],
286 [#include <sched.h>])
287
288 # Confirm that we have CPU_ZERO, and it actually works.
289 AC_MSG_CHECKING([whether CPU_ZERO works])
290 AH_TEMPLATE([HAVE_CPU_ZERO], [Defined to 1 if we have CPU_ZERO and it works])
291 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
292 #include <sched.h>
293 int main()
294 {
295 cpu_set_t foo; CPU_ZERO(&foo);
296 return 0;
297 }
298 ]])
299 ],[
300 AC_DEFINE(HAVE_CPU_ZERO, 1)
301 AC_MSG_RESULT([yes])
302 ],[
303 AC_MSG_RESULT([no])
304 ])
305
306 # Confirm that we have CPU_SET, and it actually works.
307 AC_MSG_CHECKING([whether CPU_SET works])
308 AH_TEMPLATE([HAVE_CPU_SET], [Defined to 1 if we have CPU_SET and it works])
309 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
310 #include <sched.h>
311 int main()
312 {
313 cpu_set_t foo, mask; CPU_SET(0, &foo);
314 return 0;
315 }
316 ]])
317 ],[
318 AC_DEFINE(HAVE_CPU_SET, 1)
319 AC_MSG_RESULT([yes])
320 ],[
321 AC_MSG_RESULT([no])
322 ])
323
324 # First check if the function is available at all.
325 AC_CHECK_FUNCS([sched_setaffinity],[
326 # Okay, we have it. Check if also have cpu_set_t. If we don't,
327 # then we have the first version using unsigned long, and no
328 # CPU_ZERO, etc. macros. If we do have cpu_set_t, we may have the
329 # version with 2 or 3 arguments. In that case, CPU_ZERO, etc.,
330 # should also be present, but we confirm nonetheless.
331
332 AS_IF([test "x$have_cpu_set_t" = "xyes"], [
333 # We do have it.
334 # Check how many arguments does sched_setaffinity take.
335 # Should be 3 or 2.
336 AC_MSG_CHECKING([how many arguments sched_setaffinity takes])
337 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
338 #include <sched.h>
339 int main()
340 {
341 cpu_set_t foo;
342 sched_setaffinity(0, sizeof (foo), &foo);
343 return 0;
344 }
345 ]])
346 ],
347 [sched_set_affinity_args=3],
348 [sched_set_affinity_args=2])
349 AC_DEFINE_UNQUOTED(SCHED_SETAFFINITY_ARGS,
350 $sched_set_affinity_args,
351 [Defined to sched_setaffinity's number of arguments.])
352 AC_MSG_RESULT([$sched_set_affinity_args])
353 ],[
354 # No cpu_set_t, always 3 args.
355 AC_DEFINE(SCHED_SETAFFINITY_ARGS, 3)
356 ])
357 ])
358
359 DEFAULT_INCLUDES="-include config.h"
360 AC_SUBST(DEFAULT_INCLUDES)
361
362 AC_CONFIG_LINKS([
363 include/urcu/arch.h:$ARCHSRC
364 include/urcu/uatomic.h:$UATOMICSRC
365 ])
366 AC_CONFIG_FILES([
367 Makefile
368 doc/Makefile
369 doc/examples/Makefile
370 include/Makefile
371 src/Makefile
372 tests/Makefile
373 tests/common/Makefile
374 tests/unit/Makefile
375 tests/benchmark/Makefile
376 tests/regression/Makefile
377 tests/regression/regression_tests
378 tests/utils/Makefile
379 src/liburcu.pc
380 src/liburcu-bp.pc
381 src/liburcu-cds.pc
382 src/liburcu-qsbr.pc
383 src/liburcu-mb.pc
384 src/liburcu-signal.pc
385 ])
386 AC_OUTPUT
387
388 # Report on selected configure options
389 AS_IF([test "x$def_smp_support" = "xyes"],[
390 AS_ECHO("SMP support enabled.")
391 ],[
392 AS_ECHO("SMP support disabled.")
393 ])
394
395 AS_IF([test "x$def_tls_detect" = "x"],[
396 AS_ECHO("Thread Local Storage (TLS): pthread_getspecific().")
397 ],[
398 AS_ECHO("Thread Local Storage (TLS): $def_tls_detect.")
399 ])
This page took 0.058117 seconds and 4 git commands to generate.