[urcu.git] / configure.ac

AC_PREREQ(2.59)
AC_INIT([userspace-rcu],[0.8.0],[mathieu dot desnoyers at efficios dot com], [], [http://liburcu.org/])

# Following the numbering scheme proposed by libtool for the library version
# http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
AC_SUBST([URCU_LIBRARY_VERSION], [3:0:0])

AC_CONFIG_SRCDIR([urcu.h])
AC_CONFIG_HEADERS([config.h urcu/config.h])
AC_CONFIG_AUX_DIR([config])
AC_CONFIG_MACRO_DIR([m4])

AC_CANONICAL_TARGET
AC_CANONICAL_HOST

AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip])
AM_MAINTAINER_MODE([enable])

# Enable silent rules if available (Introduced in AM 1.11)
m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])

AH_TEMPLATE([CONFIG_RCU_SMP], [Enable SMP support. With SMP support enabled, uniprocessors are also supported. With SMP support disabled, UP systems work fine, but the behavior of SMP systems is undefined.])
AH_TEMPLATE([CONFIG_RCU_HAVE_FENCE], [Defined when on a system that has memory fence instructions.])
AH_TEMPLATE([CONFIG_RCU_HAVE_FUTEX], [Defined when on a system with futex support.])
AH_TEMPLATE([CONFIG_RCU_COMPAT_ARCH], [Compatibility mode for i386 which lacks cmpxchg instruction.])
AH_TEMPLATE([CONFIG_RCU_ARM_HAVE_DMB], [Use the dmb instruction if available for use on ARM.])
AH_TEMPLATE([CONFIG_RCU_TLS], [TLS provided by the compiler.])

# Allow overriding storage used for TLS variables.
AC_ARG_ENABLE([compiler-tls],
	AS_HELP_STRING([--disable-compiler-tls], [Use pthread_getspecific() to emulate Thread Local Storage (TLS) variables.]),
	[def_compiler_tls=$enableval],
	[def_compiler_tls="yes"])

# If not overridden, use ax_tls.m4 to check if TLS is available.
AS_IF([test "x$def_compiler_tls" = "xyes"],
	[AX_TLS([def_tls_detect=$ac_cv_tls], [:])],
	[:])

AS_IF([test "x$def_tls_detect" = "x"],
	[:],
	[AC_DEFINE_UNQUOTED([CONFIG_RCU_TLS], $def_tls_detect)])

# Checks for C compiler
AC_USE_SYSTEM_EXTENSIONS
AC_PROG_CC
AC_PROG_CC_STDC

# Checks for programs.
AC_PROG_MAKE_SET
AC_CHECK_PROGS(NPROC, [nproc gnproc])
LT_INIT

# Checks for typedefs, structures, and compiler characteristics.
AC_C_INLINE
AC_TYPE_PID_T
AC_TYPE_SIZE_T
AC_TYPE_INT32_T
AC_TYPE_UINT32_T
AC_TYPE_UINT64_T
AC_TYPE_UINT8_T

AX_C___ATTRIBUTE__
AS_IF([test "x$ax_cv___attribute__" = "xyes"],
	[:],
	[AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])

AX_PTHREAD(,[AC_MSG_ERROR([Could not configure pthreads support])])
LIBS="$PTHREAD_LIBS $LIBS"
CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
CC="$PTHREAD_CC"

# Checks for library functions.
AC_FUNC_MALLOC
AC_FUNC_MMAP
AC_CHECK_FUNCS(
	[memset gettimeofday munmap sched_getcpu getcpuid strtoul sysconf gettid memeset strerror]
)

# Check for headers
AC_CHECK_HEADERS([limits.h stddef.h sys/time.h])

