configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4
   5 AC_INIT([userspace-rcu],[0.8.0],[mathieu dot desnoyers at efficios dot com])
   6
   7 # Following the numbering scheme proposed by libtool for the library version
   8 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
   9 AC_SUBST([URCU_LIBRARY_VERSION], [3:0:0])
  10
  11 AC_CONFIG_AUX_DIR([config])
  12 AC_CONFIG_MACRO_DIR([config])
  13 AC_CANONICAL_TARGET
  14 AC_CANONICAL_HOST
  15 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip])
  16 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  17
  18 m4_include([config/ax_tls.m4])
  19
  20 AC_CONFIG_SRCDIR([urcu.h])
  21
  22 AC_CONFIG_HEADERS([config.h urcu/config.h])
  23
  24 AH_TEMPLATE([CONFIG_RCU_SMP], [Enable SMP support. With SMP support enabled, uniprocessors are also supported. With SMP support disabled, UP systems work fine, but the behavior of SMP systems is undefined.])
  25 AH_TEMPLATE([CONFIG_RCU_HAVE_FENCE], [Defined when on a system that has memory fence instructions.])
  26 AH_TEMPLATE([CONFIG_RCU_HAVE_FUTEX], [Defined when on a system with futex support.])
  27 AH_TEMPLATE([CONFIG_RCU_COMPAT_ARCH], [Compatibility mode for i386 which lacks cmpxchg instruction.])
  28 AH_TEMPLATE([CONFIG_RCU_ARM_HAVE_DMB], [Use the dmb instruction if available for use on ARM.])
  29 AH_TEMPLATE([CONFIG_RCU_TLS], [TLS provided by the compiler.])
  30
  31 # Allow overriding storage used for TLS variables.
  32 AC_ARG_ENABLE([compiler-tls],
  33         AS_HELP_STRING([--disable-compiler-tls], [Use pthread_getspecific() to emulate Thread Local Storage (TLS) variables.]),
  34         [def_compiler_tls=$enableval],
  35         [def_compiler_tls="yes"])
  36
  37 # If not overridden, use ax_tls.m4 to check if TLS is available.
  38 AS_IF([test "x$def_compiler_tls" = "xyes"],
  39         [AX_TLS([def_tls_detect=$ac_cv_tls], [:])],
  40         [:])
  41
  42 AS_IF([test "x$def_tls_detect" = "x"],
  43         [:],
  44         [AC_DEFINE_UNQUOTED([CONFIG_RCU_TLS], $def_tls_detect)])
  45
  46 # Checks for programs.
  47 AC_PROG_CC
  48 AC_PROG_MAKE_SET
  49 LT_INIT
  50
  51 # Checks for typedefs, structures, and compiler characteristics.
  52 AC_C_INLINE
  53 AC_TYPE_PID_T
  54 AC_TYPE_SIZE_T
  55
  56 # Checks for library functions.
  57 AC_FUNC_MALLOC
  58 AC_FUNC_MMAP
  59 AC_CHECK_FUNCS([bzero gettimeofday munmap sched_getcpu strtoul sysconf gettid])
  60
  61 # Find arch type
  62 AS_CASE([$host_cpu],
  63         [i386], [ARCHTYPE="x86" && SUBARCHTYPE="x86compat"],
  64         [i486], [ARCHTYPE="x86"],
  65         [i586], [ARCHTYPE="x86"],
  66         [i686], [ARCHTYPE="x86"],
  67         [amd64], [ARCHTYPE="x86"],
  68         [x86_64], [ARCHTYPE="x86"],
  69         [powerpc], [ARCHTYPE="ppc"],
  70         [ppc64], [ARCHTYPE="ppc"],
  71         [powerpc64], [ARCHTYPE="ppc"],
  72         [powerpc64le], [ARCHTYPE="gcc"],
  73         [ppc], [ARCHTYPE="ppc"],
  74         [s390], [ARCHTYPE="s390"],
  75         [s390x], [ARCHTYPE="s390"],
  76         [sparc], [ARCHTYPE="sparc64"],
  77         [sparc64], [ARCHTYPE="sparc64"],
  78         [alpha*], [ARCHTYPE="alpha"],
  79         [ia64], [ARCHTYPE="gcc"],
  80         [arm*], [ARCHTYPE="arm"],
  81         [aarch64], [ARCHTYPE="gcc"],
  82         [mips*], [ARCHTYPE="mips"],
  83         [tile*], [ARCHTYPE="gcc"],
  84         [ARCHTYPE="unknown"]
  85 )
  86
  87 AS_CASE([$host],[*-*-linux-androideabi],
  88         [AM_CONDITIONAL(TARGET_IS_ANDROID, true)],
  89         [AM_CONDITIONAL(TARGET_IS_ANDROID, false)]
  90 )
  91
  92 AC_SUBST(ARCHTYPE)
  93 AC_SUBST(SUBARCHTYPE)
  94
  95 UATOMICSRC=urcu/uatomic/$ARCHTYPE.h
  96 ARCHSRC=urcu/arch/$ARCHTYPE.h
  97
  98 AS_IF([test "x$SUBARCHTYPE" = xx86compat],[
  99         AC_DEFINE([CONFIG_RCU_COMPAT_ARCH], [1])
 100 ])
 101
 102 AS_IF([test "$host_cpu" = "armv7l"],[
 103         CFLAGS="$CFLAGS -mcpu=cortex-a9 -mtune=cortex-a9 -O1"
 104 ])
 105
 106 # ARM-specific checks
 107 AS_IF([test "x$ARCHTYPE" = "xarm"],[
 108         AC_MSG_CHECKING([for dmb instruction])
 109         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 110                                 int main()
 111                                 {
 112                                         asm volatile("dmb":::"memory");
 113                                         return 0;
 114                                 }
 115                 ]])
 116         ],[
 117                 AC_MSG_RESULT([yes])
 118                 AC_DEFINE([CONFIG_RCU_ARM_HAVE_DMB], [1])
 119         ],[
 120                 AC_MSG_RESULT([no])
 121         ])
 122 ])
 123
 124 # Tile-specific checks
 125 AS_IF([echo "$host_cpu" | grep "^tile"],[
 126         AC_MSG_CHECKING([for Tile architecture type])
 127         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 128                                 #ifndef __tilegx__
 129                                 #error
 130                                 #endif
 131                 ]])
 132         ],[
 133                 AC_MSG_RESULT([ok])
 134         ],[
 135                 AC_MSG_FAILURE([URCU has only been tested on the TileGx architecture. For other Tile* architectures, please run the tests first and report the results to the maintainer so that proper support can be added.])
 136         ])
 137 ])
 138
 139 # x86-specific checks
 140 AS_IF([test "x$ARCHTYPE" = "xx86"],[
 141         AC_MSG_CHECKING([if architecture really supports the mfence instruction])
 142         #For now, using lock; addl compatibility mode even for i686, because the
 143         #Pentium III is seen as a i686, but lacks mfence instruction.
 144         #Only using fence for x86_64.
 145         #
 146         #k1om is the name for the Intel MIC family (Xeon Phi). It is an x86_64
 147         #variant but lacks fence instructions.
 148         AS_IF([test "x$host_cpu" != "xi386" -a "x$host_cpu" != "xi486" -a "x$host_cpu" != "xi586" -a "x$host_cpu" != "xi686" -a "x$host_vendor" != "xk1om"],[
 149                 AC_MSG_RESULT([yes])
 150                 AC_DEFINE([CONFIG_RCU_HAVE_FENCE], [1])
 151         ],[
 152                 AC_MSG_RESULT([no])
 153         ])
 154 ])
 155
 156 # Check if sys_futex() is available
 157 AC_MSG_CHECKING([for sys_futex()])
 158 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 159                 #include <sys/syscall.h>
 160                 #ifndef __NR_futex
 161                 #error "futexes not available"
 162                 #endif
 163         ]])
 164 ],[
 165         AC_MSG_RESULT([yes])
 166         AC_DEFINE([CONFIG_RCU_HAVE_FUTEX], [1])
 167         compat_futex_test=0
 168 ],[
 169         AC_MSG_RESULT([no])
 170         compat_futex_test=1
 171 ])
 172
 173 # Check for pthread
 174 AC_CHECK_LIB([pthread], [pthread_create],
 175         [AM_CONDITIONAL(LIBC_INCLUDES_PTHREAD, false)],
 176         [AC_CHECK_LIB([c], [pthread_create],
 177                 [AM_CONDITIONAL(LIBC_INCLUDES_PTHREAD, true)],
 178                 [AC_MSG_ERROR([Cannot find libpthread. Use [LDFLAGS]=-Ldir to specify its location.])]
 179         )]
 180 )
 181
 182 AM_CONDITIONAL([COMPAT_FUTEX], [test "x$compat_futex_test" = "x1"])
 183 AM_CONDITIONAL([COMPAT_ARCH], [test "x$SUBARCHTYPE" = "xx86compat"])
 184 AM_CONDITIONAL([NO_SHARED], [test "x$enable_shared" = "xno"])
 185
 186 # smp-support configure option
 187 AC_ARG_ENABLE([smp-support],
 188         AS_HELP_STRING([--disable-smp-support], [Disable SMP support. Warning: only use this on uniprocessor systems. [default=enabled]]),
 189         [def_smp_support=$enableval],
 190         [def_smp_support="yes"])
 191 AS_IF([test "x$def_smp_support" = "xyes"], [AC_DEFINE([CONFIG_RCU_SMP], [1])])
 192
 193
 194 # From the sched_setaffinity(2)'s man page:
 195 # ~~~~
 196 # The CPU affinity system calls were introduced in Linux kernel 2.5.8.
 197 # The library interfaces were introduced in glibc 2.3.  Initially, the
 198 # glibc interfaces included a cpusetsize argument.  In glibc 2.3.3,
 199 # the cpuset size argument was removed, but this argument was
 200 # restored in glibc 2.3.4.
 201 # ~~~~
 202
 203 # In addition to that, some vendors ported the system call to 2.4
 204 # kernels.
 205
 206 # Furthermore, when the function first appeared, the MASK argument was
 207 # an unsigned long pointer, while later it was made into a cpu_set_t
 208 # pointer.  Systems that have the cpu_set_t version also should have
 209 # the CPU_ZERO, CPU_SET, etc. macros.
 210
 211 # All this mess means we have to cater for at least 3 different
 212 # sched_setaffinity prototypes:
 213
 214 # ~~~~
 215 #  int sched_setaffinity (pid_t pid, unsigned int len, unsigned long *mask);
 216 #  int sched_setaffinity (pid_t __pid, size_t __cpusetsize, const cpu_set_t *__cpuset);
 217 #  int sched_setaffinity (pid_t __pid, const cpu_set_t *__mask);
 218 # ~~~~
 219
 220 # Since we define _GNU_SOURCE in the sources, must do so too in the
 221 # autoconf tests, as defining _GNU_SOURCE or not exposes
 222 # sched_setaffinity bits differently.
 223 saved_CFLAGS=$CFLAGS
 224 CFLAGS="$CFLAGS -D_GNU_SOURCE"
 225
 226 AC_CHECK_TYPES([cpu_set_t],
 227         [have_cpu_set_t="yes"],
 228         [have_cpu_set_t="no"],
 229         [#include <sched.h>])
 230
 231 # Confirm that we have CPU_ZERO, and it actually works.
 232 AC_MSG_CHECKING([whether CPU_ZERO works])
 233 AH_TEMPLATE([HAVE_CPU_ZERO], [Defined to 1 if we have CPU_ZERO and it works])
 234 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 235                 #define _GNU_SOURCE
 236                 #include <sched.h>
 237                 int main()
 238                 {
 239                         cpu_set_t foo; CPU_ZERO(&foo);
 240                         return 0;
 241                 }
 242         ]])
 243 ],[
 244         AC_DEFINE(HAVE_CPU_ZERO, 1)
 245         AC_MSG_RESULT([yes])
 246 ],[
 247         AC_MSG_RESULT([no])
 248 ])
 249
 250 # Confirm that we have CPU_SET, and it actually works.
 251 AC_MSG_CHECKING([whether CPU_SET works])
 252 AH_TEMPLATE([HAVE_CPU_SET], [Defined to 1 if we have CPU_SET and it works])
 253 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 254                 #define _GNU_SOURCE
 255                 #include <sched.h>
 256                 int main()
 257                 {
 258                         cpu_set_t foo, mask; CPU_SET(0, &foo);
 259                         return 0;
 260                 }
 261         ]])
 262 ],[
 263         AC_DEFINE(HAVE_CPU_SET, 1)
 264         AC_MSG_RESULT([yes])
 265 ],[
 266         AC_MSG_RESULT([no])
 267 ])
 268
 269 # First check if the function is available at all.
 270 AC_CHECK_FUNCS([sched_setaffinity],[
 271         # Okay, we have it.  Check if also have cpu_set_t.  If we don't,
 272         # then we have the first version using unsigned long, and no
 273         # CPU_ZERO, etc. macros.  If we do have cpu_set_t, we may have the
 274         # version with 2 or 3 arguments.  In that case, CPU_ZERO, etc.,
 275         # should also be present, but we confirm nonetheless.
 276
 277         AS_IF([test "x$have_cpu_set_t" = "xyes"], [
 278                 # We do have it.
 279                 # Check how many arguments does sched_setaffinity take.
 280                 # Should be 3 or 2.
 281                 AC_MSG_CHECKING([how many arguments sched_setaffinity takes])
 282                 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 283                                 #include <sched.h>
 284                                 int main()
 285                                 {
 286                                         cpu_set_t foo;
 287                                         sched_setaffinity(0, sizeof (foo), &foo);
 288                                         return 0;
 289                                 }
 290                         ]])
 291                 ],
 292                 [sched_set_affinity_args=3],
 293                 [sched_set_affinity_args=2])
 294                 AC_DEFINE_UNQUOTED(SCHED_SETAFFINITY_ARGS,
 295                         $sched_set_affinity_args,
 296                         [Defined to sched_setaffinity's number of arguments.])
 297                 AC_MSG_RESULT([$sched_set_affinity_args])
 298         ],[
 299                 # No cpu_set_t, always 3 args.
 300                 AC_DEFINE(SCHED_SETAFFINITY_ARGS, 3)
 301         ])
 302 ])
 303
 304 CFLAGS=$saved_CFLAGS
 305
 306 AC_CONFIG_LINKS([
 307         urcu/arch.h:$ARCHSRC
 308         urcu/uatomic.h:$UATOMICSRC
 309 ])
 310 AC_CONFIG_FILES([
 311         Makefile
 312         doc/Makefile
 313         doc/examples/Makefile
 314         tests/Makefile
 315         tests/common/Makefile
 316         tests/unit/Makefile
 317         tests/benchmark/Makefile
 318         tests/regression/Makefile
 319         liburcu.pc
 320         liburcu-bp.pc
 321         liburcu-cds.pc
 322         liburcu-qsbr.pc
 323         liburcu-mb.pc
 324         liburcu-signal.pc
 325 ])
 326 AC_OUTPUT
 327
 328 # Report on selected configure options
 329 AS_IF([test "x$def_smp_support" = "xyes"],[
 330         AS_ECHO("SMP support enabled.")
 331 ],[
 332         AS_ECHO("SMP support disabled.")
 333 ])
 334
 335 AS_IF([test "x$def_tls_detect" = "x"],[
 336         AS_ECHO("Thread Local Storage (TLS): pthread_getspecific().")
 337 ],[
 338         AS_ECHO("Thread Local Storage (TLS): $def_tls_detect.")
 339 ])