Update library age due to new stack/queue destroy API
[urcu.git] / configure.ac
1 AC_PREREQ(2.59)
2 AC_INIT([userspace-rcu],[0.9.0],[mathieu dot desnoyers at efficios dot com], [], [http://liburcu.org/])
3
4 # Following the numbering scheme proposed by libtool for the library version
5 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
6 AC_SUBST([URCU_LIBRARY_VERSION], [4:0:1])
7
8 AC_CONFIG_SRCDIR([urcu.h])
9 AC_CONFIG_HEADERS([config.h urcu/config.h])
10 AC_CONFIG_AUX_DIR([config])
11 AC_CONFIG_MACRO_DIR([m4])
12
13 AC_CANONICAL_TARGET
14 AC_CANONICAL_HOST
15
16 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip])
17 AM_MAINTAINER_MODE([enable])
18
19 # Enable silent rules if available (Introduced in AM 1.11)
20 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
21
22 AH_TEMPLATE([CONFIG_RCU_SMP], [Enable SMP support. With SMP support enabled, uniprocessors are also supported. With SMP support disabled, UP systems work fine, but the behavior of SMP systems is undefined.])
23 AH_TEMPLATE([CONFIG_RCU_HAVE_FENCE], [Defined when on a system that has memory fence instructions.])
24 AH_TEMPLATE([CONFIG_RCU_HAVE_FUTEX], [Defined when on a system with futex support.])
25 AH_TEMPLATE([CONFIG_RCU_COMPAT_ARCH], [Compatibility mode for i386 which lacks cmpxchg instruction.])
26 AH_TEMPLATE([CONFIG_RCU_ARM_HAVE_DMB], [Use the dmb instruction if available for use on ARM.])
27 AH_TEMPLATE([CONFIG_RCU_TLS], [TLS provided by the compiler.])
28 AH_TEMPLATE([CONFIG_RCU_HAVE_CLOCK_GETTIME], [clock_gettime() is detected.])
29
30 # Allow overriding storage used for TLS variables.
31 AC_ARG_ENABLE([compiler-tls],
32 AS_HELP_STRING([--disable-compiler-tls], [Use pthread_getspecific() to emulate Thread Local Storage (TLS) variables.]),
33 [def_compiler_tls=$enableval],
34 [def_compiler_tls="yes"])
35
36 # If not overridden, use ax_tls.m4 to check if TLS is available.
37 AS_IF([test "x$def_compiler_tls" = "xyes"],
38 [AX_TLS([def_tls_detect=$ac_cv_tls], [:])],
39 [:])
40
41 AS_IF([test "x$def_tls_detect" = "x"],
42 [:],
43 [AC_DEFINE_UNQUOTED([CONFIG_RCU_TLS], $def_tls_detect)])
44
45 # Checks for C compiler
46 AC_USE_SYSTEM_EXTENSIONS
47 AC_PROG_CC
48 AC_PROG_CC_STDC
49
50 # Checks for programs.
51 AC_PROG_AWK
52 AC_PROG_MAKE_SET
53 AC_CHECK_PROGS(NPROC, [nproc gnproc])
54 AC_CHECK_PROGS(GETCONF, [getconf])
55 AS_IF([test "x$NPROC" != "x"],
56 [NPROC_CMD=$NPROC],
57 [AS_IF([test "x$GETCONF" != "x"],
58 [NPROC_CMD="$GETCONF _NPROCESSORS_ONLN"],
59 [NPROC_CMD="echo 1"]
60 )]
61 )
62 AC_SUBST([NPROC_CMD], [$NPROC_CMD])
63
64 LT_INIT
65
66 # Checks for typedefs, structures, and compiler characteristics.
67 AC_C_INLINE
68 AC_TYPE_PID_T
69 AC_TYPE_SIZE_T
70 AC_TYPE_SSIZE_T
71 AC_TYPE_UINT16_T
72 AC_TYPE_INT32_T
73 AC_TYPE_UINT32_T
74 AC_TYPE_UINT64_T
75 AC_TYPE_UINT8_T
76
77 AX_C___ATTRIBUTE__
78 AS_IF([test "x$ax_cv___attribute__" = "xyes"],
79 [:],
80 [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])
81
82 AX_PTHREAD(,[AC_MSG_ERROR([Could not configure pthreads support])])
83 LIBS="$PTHREAD_LIBS $LIBS"
84 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
85 CC="$PTHREAD_CC"
86
87 # Checks for library functions.
88 AC_FUNC_MALLOC
89 AC_FUNC_MMAP
90 AC_FUNC_FORK
91 AC_CHECK_FUNCS([ \
92 atexit \
93 getcpuid \
94 gettid \
95 gettimeofday \
96 memeset \
97 memset \
98 munmap \
99 sched_getcpu \
100 strerror \
101 strtoul \
102 sysconf \
103 ])
104
105 # Check for headers
106 AC_HEADER_STDBOOL
107 AC_CHECK_HEADERS([ \
108 limits.h \
109 stddef.h \
110 sys/param.h \
111 sys/time.h \
112 ])
113
114 # Find arch type
115 AS_CASE([$host_cpu],
116 [k1om], [ARCHTYPE="x86"],
117 [i386], [ARCHTYPE="x86" && SUBARCHTYPE="x86compat"],
118 [i486], [ARCHTYPE="x86"],
119 [i586], [ARCHTYPE="x86"],
120 [i686], [ARCHTYPE="x86"],
121 [amd64], [ARCHTYPE="x86"],
122 [x86_64], [ARCHTYPE="x86"],
123 [powerpc], [ARCHTYPE="ppc"],
124 [ppc64], [ARCHTYPE="ppc"],
125 [powerpc64], [ARCHTYPE="ppc"],
126 [powerpc64le], [ARCHTYPE="ppc"],
127 [ppc], [ARCHTYPE="ppc"],
128 [s390], [ARCHTYPE="s390"],
129 [s390x], [ARCHTYPE="s390"],
130 [sparc], [ARCHTYPE="sparc64"],
131 [sparc64], [ARCHTYPE="sparc64"],
132 [alpha*], [ARCHTYPE="alpha"],
133 [ia64], [ARCHTYPE="ia64"],
134 [arm*], [ARCHTYPE="arm"],
135 [aarch64*], [ARCHTYPE="aarch64"],
136 [mips*], [ARCHTYPE="mips"],
137 [nios2*], [ARCHTYPE="nios2"],
138 [tile*], [ARCHTYPE="tile"],
139 [hppa*], [ARCHTYPE="hppa"],
140 [ARCHTYPE="unknown"]
141 )
142
143 AS_CASE([$host],[*-*-linux-androideabi],
144 [AM_CONDITIONAL(TARGET_IS_ANDROID, true)],
145 [AM_CONDITIONAL(TARGET_IS_ANDROID, false)]
146 )
147
148 AS_CASE([$host],[*-cygwin*],
149 [AM_CONDITIONAL(USE_CYGWIN, true)],
150 [AM_CONDITIONAL(USE_CYGWIN, false)]
151 )
152
153 AC_SUBST(ARCHTYPE)
154 AC_SUBST(SUBARCHTYPE)
155
156 UATOMICSRC=urcu/uatomic/$ARCHTYPE.h
157 ARCHSRC=urcu/arch/$ARCHTYPE.h
158
159 AS_IF([test "x$SUBARCHTYPE" = xx86compat],[
160 AC_DEFINE([CONFIG_RCU_COMPAT_ARCH], [1])
161 ])
162
163 AS_IF([test "$host_cpu" = "armv7l"],[
164 CFLAGS="$CFLAGS -mcpu=cortex-a9 -mtune=cortex-a9 -O1"
165 ])
166
167 # ARM-specific checks
168 AS_IF([test "x$ARCHTYPE" = "xarm"],[
169 AC_MSG_CHECKING([for dmb instruction])
170 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
171 int main()
172 {
173 asm volatile("dmb":::"memory");
174 return 0;
175 }
176 ]])
177 ],[
178 AC_MSG_RESULT([yes])
179 AC_DEFINE([CONFIG_RCU_ARM_HAVE_DMB], [1])
180 ],[
181 AC_MSG_RESULT([no])
182 ])
183 ])
184
185 # Tile-specific checks
186 AS_IF([echo "$host_cpu" | grep "^tile"],[
187 AC_MSG_CHECKING([for Tile architecture type])
188 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
189 #ifndef __tilegx__
190 #error
191 #endif
192 ]])
193 ],[
194 AC_MSG_RESULT([ok])
195 ],[
196 AC_MSG_FAILURE([URCU has only been tested on the TileGx architecture. For other Tile* architectures, please run the tests first and report the results to the maintainer so that proper support can be added.])
197 ])
198 ])
199
200 # x86-specific checks
201 AS_IF([test "x$ARCHTYPE" = "xx86"],[
202 AC_MSG_CHECKING([if architecture really supports the mfence instruction])
203 #For now, using lock; addl compatibility mode even for i686, because the
204 #Pentium III is seen as a i686, but lacks mfence instruction.
205 #Only using fence for x86_64.
206 #
207 #k1om is the name for the Intel MIC family (Xeon Phi). It is an x86_64
208 #variant but lacks fence instructions.
209 AS_IF([test "x$host_cpu" != "xi386" -a "x$host_cpu" != "xi486" -a "x$host_cpu" != "xi586" -a "x$host_cpu" != "xi686" -a "x$host_vendor" != "xk1om" -a "x$host_cpu" != "xk1om"],[
210 AC_MSG_RESULT([yes])
211 AC_DEFINE([CONFIG_RCU_HAVE_FENCE], [1])
212 ],[
213 AC_MSG_RESULT([no])
214 ])
215 ])
216
217 # Check if sys_futex() is available
218 AC_MSG_CHECKING([for sys_futex()])
219 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
220 #include <sys/syscall.h>
221 #ifndef __NR_futex
222 #error "futexes not available"
223 #endif
224 ]])
225 ],[
226 AC_MSG_RESULT([yes])
227 AC_DEFINE([CONFIG_RCU_HAVE_FUTEX], [1])
228 compat_futex_test=0
229 ],[
230 AC_MSG_RESULT([no])
231 compat_futex_test=1
232 ])
233
234 # Search for clock_gettime
235 AC_SEARCH_LIBS([clock_gettime], [rt], [
236 AC_DEFINE([CONFIG_RCU_HAVE_CLOCK_GETTIME], [1])
237 ], [])
238
239 # Check for pthread
240 AC_CHECK_LIB([pthread], [pthread_create],
241 [AM_CONDITIONAL(LIBC_INCLUDES_PTHREAD, false)],
242 [AC_CHECK_LIB([c], [pthread_create],
243 [AM_CONDITIONAL(LIBC_INCLUDES_PTHREAD, true)],
244 [AC_MSG_ERROR([Cannot find libpthread. Use [LDFLAGS]=-Ldir to specify its location.])]
245 )]
246 )
247
248 AM_CONDITIONAL([COMPAT_FUTEX], [test "x$compat_futex_test" = "x1"])
249 AM_CONDITIONAL([COMPAT_ARCH], [test "x$SUBARCHTYPE" = "xx86compat"])
250 AM_CONDITIONAL([NO_SHARED], [test "x$enable_shared" = "xno"])
251
252 # smp-support configure option
253 AC_ARG_ENABLE([smp-support],
254 AS_HELP_STRING([--disable-smp-support], [Disable SMP support. Warning: only use this on uniprocessor systems. [default=enabled]]),
255 [def_smp_support=$enableval],
256 [def_smp_support="yes"])
257 AS_IF([test "x$def_smp_support" = "xyes"], [AC_DEFINE([CONFIG_RCU_SMP], [1])])
258
259
260 # From the sched_setaffinity(2)'s man page:
261 # ~~~~
262 # The CPU affinity system calls were introduced in Linux kernel 2.5.8.
263 # The library interfaces were introduced in glibc 2.3. Initially, the
264 # glibc interfaces included a cpusetsize argument. In glibc 2.3.3,
265 # the cpuset size argument was removed, but this argument was
266 # restored in glibc 2.3.4.
267 # ~~~~
268
269 # In addition to that, some vendors ported the system call to 2.4
270 # kernels.
271
272 # Furthermore, when the function first appeared, the MASK argument was
273 # an unsigned long pointer, while later it was made into a cpu_set_t
274 # pointer. Systems that have the cpu_set_t version also should have
275 # the CPU_ZERO, CPU_SET, etc. macros.
276
277 # All this mess means we have to cater for at least 3 different
278 # sched_setaffinity prototypes:
279
280 # ~~~~
281 # int sched_setaffinity (pid_t pid, unsigned int len, unsigned long *mask);
282 # int sched_setaffinity (pid_t __pid, size_t __cpusetsize, const cpu_set_t *__cpuset);
283 # int sched_setaffinity (pid_t __pid, const cpu_set_t *__mask);
284 # ~~~~
285
286 # Since we define _GNU_SOURCE in the sources, must do so too in the
287 # autoconf tests, as defining _GNU_SOURCE or not exposes
288 # sched_setaffinity bits differently.
289 saved_CFLAGS=$CFLAGS
290 CFLAGS="$CFLAGS -D_GNU_SOURCE"
291
292 AC_CHECK_TYPES([cpu_set_t],
293 [have_cpu_set_t="yes"],
294 [have_cpu_set_t="no"],
295 [#include <sched.h>])
296
297 # Confirm that we have CPU_ZERO, and it actually works.
298 AC_MSG_CHECKING([whether CPU_ZERO works])
299 AH_TEMPLATE([HAVE_CPU_ZERO], [Defined to 1 if we have CPU_ZERO and it works])
300 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
301 #define _GNU_SOURCE
302 #include <sched.h>
303 int main()
304 {
305 cpu_set_t foo; CPU_ZERO(&foo);
306 return 0;
307 }
308 ]])
309 ],[
310 AC_DEFINE(HAVE_CPU_ZERO, 1)
311 AC_MSG_RESULT([yes])
312 ],[
313 AC_MSG_RESULT([no])
314 ])
315
316 # Confirm that we have CPU_SET, and it actually works.
317 AC_MSG_CHECKING([whether CPU_SET works])
318 AH_TEMPLATE([HAVE_CPU_SET], [Defined to 1 if we have CPU_SET and it works])
319 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
320 #define _GNU_SOURCE
321 #include <sched.h>
322 int main()
323 {
324 cpu_set_t foo, mask; CPU_SET(0, &foo);
325 return 0;
326 }
327 ]])
328 ],[
329 AC_DEFINE(HAVE_CPU_SET, 1)
330 AC_MSG_RESULT([yes])
331 ],[
332 AC_MSG_RESULT([no])
333 ])
334
335 # First check if the function is available at all.
336 AC_CHECK_FUNCS([sched_setaffinity],[
337 # Okay, we have it. Check if also have cpu_set_t. If we don't,
338 # then we have the first version using unsigned long, and no
339 # CPU_ZERO, etc. macros. If we do have cpu_set_t, we may have the
340 # version with 2 or 3 arguments. In that case, CPU_ZERO, etc.,
341 # should also be present, but we confirm nonetheless.
342
343 AS_IF([test "x$have_cpu_set_t" = "xyes"], [
344 # We do have it.
345 # Check how many arguments does sched_setaffinity take.
346 # Should be 3 or 2.
347 AC_MSG_CHECKING([how many arguments sched_setaffinity takes])
348 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
349 #include <sched.h>
350 int main()
351 {
352 cpu_set_t foo;
353 sched_setaffinity(0, sizeof (foo), &foo);
354 return 0;
355 }
356 ]])
357 ],
358 [sched_set_affinity_args=3],
359 [sched_set_affinity_args=2])
360 AC_DEFINE_UNQUOTED(SCHED_SETAFFINITY_ARGS,
361 $sched_set_affinity_args,
362 [Defined to sched_setaffinity's number of arguments.])
363 AC_MSG_RESULT([$sched_set_affinity_args])
364 ],[
365 # No cpu_set_t, always 3 args.
366 AC_DEFINE(SCHED_SETAFFINITY_ARGS, 3)
367 ])
368 ])
369
370 CFLAGS=$saved_CFLAGS
371
372 AC_CONFIG_LINKS([
373 urcu/arch.h:$ARCHSRC
374 urcu/uatomic.h:$UATOMICSRC
375 ])
376 AC_CONFIG_FILES([
377 Makefile
378 doc/Makefile
379 doc/examples/Makefile
380 tests/Makefile
381 tests/common/Makefile
382 tests/unit/Makefile
383 tests/benchmark/Makefile
384 tests/regression/Makefile
385 tests/regression/regression_tests
386 tests/utils/Makefile
387 liburcu.pc
388 liburcu-bp.pc
389 liburcu-cds.pc
390 liburcu-qsbr.pc
391 liburcu-mb.pc
392 liburcu-signal.pc
393 ])
394 AC_OUTPUT
395
396 # Report on selected configure options
397 AS_IF([test "x$def_smp_support" = "xyes"],[
398 AS_ECHO("SMP support enabled.")
399 ],[
400 AS_ECHO("SMP support disabled.")
401 ])
402
403 AS_IF([test "x$def_tls_detect" = "x"],[
404 AS_ECHO("Thread Local Storage (TLS): pthread_getspecific().")
405 ],[
406 AS_ECHO("Thread Local Storage (TLS): $def_tls_detect.")
407 ])
This page took 0.048557 seconds and 4 git commands to generate.