# Find arch type
AS_CASE([$host_cpu],
	[i386], [ARCHTYPE="x86" && SUBARCHTYPE="x86compat"],
	[i486], [ARCHTYPE="x86"],
	[i586], [ARCHTYPE="x86"],
	[i686], [ARCHTYPE="x86"],
	[amd64], [ARCHTYPE="x86"],
	[x86_64], [ARCHTYPE="x86"],
	[powerpc], [ARCHTYPE="ppc"],
	[ppc64], [ARCHTYPE="ppc"],
	[powerpc64], [ARCHTYPE="ppc"],
	[powerpc64le], [ARCHTYPE="ppc"],
	[ppc], [ARCHTYPE="ppc"],
	[s390], [ARCHTYPE="s390"],
	[s390x], [ARCHTYPE="s390"],
	[sparc], [ARCHTYPE="sparc64"],
	[sparc64], [ARCHTYPE="sparc64"],
	[alpha*], [ARCHTYPE="alpha"],
	[ia64], [ARCHTYPE="ia64"],
	[arm*], [ARCHTYPE="arm"],
	[aarch64], [ARCHTYPE="aarch64"],
	[mips*], [ARCHTYPE="mips"],
	[tile*], [ARCHTYPE="tile"],
	[hppa*], [ARCHTYPE="hppa"],
	[ARCHTYPE="unknown"]
)

AS_CASE([$host],[*-*-linux-androideabi],
	[AM_CONDITIONAL(TARGET_IS_ANDROID, true)],
	[AM_CONDITIONAL(TARGET_IS_ANDROID, false)]
)

AC_SUBST(ARCHTYPE)
AC_SUBST(SUBARCHTYPE)

UATOMICSRC=urcu/uatomic/$ARCHTYPE.h
ARCHSRC=urcu/arch/$ARCHTYPE.h

AS_IF([test "x$SUBARCHTYPE" = xx86compat],[
	AC_DEFINE([CONFIG_RCU_COMPAT_ARCH], [1])
])

AS_IF([test "$host_cpu" = "armv7l"],[
	CFLAGS="$CFLAGS -mcpu=cortex-a9 -mtune=cortex-a9 -O1"
])

# ARM-specific checks
AS_IF([test "x$ARCHTYPE" = "xarm"],[
	AC_MSG_CHECKING([for dmb instruction])
	AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
				int main()
				{
					asm volatile("dmb":::"memory");
					return 0;
				}
		]])
	],[
		AC_MSG_RESULT([yes])
		AC_DEFINE([CONFIG_RCU_ARM_HAVE_DMB], [1])
	],[
		AC_MSG_RESULT([no])
	])
])

# Tile-specific checks
AS_IF([echo "$host_cpu" | grep "^tile"],[
	AC_MSG_CHECKING([for Tile architecture type])
	AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
				#ifndef __tilegx__
				#error
				#endif
		]])
	],[
		AC_MSG_RESULT([ok])
	],[
		AC_MSG_FAILURE([URCU has only been tested on the TileGx architecture. For other Tile* architectures, please run the tests first and report the results to the maintainer so that proper support can be added.])
	])
])

# x86-specific checks
AS_IF([test "x$ARCHTYPE" = "xx86"],[
	AC_MSG_CHECKING([if architecture really supports the mfence instruction])
	#For now, using lock; addl compatibility mode even for i686, because the
	#Pentium III is seen as a i686, but lacks mfence instruction.
	#Only using fence for x86_64.
	#
	#k1om is the name for the Intel MIC family (Xeon Phi). It is an x86_64
	#variant but lacks fence instructions.
	AS_IF([test "x$host_cpu" != "xi386" -a "x$host_cpu" != "xi486" -a "x$host_cpu" != "xi586" -a "x$host_cpu" != "xi686" -a "x$host_vendor" != "xk1om"],[
		AC_MSG_RESULT([yes])
		AC_DEFINE([CONFIG_RCU_HAVE_FENCE], [1])
	],[
		AC_MSG_RESULT([no])
	])
])

