configure.ac

   1 AC_PREREQ(2.59)
   2 AC_INIT([userspace-rcu],[0.9.0],[mathieu dot desnoyers at efficios dot com], [], [http://liburcu.org/])
   3
   4 # Following the numbering scheme proposed by libtool for the library version
   5 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
   6 AC_SUBST([URCU_LIBRARY_VERSION], [4:0:0])
   7
   8 AC_CONFIG_SRCDIR([urcu.h])
   9 AC_CONFIG_HEADERS([config.h urcu/config.h])
  10 AC_CONFIG_AUX_DIR([config])
  11 AC_CONFIG_MACRO_DIR([m4])
  12
  13 AC_CANONICAL_TARGET
  14 AC_CANONICAL_HOST
  15
  16 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip])
  17 AM_MAINTAINER_MODE([enable])
  18
  19 # Enable silent rules if available (Introduced in AM 1.11)
  20 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  21
  22 AH_TEMPLATE([CONFIG_RCU_SMP], [Enable SMP support. With SMP support enabled, uniprocessors are also supported. With SMP support disabled, UP systems work fine, but the behavior of SMP systems is undefined.])
  23 AH_TEMPLATE([CONFIG_RCU_HAVE_FENCE], [Defined when on a system that has memory fence instructions.])
  24 AH_TEMPLATE([CONFIG_RCU_HAVE_FUTEX], [Defined when on a system with futex support.])
  25 AH_TEMPLATE([CONFIG_RCU_COMPAT_ARCH], [Compatibility mode for i386 which lacks cmpxchg instruction.])
  26 AH_TEMPLATE([CONFIG_RCU_ARM_HAVE_DMB], [Use the dmb instruction if available for use on ARM.])
  27 AH_TEMPLATE([CONFIG_RCU_TLS], [TLS provided by the compiler.])
  28
  29 # Allow overriding storage used for TLS variables.
  30 AC_ARG_ENABLE([compiler-tls],
  31         AS_HELP_STRING([--disable-compiler-tls], [Use pthread_getspecific() to emulate Thread Local Storage (TLS) variables.]),
  32         [def_compiler_tls=$enableval],
  33         [def_compiler_tls="yes"])
  34
  35 # If not overridden, use ax_tls.m4 to check if TLS is available.
  36 AS_IF([test "x$def_compiler_tls" = "xyes"],
  37         [AX_TLS([def_tls_detect=$ac_cv_tls], [:])],
  38         [:])
  39
  40 AS_IF([test "x$def_tls_detect" = "x"],
  41         [:],
  42         [AC_DEFINE_UNQUOTED([CONFIG_RCU_TLS], $def_tls_detect)])
  43
  44 # Checks for C compiler
  45 AC_USE_SYSTEM_EXTENSIONS
  46 AC_PROG_CC
  47 AC_PROG_CC_STDC
  48
  49 # Checks for programs.
  50 AC_PROG_AWK
  51 AC_PROG_MAKE_SET
  52 AC_CHECK_PROGS(NPROC, [nproc gnproc])
  53 LT_INIT
  54
  55 # Checks for typedefs, structures, and compiler characteristics.
  56 AC_C_INLINE
  57 AC_TYPE_PID_T
  58 AC_TYPE_SIZE_T
  59 AC_TYPE_SSIZE_T
  60 AC_TYPE_UINT16_T
  61 AC_TYPE_INT32_T
  62 AC_TYPE_UINT32_T
  63 AC_TYPE_UINT64_T
  64 AC_TYPE_UINT8_T
  65
  66 AX_C___ATTRIBUTE__
  67 AS_IF([test "x$ax_cv___attribute__" = "xyes"],
  68         [:],
  69         [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])
  70
  71 AX_PTHREAD(,[AC_MSG_ERROR([Could not configure pthreads support])])
  72 LIBS="$PTHREAD_LIBS $LIBS"
  73 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
  74 CC="$PTHREAD_CC"
  75
  76 # Checks for library functions.
  77 AC_FUNC_MALLOC
  78 AC_FUNC_MMAP
  79 AC_FUNC_FORK
  80 AC_CHECK_FUNCS([ \
  81         atexit \
  82         clock_gettime \
  83         getcpuid \
  84         gettid \
  85         gettimeofday \
  86         memeset \
  87         memset \
  88         munmap \
  89         sched_getcpu \
  90         strerror \
  91         strtoul \
  92         sysconf \
  93 ])
  94
  95 # Check for headers
  96 AC_HEADER_STDBOOL
  97 AC_CHECK_HEADERS([ \
  98         limits.h \
  99         stddef.h \
 100         sys/param.h \
 101         sys/time.h \
 102 ])
 103
 104 # Find arch type
 105 AS_CASE([$host_cpu],
 106         [k1om], [ARCHTYPE="x86"],
 107         [i386], [ARCHTYPE="x86" && SUBARCHTYPE="x86compat"],
 108         [i486], [ARCHTYPE="x86"],
 109         [i586], [ARCHTYPE="x86"],
 110         [i686], [ARCHTYPE="x86"],
 111         [amd64], [ARCHTYPE="x86"],
 112         [x86_64], [ARCHTYPE="x86"],
 113         [powerpc], [ARCHTYPE="ppc"],
 114         [ppc64], [ARCHTYPE="ppc"],
 115         [powerpc64], [ARCHTYPE="ppc"],
 116         [powerpc64le], [ARCHTYPE="ppc"],
 117         [ppc], [ARCHTYPE="ppc"],
 118         [s390], [ARCHTYPE="s390"],
 119         [s390x], [ARCHTYPE="s390"],
 120         [sparc], [ARCHTYPE="sparc64"],
 121         [sparc64], [ARCHTYPE="sparc64"],
 122         [alpha*], [ARCHTYPE="alpha"],
 123         [ia64], [ARCHTYPE="ia64"],
 124         [arm*], [ARCHTYPE="arm"],
 125         [aarch64], [ARCHTYPE="aarch64"],
 126         [mips*], [ARCHTYPE="mips"],
 127         [tile*], [ARCHTYPE="tile"],
 128         [hppa*], [ARCHTYPE="hppa"],
 129         [ARCHTYPE="unknown"]
 130 )
 131
 132 AS_CASE([$host],[*-*-linux-androideabi],
 133         [AM_CONDITIONAL(TARGET_IS_ANDROID, true)],
 134         [AM_CONDITIONAL(TARGET_IS_ANDROID, false)]
 135 )
 136
 137 AC_SUBST(ARCHTYPE)
 138 AC_SUBST(SUBARCHTYPE)
 139
 140 UATOMICSRC=urcu/uatomic/$ARCHTYPE.h
 141 ARCHSRC=urcu/arch/$ARCHTYPE.h
 142
 143 AS_IF([test "x$SUBARCHTYPE" = xx86compat],[
 144         AC_DEFINE([CONFIG_RCU_COMPAT_ARCH], [1])
 145 ])
 146
 147 AS_IF([test "$host_cpu" = "armv7l"],[
 148         CFLAGS="$CFLAGS -mcpu=cortex-a9 -mtune=cortex-a9 -O1"
 149 ])
 150
 151 # ARM-specific checks
 152 AS_IF([test "x$ARCHTYPE" = "xarm"],[
 153         AC_MSG_CHECKING([for dmb instruction])
 154         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 155                                 int main()
 156                                 {
 157                                         asm volatile("dmb":::"memory");
 158                                         return 0;
 159                                 }
 160                 ]])
 161         ],[
 162                 AC_MSG_RESULT([yes])
 163                 AC_DEFINE([CONFIG_RCU_ARM_HAVE_DMB], [1])
 164         ],[
 165                 AC_MSG_RESULT([no])
 166         ])
 167 ])
 168
 169 # Tile-specific checks
 170 AS_IF([echo "$host_cpu" | grep "^tile"],[
 171         AC_MSG_CHECKING([for Tile architecture type])
 172         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 173                                 #ifndef __tilegx__
 174                                 #error
 175                                 #endif
 176                 ]])
 177         ],[
 178                 AC_MSG_RESULT([ok])
 179         ],[
 180                 AC_MSG_FAILURE([URCU has only been tested on the TileGx architecture. For other Tile* architectures, please run the tests first and report the results to the maintainer so that proper support can be added.])
 181         ])
 182 ])
 183
 184 # x86-specific checks
 185 AS_IF([test "x$ARCHTYPE" = "xx86"],[
 186         AC_MSG_CHECKING([if architecture really supports the mfence instruction])
 187         #For now, using lock; addl compatibility mode even for i686, because the
 188         #Pentium III is seen as a i686, but lacks mfence instruction.
 189         #Only using fence for x86_64.
 190         #
 191         #k1om is the name for the Intel MIC family (Xeon Phi). It is an x86_64
 192         #variant but lacks fence instructions.
 193         AS_IF([test "x$host_cpu" != "xi386" -a "x$host_cpu" != "xi486" -a "x$host_cpu" != "xi586" -a "x$host_cpu" != "xi686" -a "x$host_vendor" != "xk1om" -a "x$host_cpu" != "xk1om"],[
 194                 AC_MSG_RESULT([yes])
 195                 AC_DEFINE([CONFIG_RCU_HAVE_FENCE], [1])
 196         ],[
 197                 AC_MSG_RESULT([no])
 198         ])
 199 ])
 200
 201 # Check if sys_futex() is available
 202 AC_MSG_CHECKING([for sys_futex()])
 203 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 204                 #include <sys/syscall.h>
 205                 #ifndef __NR_futex
 206                 #error "futexes not available"
 207                 #endif
 208         ]])
 209 ],[
 210         AC_MSG_RESULT([yes])
 211         AC_DEFINE([CONFIG_RCU_HAVE_FUTEX], [1])
 212         compat_futex_test=0
 213 ],[
 214         AC_MSG_RESULT([no])
 215         compat_futex_test=1
 216 ])
 217
 218 # Check for pthread
 219 AC_CHECK_LIB([pthread], [pthread_create],
 220         [AM_CONDITIONAL(LIBC_INCLUDES_PTHREAD, false)],
 221         [AC_CHECK_LIB([c], [pthread_create],
 222                 [AM_CONDITIONAL(LIBC_INCLUDES_PTHREAD, true)],
 223                 [AC_MSG_ERROR([Cannot find libpthread. Use [LDFLAGS]=-Ldir to specify its location.])]
 224         )]
 225 )
 226
 227 AM_CONDITIONAL([COMPAT_FUTEX], [test "x$compat_futex_test" = "x1"])
 228 AM_CONDITIONAL([COMPAT_ARCH], [test "x$SUBARCHTYPE" = "xx86compat"])
 229 AM_CONDITIONAL([NO_SHARED], [test "x$enable_shared" = "xno"])
 230
 231 # smp-support configure option
 232 AC_ARG_ENABLE([smp-support],
 233         AS_HELP_STRING([--disable-smp-support], [Disable SMP support. Warning: only use this on uniprocessor systems. [default=enabled]]),
 234         [def_smp_support=$enableval],
 235         [def_smp_support="yes"])
 236 AS_IF([test "x$def_smp_support" = "xyes"], [AC_DEFINE([CONFIG_RCU_SMP], [1])])
 237
 238
 239 # From the sched_setaffinity(2)'s man page:
 240 # ~~~~
 241 # The CPU affinity system calls were introduced in Linux kernel 2.5.8.
 242 # The library interfaces were introduced in glibc 2.3.  Initially, the
 243 # glibc interfaces included a cpusetsize argument.  In glibc 2.3.3,
 244 # the cpuset size argument was removed, but this argument was
 245 # restored in glibc 2.3.4.
 246 # ~~~~
 247
 248 # In addition to that, some vendors ported the system call to 2.4
 249 # kernels.
 250
 251 # Furthermore, when the function first appeared, the MASK argument was
 252 # an unsigned long pointer, while later it was made into a cpu_set_t
 253 # pointer.  Systems that have the cpu_set_t version also should have
 254 # the CPU_ZERO, CPU_SET, etc. macros.
 255
 256 # All this mess means we have to cater for at least 3 different
 257 # sched_setaffinity prototypes:
 258
 259 # ~~~~
 260 #  int sched_setaffinity (pid_t pid, unsigned int len, unsigned long *mask);
 261 #  int sched_setaffinity (pid_t __pid, size_t __cpusetsize, const cpu_set_t *__cpuset);
 262 #  int sched_setaffinity (pid_t __pid, const cpu_set_t *__mask);
 263 # ~~~~
 264
 265 # Since we define _GNU_SOURCE in the sources, must do so too in the
 266 # autoconf tests, as defining _GNU_SOURCE or not exposes
 267 # sched_setaffinity bits differently.
 268 saved_CFLAGS=$CFLAGS
 269 CFLAGS="$CFLAGS -D_GNU_SOURCE"
 270
 271 AC_CHECK_TYPES([cpu_set_t],
 272         [have_cpu_set_t="yes"],
 273         [have_cpu_set_t="no"],
 274         [#include <sched.h>])
 275
 276 # Confirm that we have CPU_ZERO, and it actually works.
 277 AC_MSG_CHECKING([whether CPU_ZERO works])
 278 AH_TEMPLATE([HAVE_CPU_ZERO], [Defined to 1 if we have CPU_ZERO and it works])
 279 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 280                 #define _GNU_SOURCE
 281                 #include <sched.h>
 282                 int main()
 283                 {
 284                         cpu_set_t foo; CPU_ZERO(&foo);
 285                         return 0;
 286                 }
 287         ]])
 288 ],[
 289         AC_DEFINE(HAVE_CPU_ZERO, 1)
 290         AC_MSG_RESULT([yes])
 291 ],[
 292         AC_MSG_RESULT([no])
 293 ])
 294
 295 # Confirm that we have CPU_SET, and it actually works.
 296 AC_MSG_CHECKING([whether CPU_SET works])
 297 AH_TEMPLATE([HAVE_CPU_SET], [Defined to 1 if we have CPU_SET and it works])
 298 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 299                 #define _GNU_SOURCE
 300                 #include <sched.h>
 301                 int main()
 302                 {
 303                         cpu_set_t foo, mask; CPU_SET(0, &foo);
 304                         return 0;
 305                 }
 306         ]])
 307 ],[
 308         AC_DEFINE(HAVE_CPU_SET, 1)
 309         AC_MSG_RESULT([yes])
 310 ],[
 311         AC_MSG_RESULT([no])
 312 ])
 313
 314 # First check if the function is available at all.
 315 AC_CHECK_FUNCS([sched_setaffinity],[
 316         # Okay, we have it.  Check if also have cpu_set_t.  If we don't,
 317         # then we have the first version using unsigned long, and no
 318         # CPU_ZERO, etc. macros.  If we do have cpu_set_t, we may have the
 319         # version with 2 or 3 arguments.  In that case, CPU_ZERO, etc.,
 320         # should also be present, but we confirm nonetheless.
 321
 322         AS_IF([test "x$have_cpu_set_t" = "xyes"], [
 323                 # We do have it.
 324                 # Check how many arguments does sched_setaffinity take.
 325                 # Should be 3 or 2.
 326                 AC_MSG_CHECKING([how many arguments sched_setaffinity takes])
 327                 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 328                                 #include <sched.h>
 329                                 int main()
 330                                 {
 331                                         cpu_set_t foo;
 332                                         sched_setaffinity(0, sizeof (foo), &foo);
 333                                         return 0;
 334                                 }
 335                         ]])
 336                 ],
 337                 [sched_set_affinity_args=3],
 338                 [sched_set_affinity_args=2])
 339                 AC_DEFINE_UNQUOTED(SCHED_SETAFFINITY_ARGS,
 340                         $sched_set_affinity_args,
 341                         [Defined to sched_setaffinity's number of arguments.])
 342                 AC_MSG_RESULT([$sched_set_affinity_args])
 343         ],[
 344                 # No cpu_set_t, always 3 args.
 345                 AC_DEFINE(SCHED_SETAFFINITY_ARGS, 3)
 346         ])
 347 ])
 348
 349 CFLAGS=$saved_CFLAGS
 350
 351 AC_CONFIG_LINKS([
 352         urcu/arch.h:$ARCHSRC
 353         urcu/uatomic.h:$UATOMICSRC
 354 ])
 355 AC_CONFIG_FILES([
 356         Makefile
 357         doc/Makefile
 358         doc/examples/Makefile
 359         tests/Makefile
 360         tests/common/Makefile
 361         tests/unit/Makefile
 362         tests/benchmark/Makefile
 363         tests/regression/Makefile
 364         tests/regression/regression_tests
 365         tests/utils/Makefile
 366         liburcu.pc
 367         liburcu-bp.pc
 368         liburcu-cds.pc
 369         liburcu-qsbr.pc
 370         liburcu-mb.pc
 371         liburcu-signal.pc
 372 ])
 373 AC_OUTPUT
 374
 375 # Report on selected configure options
 376 AS_IF([test "x$def_smp_support" = "xyes"],[
 377         AS_ECHO("SMP support enabled.")
 378 ],[
 379         AS_ECHO("SMP support disabled.")
 380 ])
 381
 382 AS_IF([test "x$def_tls_detect" = "x"],[
 383         AS_ECHO("Thread Local Storage (TLS): pthread_getspecific().")
 384 ],[
 385         AS_ECHO("Thread Local Storage (TLS): $def_tls_detect.")
 386 ])