# Check if sys_futex() is available
AC_MSG_CHECKING([for sys_futex()])
AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
		#include <sys/syscall.h>
		#ifndef __NR_futex
		#error "futexes not available"
		#endif
	]])
],[
	AC_MSG_RESULT([yes])
	AC_DEFINE([CONFIG_RCU_HAVE_FUTEX], [1])
	compat_futex_test=0
],[
	AC_MSG_RESULT([no])
	compat_futex_test=1
])

# Check for pthread
AC_CHECK_LIB([pthread], [pthread_create],
	[AM_CONDITIONAL(LIBC_INCLUDES_PTHREAD, false)],
	[AC_CHECK_LIB([c], [pthread_create],
		[AM_CONDITIONAL(LIBC_INCLUDES_PTHREAD, true)],
		[AC_MSG_ERROR([Cannot find libpthread. Use [LDFLAGS]=-Ldir to specify its location.])]
	)]
)

AM_CONDITIONAL([COMPAT_FUTEX], [test "x$compat_futex_test" = "x1"])
AM_CONDITIONAL([COMPAT_ARCH], [test "x$SUBARCHTYPE" = "xx86compat"])
AM_CONDITIONAL([NO_SHARED], [test "x$enable_shared" = "xno"])

# smp-support configure option
AC_ARG_ENABLE([smp-support], 
	AS_HELP_STRING([--disable-smp-support], [Disable SMP support. Warning: only use this on uniprocessor systems. [default=enabled]]),
	[def_smp_support=$enableval],
	[def_smp_support="yes"])
AS_IF([test "x$def_smp_support" = "xyes"], [AC_DEFINE([CONFIG_RCU_SMP], [1])])


# From the sched_setaffinity(2)'s man page:
# ~~~~
# The CPU affinity system calls were introduced in Linux kernel 2.5.8.
# The library interfaces were introduced in glibc 2.3.  Initially, the
# glibc interfaces included a cpusetsize argument.  In glibc 2.3.3,
# the cpuset size argument was removed, but this argument was
# restored in glibc 2.3.4.
# ~~~~

# In addition to that, some vendors ported the system call to 2.4
# kernels.

# Furthermore, when the function first appeared, the MASK argument was
# an unsigned long pointer, while later it was made into a cpu_set_t
# pointer.  Systems that have the cpu_set_t version also should have
# the CPU_ZERO, CPU_SET, etc. macros.

# All this mess means we have to cater for at least 3 different
# sched_setaffinity prototypes:

# ~~~~
#  int sched_setaffinity (pid_t pid, unsigned int len, unsigned long *mask);
#  int sched_setaffinity (pid_t __pid, size_t __cpusetsize, const cpu_set_t *__cpuset);
#  int sched_setaffinity (pid_t __pid, const cpu_set_t *__mask);
# ~~~~

# Since we define _GNU_SOURCE in the sources, must do so too in the
# autoconf tests, as defining _GNU_SOURCE or not exposes
# sched_setaffinity bits differently.
saved_CFLAGS=$CFLAGS
CFLAGS="$CFLAGS -D_GNU_SOURCE"

AC_CHECK_TYPES([cpu_set_t],
	[have_cpu_set_t="yes"],
	[have_cpu_set_t="no"],
	[#include <sched.h>])

# Confirm that we have CPU_ZERO, and it actually works.
AC_MSG_CHECKING([whether CPU_ZERO works])
AH_TEMPLATE([HAVE_CPU_ZERO], [Defined to 1 if we have CPU_ZERO and it works])
AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
		#define _GNU_SOURCE
		#include <sched.h>
		int main()
		{
			cpu_set_t foo; CPU_ZERO(&foo);
			return 0;
		}
	]])
],[
	AC_DEFINE(HAVE_CPU_ZERO, 1)
	AC_MSG_RESULT([yes])
],[
	AC_MSG_RESULT([no])
])

# Confirm that we have CPU_SET, and it actually works.
AC_MSG_CHECKING([whether CPU_SET works])
AH_TEMPLATE([HAVE_CPU_SET], [Defined to 1 if we have CPU_SET and it works])
AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
		#define _GNU_SOURCE
		#include <sched.h>
		int main()
		{
			cpu_set_t foo, mask; CPU_SET(0, &foo);
			return 0;
		}
	]])
],[
	AC_DEFINE(HAVE_CPU_SET, 1)
	AC_MSG_RESULT([yes])
],[
	AC_MSG_RESULT([no])
])

# First check if the function is available at all.
AC_CHECK_FUNCS([sched_setaffinity],[
	# Okay, we have it.  Check if also have cpu_set_t.  If we don't,
	# then we have the first version using unsigned long, and no
	# CPU_ZERO, etc. macros.  If we do have cpu_set_t, we may have the
	# version with 2 or 3 arguments.  In that case, CPU_ZERO, etc.,
	# should also be present, but we confirm nonetheless.

	AS_IF([test "x$have_cpu_set_t" = "xyes"], [
		# We do have it.
		# Check how many arguments does sched_setaffinity take.
		# Should be 3 or 2.
		AC_MSG_CHECKING([how many arguments sched_setaffinity takes])
		AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
				#include <sched.h>
				int main()
				{
					cpu_set_t foo;
					sched_setaffinity(0, sizeof (foo), &foo);
					return 0;
				}
			]])
		],
		[sched_set_affinity_args=3],
		[sched_set_affinity_args=2])
		AC_DEFINE_UNQUOTED(SCHED_SETAFFINITY_ARGS,
			$sched_set_affinity_args,
			[Defined to sched_setaffinity's number of arguments.])
		AC_MSG_RESULT([$sched_set_affinity_args])
	],[
		# No cpu_set_t, always 3 args.
		AC_DEFINE(SCHED_SETAFFINITY_ARGS, 3)
	])
])

CFLAGS=$saved_CFLAGS

AC_CONFIG_LINKS([
	urcu/arch.h:$ARCHSRC
	urcu/uatomic.h:$UATOMICSRC
])
AC_CONFIG_FILES([
	Makefile
	doc/Makefile
	doc/examples/Makefile
	tests/Makefile
	tests/common/Makefile
	tests/unit/Makefile
	tests/benchmark/Makefile
	tests/regression/Makefile
	tests/regression/regression_tests
	tests/utils/Makefile
	liburcu.pc
	liburcu-bp.pc
	liburcu-cds.pc
	liburcu-qsbr.pc
	liburcu-mb.pc
	liburcu-signal.pc
])
AC_OUTPUT

# Report on selected configure options
AS_IF([test "x$def_smp_support" = "xyes"],[
	AS_ECHO("SMP support enabled.")
],[
	AS_ECHO("SMP support disabled.")
])

AS_IF([test "x$def_tls_detect" = "x"],[
	AS_ECHO("Thread Local Storage (TLS): pthread_getspecific().")
],[
	AS_ECHO("Thread Local Storage (TLS): $def_tls_detect.")
])
Commit	Line	Data
	1	AC_PREREQ(2.59)
	2	AC_INIT([userspace-rcu],[0.8.0],[mathieu dot desnoyers at efficios dot com], [], [http://liburcu.org/])
	3
	4	# Following the numbering scheme proposed by libtool for the library version
	5	# http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
	6	AC_SUBST([URCU_LIBRARY_VERSION], [3:0:0])
	7
	8	AC_CONFIG_SRCDIR([urcu.h])
	9	AC_CONFIG_HEADERS([config.h urcu/config.h])
	10	AC_CONFIG_AUX_DIR([config])
	11	AC_CONFIG_MACRO_DIR([m4])
	12
	13	AC_CANONICAL_TARGET
	14	AC_CANONICAL_HOST
	15
	16	AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip])
	17	AM_MAINTAINER_MODE([enable])
	18
	19	# Enable silent rules if available (Introduced in AM 1.11)
	20	m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
	21
	22	AH_TEMPLATE([CONFIG_RCU_SMP], [Enable SMP support. With SMP support enabled, uniprocessors are also supported. With SMP support disabled, UP systems work fine, but the behavior of SMP systems is undefined.])
	23	AH_TEMPLATE([CONFIG_RCU_HAVE_FENCE], [Defined when on a system that has memory fence instructions.])
	24	AH_TEMPLATE([CONFIG_RCU_HAVE_FUTEX], [Defined when on a system with futex support.])
	25	AH_TEMPLATE([CONFIG_RCU_COMPAT_ARCH], [Compatibility mode for i386 which lacks cmpxchg instruction.])
	26	AH_TEMPLATE([CONFIG_RCU_ARM_HAVE_DMB], [Use the dmb instruction if available for use on ARM.])
	27	AH_TEMPLATE([CONFIG_RCU_TLS], [TLS provided by the compiler.])
	28
	29	# Allow overriding storage used for TLS variables.
	30	AC_ARG_ENABLE([compiler-tls],
	31	AS_HELP_STRING([--disable-compiler-tls], [Use pthread_getspecific() to emulate Thread Local Storage (TLS) variables.]),
	32	[def_compiler_tls=$enableval],
	33	[def_compiler_tls="yes"])
	34
	35	# If not overridden, use ax_tls.m4 to check if TLS is available.
	36	AS_IF([test "x$def_compiler_tls" = "xyes"],
	37	[AX_TLS([def_tls_detect=$ac_cv_tls], [:])],
	38	[:])
	39
	40	AS_IF([test "x$def_tls_detect" = "x"],
	41	[:],
	42	[AC_DEFINE_UNQUOTED([CONFIG_RCU_TLS], $def_tls_detect)])
	43
	44	# Checks for C compiler
	45	AC_USE_SYSTEM_EXTENSIONS
	46	AC_PROG_CC
	47	AC_PROG_CC_STDC
	48
	49	# Checks for programs.
	50	AC_PROG_MAKE_SET
	51	AC_CHECK_PROGS(NPROC, [nproc gnproc])
	52	LT_INIT
	53
	54	# Checks for typedefs, structures, and compiler characteristics.
	55	AC_C_INLINE
	56	AC_TYPE_PID_T
	57	AC_TYPE_SIZE_T
	58	AC_TYPE_INT32_T
	59	AC_TYPE_UINT32_T
	60	AC_TYPE_UINT64_T
	61	AC_TYPE_UINT8_T
	62
	63	AX_C___ATTRIBUTE__
	64	AS_IF([test "x$ax_cv___attribute__" = "xyes"],
	65	[:],
	66	[AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])
	67
	68	AX_PTHREAD(,[AC_MSG_ERROR([Could not configure pthreads support])])
	69	LIBS="$PTHREAD_LIBS $LIBS"
	70	CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
	71	CC="$PTHREAD_CC"
	72
	73	# Checks for library functions.
	74	AC_FUNC_MALLOC
	75	AC_FUNC_MMAP
	76	AC_CHECK_FUNCS(
	77	[memset gettimeofday munmap sched_getcpu getcpuid strtoul sysconf gettid memeset strerror]
	78	)
	79
	80	# Check for headers
	81	AC_CHECK_HEADERS([limits.h stddef.h sys/time.h])
	82
	83	# Find arch type
	84	AS_CASE([$host_cpu],
	85	[i386], [ARCHTYPE="x86" && SUBARCHTYPE="x86compat"],
	86	[i486], [ARCHTYPE="x86"],
	87	[i586], [ARCHTYPE="x86"],
	88	[i686], [ARCHTYPE="x86"],
	89	[amd64], [ARCHTYPE="x86"],
	90	[x86_64], [ARCHTYPE="x86"],
	91	[powerpc], [ARCHTYPE="ppc"],
	92	[ppc64], [ARCHTYPE="ppc"],
	93	[powerpc64], [ARCHTYPE="ppc"],
	94	[powerpc64le], [ARCHTYPE="ppc"],
	95	[ppc], [ARCHTYPE="ppc"],
	96	[s390], [ARCHTYPE="s390"],
	97	[s390x], [ARCHTYPE="s390"],
	98	[sparc], [ARCHTYPE="sparc64"],
	99	[sparc64], [ARCHTYPE="sparc64"],
	100	[alpha*], [ARCHTYPE="alpha"],
	101	[ia64], [ARCHTYPE="ia64"],
	102	[arm*], [ARCHTYPE="arm"],
	103	[aarch64], [ARCHTYPE="aarch64"],
	104	[mips*], [ARCHTYPE="mips"],
	105	[tile*], [ARCHTYPE="tile"],
	106	[hppa*], [ARCHTYPE="hppa"],
	107	[ARCHTYPE="unknown"]
	108	)
	109
	110	AS_CASE([$host],[--linux-androideabi],
	111	[AM_CONDITIONAL(TARGET_IS_ANDROID, true)],
	112	[AM_CONDITIONAL(TARGET_IS_ANDROID, false)]
	113	)
	114
	115	AC_SUBST(ARCHTYPE)
	116	AC_SUBST(SUBARCHTYPE)
	117
	118	UATOMICSRC=urcu/uatomic/$ARCHTYPE.h
	119	ARCHSRC=urcu/arch/$ARCHTYPE.h
	120
	121	AS_IF([test "x$SUBARCHTYPE" = xx86compat],[
	122	AC_DEFINE([CONFIG_RCU_COMPAT_ARCH], [1])
	123	])
	124
	125	AS_IF([test "$host_cpu" = "armv7l"],[
	126	CFLAGS="$CFLAGS -mcpu=cortex-a9 -mtune=cortex-a9 -O1"
	127	])
	128
	129	# ARM-specific checks
	130	AS_IF([test "x$ARCHTYPE" = "xarm"],[
	131	AC_MSG_CHECKING([for dmb instruction])
	132	AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
	133	int main()
	134	{
	135	asm volatile("dmb":::"memory");
	136	return 0;
	137	}
	138	]])
	139	],[
	140	AC_MSG_RESULT([yes])
	141	AC_DEFINE([CONFIG_RCU_ARM_HAVE_DMB], [1])
	142	],[
	143	AC_MSG_RESULT([no])
	144	])
	145	])
	146
	147	# Tile-specific checks
	148	AS_IF([echo "$host_cpu" \| grep "^tile"],[
	149	AC_MSG_CHECKING([for Tile architecture type])
	150	AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
	151	#ifndef __tilegx__
	152	#error
	153	#endif
	154	]])
	155	],[
	156	AC_MSG_RESULT([ok])
	157	],[
	158	AC_MSG_FAILURE([URCU has only been tested on the TileGx architecture. For other Tile* architectures, please run the tests first and report the results to the maintainer so that proper support can be added.])
	159	])
	160	])
	161
	162	# x86-specific checks
	163	AS_IF([test "x$ARCHTYPE" = "xx86"],[
	164	AC_MSG_CHECKING([if architecture really supports the mfence instruction])
	165	#For now, using lock; addl compatibility mode even for i686, because the
	166	#Pentium III is seen as a i686, but lacks mfence instruction.
	167	#Only using fence for x86_64.
	168	#
	169	#k1om is the name for the Intel MIC family (Xeon Phi). It is an x86_64
	170	#variant but lacks fence instructions.
	171	AS_IF([test "x$host_cpu" != "xi386" -a "x$host_cpu" != "xi486" -a "x$host_cpu" != "xi586" -a "x$host_cpu" != "xi686" -a "x$host_vendor" != "xk1om"],[
	172	AC_MSG_RESULT([yes])
	173	AC_DEFINE([CONFIG_RCU_HAVE_FENCE], [1])
	174	],[
	175	AC_MSG_RESULT([no])
	176	])
	177	])
	178
	179	# Check if sys_futex() is available
	180	AC_MSG_CHECKING([for sys_futex()])
	181	AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
	182	#include <sys/syscall.h>
	183	#ifndef __NR_futex
	184	#error "futexes not available"
	185	#endif
	186	]])
	187	],[
	188	AC_MSG_RESULT([yes])
	189	AC_DEFINE([CONFIG_RCU_HAVE_FUTEX], [1])
	190	compat_futex_test=0
	191	],[
	192	AC_MSG_RESULT([no])
	193	compat_futex_test=1
	194	])
	195
	196	# Check for pthread
	197	AC_CHECK_LIB([pthread], [pthread_create],
	198	[AM_CONDITIONAL(LIBC_INCLUDES_PTHREAD, false)],
	199	[AC_CHECK_LIB([c], [pthread_create],
	200	[AM_CONDITIONAL(LIBC_INCLUDES_PTHREAD, true)],
	201	[AC_MSG_ERROR([Cannot find libpthread. Use [LDFLAGS]=-Ldir to specify its location.])]
	202	)]
	203	)
	204
	205	AM_CONDITIONAL([COMPAT_FUTEX], [test "x$compat_futex_test" = "x1"])
	206	AM_CONDITIONAL([COMPAT_ARCH], [test "x$SUBARCHTYPE" = "xx86compat"])
	207	AM_CONDITIONAL([NO_SHARED], [test "x$enable_shared" = "xno"])
	208
	209	# smp-support configure option
	210	AC_ARG_ENABLE([smp-support],
	211	AS_HELP_STRING([--disable-smp-support], [Disable SMP support. Warning: only use this on uniprocessor systems. [default=enabled]]),
	212	[def_smp_support=$enableval],
	213	[def_smp_support="yes"])
	214	AS_IF([test "x$def_smp_support" = "xyes"], [AC_DEFINE([CONFIG_RCU_SMP], [1])])
	215
	216
	217	# From the sched_setaffinity(2)'s man page:
	218	# ~~~~
	219	# The CPU affinity system calls were introduced in Linux kernel 2.5.8.
	220	# The library interfaces were introduced in glibc 2.3. Initially, the
	221	# glibc interfaces included a cpusetsize argument. In glibc 2.3.3,
	222	# the cpuset size argument was removed, but this argument was
	223	# restored in glibc 2.3.4.
	224	# ~~~~
	225
	226	# In addition to that, some vendors ported the system call to 2.4
	227	# kernels.
	228
	229	# Furthermore, when the function first appeared, the MASK argument was
	230	# an unsigned long pointer, while later it was made into a cpu_set_t
	231	# pointer. Systems that have the cpu_set_t version also should have
	232	# the CPU_ZERO, CPU_SET, etc. macros.
	233
	234	# All this mess means we have to cater for at least 3 different
	235	# sched_setaffinity prototypes:
	236
	237	# ~~~~
	238	# int sched_setaffinity (pid_t pid, unsigned int len, unsigned long *mask);
	239	# int sched_setaffinity (pid_t __pid, size_t __cpusetsize, const cpu_set_t *__cpuset);
	240	# int sched_setaffinity (pid_t __pid, const cpu_set_t *__mask);
	241	# ~~~~
	242
	243	# Since we define _GNU_SOURCE in the sources, must do so too in the
	244	# autoconf tests, as defining _GNU_SOURCE or not exposes
	245	# sched_setaffinity bits differently.
	246	saved_CFLAGS=$CFLAGS
	247	CFLAGS="$CFLAGS -D_GNU_SOURCE"
	248
	249	AC_CHECK_TYPES([cpu_set_t],
	250	[have_cpu_set_t="yes"],
	251	[have_cpu_set_t="no"],
	252	[#include <sched.h>])
	253
	254	# Confirm that we have CPU_ZERO, and it actually works.
	255	AC_MSG_CHECKING([whether CPU_ZERO works])
	256	AH_TEMPLATE([HAVE_CPU_ZERO], [Defined to 1 if we have CPU_ZERO and it works])
	257	AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
	258	#define _GNU_SOURCE
	259	#include <sched.h>
	260	int main()
	261	{
	262	cpu_set_t foo; CPU_ZERO(&foo);
	263	return 0;
	264	}
	265	]])
	266	],[
	267	AC_DEFINE(HAVE_CPU_ZERO, 1)
	268	AC_MSG_RESULT([yes])
	269	],[
	270	AC_MSG_RESULT([no])
	271	])
	272
	273	# Confirm that we have CPU_SET, and it actually works.
	274	AC_MSG_CHECKING([whether CPU_SET works])
	275	AH_TEMPLATE([HAVE_CPU_SET], [Defined to 1 if we have CPU_SET and it works])
	276	AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
	277	#define _GNU_SOURCE
	278	#include <sched.h>
	279	int main()
	280	{
	281	cpu_set_t foo, mask; CPU_SET(0, &foo);
	282	return 0;
	283	}
	284	]])
	285	],[
	286	AC_DEFINE(HAVE_CPU_SET, 1)
	287	AC_MSG_RESULT([yes])
	288	],[
	289	AC_MSG_RESULT([no])
	290	])
	291
	292	# First check if the function is available at all.
	293	AC_CHECK_FUNCS([sched_setaffinity],[
	294	# Okay, we have it. Check if also have cpu_set_t. If we don't,
	295	# then we have the first version using unsigned long, and no
	296	# CPU_ZERO, etc. macros. If we do have cpu_set_t, we may have the
	297	# version with 2 or 3 arguments. In that case, CPU_ZERO, etc.,
	298	# should also be present, but we confirm nonetheless.
	299
	300	AS_IF([test "x$have_cpu_set_t" = "xyes"], [
	301	# We do have it.
	302	# Check how many arguments does sched_setaffinity take.
	303	# Should be 3 or 2.
	304	AC_MSG_CHECKING([how many arguments sched_setaffinity takes])
	305	AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
	306	#include <sched.h>
	307	int main()
	308	{
	309	cpu_set_t foo;
	310	sched_setaffinity(0, sizeof (foo), &foo);
	311	return 0;
	312	}
	313	]])
	314	],
	315	[sched_set_affinity_args=3],
	316	[sched_set_affinity_args=2])
	317	AC_DEFINE_UNQUOTED(SCHED_SETAFFINITY_ARGS,
	318	$sched_set_affinity_args,
	319	[Defined to sched_setaffinity's number of arguments.])
	320	AC_MSG_RESULT([$sched_set_affinity_args])
	321	],[
	322	# No cpu_set_t, always 3 args.
	323	AC_DEFINE(SCHED_SETAFFINITY_ARGS, 3)
	324	])
	325	])
	326
	327	CFLAGS=$saved_CFLAGS
	328
	329	AC_CONFIG_LINKS([
	330	urcu/arch.h:$ARCHSRC
	331	urcu/uatomic.h:$UATOMICSRC
	332	])
	333	AC_CONFIG_FILES([
	334	Makefile
	335	doc/Makefile
	336	doc/examples/Makefile
	337	tests/Makefile
	338	tests/common/Makefile
	339	tests/unit/Makefile
	340	tests/benchmark/Makefile
	341	tests/regression/Makefile
	342	tests/regression/regression_tests
	343	tests/utils/Makefile
	344	liburcu.pc
	345	liburcu-bp.pc
	346	liburcu-cds.pc
	347	liburcu-qsbr.pc
	348	liburcu-mb.pc
	349	liburcu-signal.pc
	350	])
	351	AC_OUTPUT
	352
	353	# Report on selected configure options
	354	AS_IF([test "x$def_smp_support" = "xyes"],[
	355	AS_ECHO("SMP support enabled.")
	356	],[
	357	AS_ECHO("SMP support disabled.")
	358	])
	359
	360	AS_IF([test "x$def_tls_detect" = "x"],[
	361	AS_ECHO("Thread Local Storage (TLS): pthread_getspecific().")
	362	],[
	363	AS_ECHO("Thread Local Storage (TLS): $def_tls_detect.")
	364	])