projects / urcu.git / blame_incremental
? search:
summary | shortlog | log | commit | commitdiff | tree
blob | blame (non-incremental) | history | HEAD
Fix: urcu/futex.h: users of struct timespec should include time.h
[urcu.git] / configure.ac
... / ...
CommitLineData
1AC_PREREQ(2.59)
2AC_INIT([userspace-rcu],[0.11.0],[mathieu dot desnoyers at efficios dot com], [], [http://liburcu.org/])
3
4# Following the numbering scheme proposed by libtool for the library version
5# http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
6AC_SUBST([URCU_LIBRARY_VERSION], [6:0:1])
7
8AC_CONFIG_HEADERS([include/config.h include/urcu/config.h])
9AC_CONFIG_AUX_DIR([config])
10AC_CONFIG_MACRO_DIR([m4])
11
12AC_CANONICAL_TARGET
13AC_CANONICAL_HOST
14
15AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip nostdinc])
16AM_MAINTAINER_MODE([enable])
17
18# Enable silent rules if available (Introduced in AM 1.11)
19m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
20
21AC_REQUIRE_AUX_FILE([tap-driver.sh])
22
23AH_TEMPLATE([CONFIG_RCU_SMP], [Enable SMP support. With SMP support enabled, uniprocessors are also supported. With SMP support disabled, UP systems work fine, but the behavior of SMP systems is undefined.])
24AH_TEMPLATE([CONFIG_RCU_HAVE_FENCE], [Defined when on a system that has memory fence instructions.])
25AH_TEMPLATE([CONFIG_RCU_HAVE_FUTEX], [Defined when on a system with futex support.])
26AH_TEMPLATE([CONFIG_RCU_COMPAT_ARCH], [Compatibility mode for i386 which lacks cmpxchg instruction.])
27AH_TEMPLATE([CONFIG_RCU_ARM_HAVE_DMB], [Use the dmb instruction if available for use on ARM.])
28AH_TEMPLATE([CONFIG_RCU_TLS], [TLS provided by the compiler.])
29AH_TEMPLATE([CONFIG_RCU_HAVE_CLOCK_GETTIME], [clock_gettime() is detected.])
30AH_TEMPLATE([CONFIG_RCU_FORCE_SYS_MEMBARRIER], [Require the operating system to support the membarrier system call for default and bulletproof flavors.])
31AH_TEMPLATE([CONFIG_RCU_DEBUG], [Enable internal debugging self-checks. Introduce performance penalty.])
32AH_TEMPLATE([CONFIG_CDS_LFHT_ITER_DEBUG], [Enable extra debugging checks for lock-free hash table iterator traversal. Alters the rculfhash ABI. Make sure to compile both library and application with matching configuration.])
33
34# Allow requiring the operating system to support the membarrier system
35# call. Applies to default and bulletproof flavors.
36AC_ARG_ENABLE([sys-membarrier-fallback],
37 AS_HELP_STRING([--disable-sys-membarrier-fallback], [Abort if sys-membarrier is needed but not available rather than using a fallback.]),
38 [def_sys_membarrier_fallback=$enableval],
39 [def_sys_membarrier_fallback="yes"])
40AS_IF([test "x$def_sys_membarrier_fallback" != "xyes"], [AC_DEFINE([CONFIG_RCU_FORCE_SYS_MEMBARRIER], [1])])
41
42# Allow overriding storage used for TLS variables.
43AC_ARG_ENABLE([compiler-tls],
44 AS_HELP_STRING([--disable-compiler-tls], [Use pthread_getspecific() to emulate Thread Local Storage (TLS) variables.]),
45 [def_compiler_tls=$enableval],
46 [def_compiler_tls="yes"])
47
48# Checks for C compiler
49AC_USE_SYSTEM_EXTENSIONS
50AC_PROG_CC
51AC_PROG_CC_STDC
52
53# If not overridden, use ax_tls.m4 to check if TLS is available.
54AS_IF([test "x$def_compiler_tls" = "xyes"],
55 [AX_TLS([def_tls_detect=$ac_cv_tls], [:])],
56 [:])
57
58AS_IF([test "x$def_tls_detect" = "x"],
59 [:],
60 [AC_DEFINE_UNQUOTED([CONFIG_RCU_TLS], $def_tls_detect)])
61
62# Checks for programs.
63AC_PROG_AWK
64AC_PROG_MAKE_SET
65AC_CHECK_PROGS(NPROC, [nproc gnproc])
66AC_CHECK_PROGS(GETCONF, [getconf])
67AS_IF([test "x$NPROC" != "x"],
68 [NPROC_CMD=$NPROC],
69 [AS_IF([test "x$GETCONF" != "x"],
70 [NPROC_CMD="$GETCONF _NPROCESSORS_ONLN"],
71 [NPROC_CMD="echo 1"]
72 )]
73)
74AC_SUBST([NPROC_CMD], [$NPROC_CMD])
75
76LT_INIT
77
78# Checks for typedefs, structures, and compiler characteristics.
79AC_C_INLINE
80AC_TYPE_PID_T
81AC_TYPE_SIZE_T
82AC_TYPE_SSIZE_T
83AC_TYPE_UINT16_T
84AC_TYPE_INT32_T
85AC_TYPE_UINT32_T
86AC_TYPE_UINT64_T
87AC_TYPE_UINT8_T
88
89AX_C___ATTRIBUTE__
90AS_IF([test "x$ax_cv___attribute__" = "xyes"],
91 [:],
92 [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])
93
94AX_PTHREAD(,[AC_MSG_ERROR([Could not configure pthreads support])])
95
96AM_CFLAGS="$AM_CFLAGS $PTHREAD_CFLAGS"
97
98# Checks for library functions.
99AC_FUNC_MMAP
100AC_FUNC_FORK
101AC_CHECK_FUNCS([ \
102 atexit \
103 getcpuid \
104 gettid \
105 gettimeofday \
106 memeset \
107 memset \
108 munmap \
109 rand_r \
110 sched_getcpu \
111 strerror \
112 strtoul \
113 sysconf \
114])
115
116# AC_FUNC_MALLOC causes problems when cross-compiling.
117#AC_FUNC_MALLOC
118
119# Check for headers
120AC_HEADER_STDBOOL
121AC_CHECK_HEADERS([ \
122 limits.h \
123 stddef.h \
124 sys/param.h \
125 sys/time.h \
126])
127
128# Find arch type
129AS_CASE([$host_cpu],
130 [k1om], [ARCHTYPE="x86"],
131 [i386], [ARCHTYPE="x86" && SUBARCHTYPE="x86compat"],
132 [i486], [ARCHTYPE="x86"],
133 [i586], [ARCHTYPE="x86"],
134 [i686], [ARCHTYPE="x86"],
135 [amd64], [ARCHTYPE="x86"],
136 [x86_64], [ARCHTYPE="x86"],
137 [powerpc], [ARCHTYPE="ppc"],
138 [ppc64], [ARCHTYPE="ppc"],
139 [powerpc64], [ARCHTYPE="ppc"],
140 [powerpc64le], [ARCHTYPE="ppc"],
141 [ppc], [ARCHTYPE="ppc"],
142 [s390], [ARCHTYPE="s390"],
143 [s390x], [ARCHTYPE="s390"],
144 [sparc], [ARCHTYPE="sparc64"],
145 [sparc64], [ARCHTYPE="sparc64"],
146 [alpha*], [ARCHTYPE="alpha"],
147 [ia64], [ARCHTYPE="ia64"],
148 [arm*], [ARCHTYPE="arm"],
149 [aarch64*], [ARCHTYPE="aarch64"],
150 [mips*], [ARCHTYPE="mips"],
151 [nios2*], [ARCHTYPE="nios2"],
152 [tile*], [ARCHTYPE="tile"],
153 [hppa*], [ARCHTYPE="hppa"],
154 [m68k], [ARCHTYPE="m68k"],
155 [riscv*], [ARCHTYPE="riscv"],
156 [ARCHTYPE="unknown"]
157)
158
159AS_CASE([$host],[*-cygwin*],
160 [AM_CONDITIONAL(USE_CYGWIN, true)],
161 [AM_CONDITIONAL(USE_CYGWIN, false)]
162)
163
164AC_SUBST(ARCHTYPE)
165AC_SUBST(SUBARCHTYPE)
166
167UATOMICSRC=include/urcu/uatomic/$ARCHTYPE.h
168ARCHSRC=include/urcu/arch/$ARCHTYPE.h
169
170AS_IF([test "x$SUBARCHTYPE" = xx86compat],[
171 AC_DEFINE([CONFIG_RCU_COMPAT_ARCH], [1])
172])
173
174AS_IF([test "$host_cpu" = "armv7l"],[
175 AM_CFLAGS="$AM_CFLAGS -mcpu=cortex-a9 -mtune=cortex-a9 -O1"
176])
177
178# ARM-specific checks
179AS_IF([test "x$ARCHTYPE" = "xarm"],[
180 AC_MSG_CHECKING([for dmb instruction])
181 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
182 int main()
183 {
184 asm volatile("dmb":::"memory");
185 return 0;
186 }
187 ]])
188 ],[
189 AC_MSG_RESULT([yes])
190 AC_DEFINE([CONFIG_RCU_ARM_HAVE_DMB], [1])
191 ],[
192 AC_MSG_RESULT([no])
193 ])
194])
195
196# Tile-specific checks
197AS_IF([echo "$host_cpu" | grep "^tile"],[
198 AC_MSG_CHECKING([for Tile architecture type])
199 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
200 #ifndef __tilegx__
201 #error
202 #endif
203 ]])
204 ],[
205 AC_MSG_RESULT([ok])
206 ],[
207 AC_MSG_FAILURE([URCU has only been tested on the TileGx architecture. For other Tile* architectures, please run the tests first and report the results to the maintainer so that proper support can be added.])
208 ])
209])
210
211# x86-specific checks
212AS_IF([test "x$ARCHTYPE" = "xx86"],[
213 AC_MSG_CHECKING([if architecture really supports the mfence instruction])
214 #For now, using lock; addl compatibility mode even for i686, because the
215 #Pentium III is seen as a i686, but lacks mfence instruction.
216 #Only using fence for x86_64.
217 #
218 #k1om is the name for the Intel MIC family (Xeon Phi). It is an x86_64
219 #variant but lacks fence instructions.
220 AS_IF([test "x$host_cpu" != "xi386" -a "x$host_cpu" != "xi486" -a "x$host_cpu" != "xi586" -a "x$host_cpu" != "xi686" -a "x$host_vendor" != "xk1om" -a "x$host_cpu" != "xk1om"],[
221 AC_MSG_RESULT([yes])
222 AC_DEFINE([CONFIG_RCU_HAVE_FENCE], [1])
223 config_rcu_have_fence=yes
224 ],[
225 AC_MSG_RESULT([no])
226 config_rcu_have_fence=no
227 ])
228])
229
230# Check if sys_futex() is available
231AC_MSG_CHECKING([for sys_futex()])
232AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
233 #include <sys/syscall.h>
234 #ifndef __NR_futex
235 #error "futexes not available"
236 #endif
237 ]])
238],[
239 AC_MSG_RESULT([yes])
240 AC_DEFINE([CONFIG_RCU_HAVE_FUTEX], [1])
241 compat_futex_test=0
242],[
243 AC_MSG_RESULT([no])
244 compat_futex_test=1
245])
246
247# Search for clock_gettime
248AC_SEARCH_LIBS([clock_gettime], [rt], [
249 AC_DEFINE([CONFIG_RCU_HAVE_CLOCK_GETTIME], [1])
250 config_rcu_have_clock_gettime=yes
251], [])
252
253AM_CONDITIONAL([COMPAT_FUTEX], [test "x$compat_futex_test" = "x1"])
254AM_CONDITIONAL([COMPAT_ARCH], [test "x$SUBARCHTYPE" = "xx86compat"])
255AM_CONDITIONAL([NO_SHARED], [test "x$enable_shared" = "xno"])
256
257# smp-support configure option
258AC_ARG_ENABLE([smp-support],
259 AS_HELP_STRING([--disable-smp-support], [Disable SMP support. Warning: only use this on uniprocessor systems. [default=enabled]]),
260 [def_smp_support=$enableval],
261 [def_smp_support="yes"])
262AS_IF([test "x$def_smp_support" = "xyes"], [AC_DEFINE([CONFIG_RCU_SMP], [1])])
263
264# RCU debugging option
265AC_ARG_ENABLE([rcu-debug],
266 AS_HELP_STRING([--enable-rcu-debug], [Enable internal debugging
267 self-checks. Introduce performance penalty.]))
268AS_IF([test "x$enable_rcu_debug" = "xyes"], [
269 AC_DEFINE([CONFIG_RCU_DEBUG], [1])
270])
271
272# rculfhash iterator debugging
273AC_ARG_ENABLE([cds-lfht-iter-debug],
274 AS_HELP_STRING([--enable-cds-lfht-iter-debug], [Enable extra debugging checks for lock-free hash table iterator traversal. Alters the rculfhash ABI. Make sure to compile both library and application with matching configuration.]))
275AS_IF([test "x$enable_cds_lfht_iter_debug" = "xyes"], [
276 AC_DEFINE([CONFIG_CDS_LFHT_ITER_DEBUG], [1])
277])
278
279# From the sched_setaffinity(2)'s man page:
280# ~~~~
281# The CPU affinity system calls were introduced in Linux kernel 2.5.8.
282# The library interfaces were introduced in glibc 2.3. Initially, the
283# glibc interfaces included a cpusetsize argument. In glibc 2.3.3,
284# the cpuset size argument was removed, but this argument was
285# restored in glibc 2.3.4.
286# ~~~~
287
288# In addition to that, some vendors ported the system call to 2.4
289# kernels.
290
291# Furthermore, when the function first appeared, the MASK argument was
292# an unsigned long pointer, while later it was made into a cpu_set_t
293# pointer. Systems that have the cpu_set_t version also should have
294# the CPU_ZERO, CPU_SET, etc. macros.
295
296# All this mess means we have to cater for at least 3 different
297# sched_setaffinity prototypes:
298
299# ~~~~
300# int sched_setaffinity (pid_t pid, unsigned int len, unsigned long *mask);
301# int sched_setaffinity (pid_t __pid, size_t __cpusetsize, const cpu_set_t *__cpuset);
302# int sched_setaffinity (pid_t __pid, const cpu_set_t *__mask);
303# ~~~~
304
305AC_CHECK_TYPES([cpu_set_t],
306 [have_cpu_set_t="yes"],
307 [have_cpu_set_t="no"],
308 [#include <sched.h>])
309
310# Confirm that we have CPU_ZERO, and it actually works.
311AC_MSG_CHECKING([whether CPU_ZERO works])
312AH_TEMPLATE([HAVE_CPU_ZERO], [Defined to 1 if we have CPU_ZERO and it works])
313AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
314 #include <sched.h>
315 int main()
316 {
317 cpu_set_t foo; CPU_ZERO(&foo);
318 return 0;
319 }
320 ]])
321],[
322 AC_DEFINE(HAVE_CPU_ZERO, 1)
323 AC_MSG_RESULT([yes])
324],[
325 AC_MSG_RESULT([no])
326])
327
328# Confirm that we have CPU_SET, and it actually works.
329AC_MSG_CHECKING([whether CPU_SET works])
330AH_TEMPLATE([HAVE_CPU_SET], [Defined to 1 if we have CPU_SET and it works])
331AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
332 #include <sched.h>
333 int main()
334 {
335 cpu_set_t foo, mask; CPU_SET(0, &foo);
336 return 0;
337 }
338 ]])
339],[
340 AC_DEFINE(HAVE_CPU_SET, 1)
341 AC_MSG_RESULT([yes])
342],[
343 AC_MSG_RESULT([no])
344])
345
346# First check if the function is available at all.
347AC_CHECK_FUNCS([sched_setaffinity],[
348 # Okay, we have it. Check if also have cpu_set_t. If we don't,
349 # then we have the first version using unsigned long, and no
350 # CPU_ZERO, etc. macros. If we do have cpu_set_t, we may have the
351 # version with 2 or 3 arguments. In that case, CPU_ZERO, etc.,
352 # should also be present, but we confirm nonetheless.
353
354 AS_IF([test "x$have_cpu_set_t" = "xyes"], [
355 # We do have it.
356 # Check how many arguments does sched_setaffinity take.
357 # Should be 3 or 2.
358 AC_MSG_CHECKING([how many arguments sched_setaffinity takes])
359 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
360 #include <sched.h>
361 int main()
362 {
363 cpu_set_t foo;
364 sched_setaffinity(0, sizeof (foo), &foo);
365 return 0;
366 }
367 ]])
368 ],
369 [sched_set_affinity_args=3],
370 [sched_set_affinity_args=2])
371 AC_DEFINE_UNQUOTED(SCHED_SETAFFINITY_ARGS,
372 $sched_set_affinity_args,
373 [Defined to sched_setaffinity's number of arguments.])
374 AC_MSG_RESULT([$sched_set_affinity_args])
375 ],[
376 # No cpu_set_t, always 3 args.
377 AC_DEFINE(SCHED_SETAFFINITY_ARGS, 3)
378 ])
379])
380
381AM_CPPFLAGS="-include config.h"
382AC_SUBST(AM_CPPFLAGS)
383
384AM_CFLAGS="-Wall -Wextra -Wno-unused-parameter $AM_CFLAGS"
385AC_SUBST(AM_CFLAGS)
386
387AC_CONFIG_LINKS([
388 include/urcu/arch.h:$ARCHSRC
389 include/urcu/uatomic.h:$UATOMICSRC
390])
391AC_CONFIG_FILES([
392 Makefile
393 doc/Makefile
394 doc/examples/Makefile
395 include/Makefile
396 src/Makefile
397 tests/Makefile
398 tests/common/Makefile
399 tests/unit/Makefile
400 tests/benchmark/Makefile
401 tests/regression/Makefile
402 tests/utils/Makefile
403 src/liburcu.pc
404 src/liburcu-bp.pc
405 src/liburcu-cds.pc
406 src/liburcu-qsbr.pc
407 src/liburcu-mb.pc
408 src/liburcu-signal.pc
409])
410
411AC_CONFIG_FILES([tests/regression/rcutorture_urcu_bp_perf_global.tap], [chmod +x tests/regression/rcutorture_urcu_bp_perf_global.tap])
412AC_CONFIG_FILES([tests/regression/rcutorture_urcu_bp_perf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_bp_perf_percpu.tap])
413AC_CONFIG_FILES([tests/regression/rcutorture_urcu_bp_perf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_bp_perf_perthread.tap])
414AC_CONFIG_FILES([tests/regression/rcutorture_urcu_bp_rperf_global.tap], [chmod +x tests/regression/rcutorture_urcu_bp_rperf_global.tap])
415AC_CONFIG_FILES([tests/regression/rcutorture_urcu_bp_rperf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_bp_rperf_percpu.tap])
416AC_CONFIG_FILES([tests/regression/rcutorture_urcu_bp_rperf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_bp_rperf_perthread.tap])
417AC_CONFIG_FILES([tests/regression/rcutorture_urcu_bp_stress_global.tap], [chmod +x tests/regression/rcutorture_urcu_bp_stress_global.tap])
418AC_CONFIG_FILES([tests/regression/rcutorture_urcu_bp_stress_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_bp_stress_percpu.tap])
419AC_CONFIG_FILES([tests/regression/rcutorture_urcu_bp_stress_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_bp_stress_perthread.tap])
420AC_CONFIG_FILES([tests/regression/rcutorture_urcu_bp_uperf_global.tap], [chmod +x tests/regression/rcutorture_urcu_bp_uperf_global.tap])
421AC_CONFIG_FILES([tests/regression/rcutorture_urcu_bp_uperf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_bp_uperf_percpu.tap])
422AC_CONFIG_FILES([tests/regression/rcutorture_urcu_bp_uperf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_bp_uperf_perthread.tap])
423AC_CONFIG_FILES([tests/regression/rcutorture_urcu_mb_perf_global.tap], [chmod +x tests/regression/rcutorture_urcu_mb_perf_global.tap])
424AC_CONFIG_FILES([tests/regression/rcutorture_urcu_mb_perf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_mb_perf_percpu.tap])
425AC_CONFIG_FILES([tests/regression/rcutorture_urcu_mb_perf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_mb_perf_perthread.tap])
426AC_CONFIG_FILES([tests/regression/rcutorture_urcu_mb_rperf_global.tap], [chmod +x tests/regression/rcutorture_urcu_mb_rperf_global.tap])
427AC_CONFIG_FILES([tests/regression/rcutorture_urcu_mb_rperf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_mb_rperf_percpu.tap])
428AC_CONFIG_FILES([tests/regression/rcutorture_urcu_mb_rperf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_mb_rperf_perthread.tap])
429AC_CONFIG_FILES([tests/regression/rcutorture_urcu_mb_stress_global.tap], [chmod +x tests/regression/rcutorture_urcu_mb_stress_global.tap])
430AC_CONFIG_FILES([tests/regression/rcutorture_urcu_mb_stress_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_mb_stress_percpu.tap])
431AC_CONFIG_FILES([tests/regression/rcutorture_urcu_mb_stress_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_mb_stress_perthread.tap])
432AC_CONFIG_FILES([tests/regression/rcutorture_urcu_mb_uperf_global.tap], [chmod +x tests/regression/rcutorture_urcu_mb_uperf_global.tap])
433AC_CONFIG_FILES([tests/regression/rcutorture_urcu_mb_uperf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_mb_uperf_percpu.tap])
434AC_CONFIG_FILES([tests/regression/rcutorture_urcu_mb_uperf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_mb_uperf_perthread.tap])
435AC_CONFIG_FILES([tests/regression/rcutorture_urcu_membarrier_perf_global.tap], [chmod +x tests/regression/rcutorture_urcu_membarrier_perf_global.tap])
436AC_CONFIG_FILES([tests/regression/rcutorture_urcu_membarrier_perf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_membarrier_perf_percpu.tap])
437AC_CONFIG_FILES([tests/regression/rcutorture_urcu_membarrier_perf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_membarrier_perf_perthread.tap])
438AC_CONFIG_FILES([tests/regression/rcutorture_urcu_membarrier_rperf_global.tap], [chmod +x tests/regression/rcutorture_urcu_membarrier_rperf_global.tap])
439AC_CONFIG_FILES([tests/regression/rcutorture_urcu_membarrier_rperf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_membarrier_rperf_percpu.tap])
440AC_CONFIG_FILES([tests/regression/rcutorture_urcu_membarrier_rperf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_membarrier_rperf_perthread.tap])
441AC_CONFIG_FILES([tests/regression/rcutorture_urcu_membarrier_stress_global.tap], [chmod +x tests/regression/rcutorture_urcu_membarrier_stress_global.tap])
442AC_CONFIG_FILES([tests/regression/rcutorture_urcu_membarrier_stress_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_membarrier_stress_percpu.tap])
443AC_CONFIG_FILES([tests/regression/rcutorture_urcu_membarrier_stress_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_membarrier_stress_perthread.tap])
444AC_CONFIG_FILES([tests/regression/rcutorture_urcu_membarrier_uperf_global.tap], [chmod +x tests/regression/rcutorture_urcu_membarrier_uperf_global.tap])
445AC_CONFIG_FILES([tests/regression/rcutorture_urcu_membarrier_uperf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_membarrier_uperf_percpu.tap])
446AC_CONFIG_FILES([tests/regression/rcutorture_urcu_membarrier_uperf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_membarrier_uperf_perthread.tap])
447AC_CONFIG_FILES([tests/regression/rcutorture_urcu_qsbr_perf_global.tap], [chmod +x tests/regression/rcutorture_urcu_qsbr_perf_global.tap])
448AC_CONFIG_FILES([tests/regression/rcutorture_urcu_qsbr_perf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_qsbr_perf_percpu.tap])
449AC_CONFIG_FILES([tests/regression/rcutorture_urcu_qsbr_perf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_qsbr_perf_perthread.tap])
450AC_CONFIG_FILES([tests/regression/rcutorture_urcu_qsbr_rperf_global.tap], [chmod +x tests/regression/rcutorture_urcu_qsbr_rperf_global.tap])
451AC_CONFIG_FILES([tests/regression/rcutorture_urcu_qsbr_rperf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_qsbr_rperf_percpu.tap])
452AC_CONFIG_FILES([tests/regression/rcutorture_urcu_qsbr_rperf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_qsbr_rperf_perthread.tap])
453AC_CONFIG_FILES([tests/regression/rcutorture_urcu_qsbr_stress_global.tap], [chmod +x tests/regression/rcutorture_urcu_qsbr_stress_global.tap])
454AC_CONFIG_FILES([tests/regression/rcutorture_urcu_qsbr_stress_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_qsbr_stress_percpu.tap])
455AC_CONFIG_FILES([tests/regression/rcutorture_urcu_qsbr_stress_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_qsbr_stress_perthread.tap])
456AC_CONFIG_FILES([tests/regression/rcutorture_urcu_qsbr_uperf_global.tap], [chmod +x tests/regression/rcutorture_urcu_qsbr_uperf_global.tap])
457AC_CONFIG_FILES([tests/regression/rcutorture_urcu_qsbr_uperf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_qsbr_uperf_percpu.tap])
458AC_CONFIG_FILES([tests/regression/rcutorture_urcu_qsbr_uperf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_qsbr_uperf_perthread.tap])
459AC_CONFIG_FILES([tests/regression/rcutorture_urcu_signal_perf_global.tap], [chmod +x tests/regression/rcutorture_urcu_signal_perf_global.tap])
460AC_CONFIG_FILES([tests/regression/rcutorture_urcu_signal_perf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_signal_perf_percpu.tap])
461AC_CONFIG_FILES([tests/regression/rcutorture_urcu_signal_perf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_signal_perf_perthread.tap])
462AC_CONFIG_FILES([tests/regression/rcutorture_urcu_signal_rperf_global.tap], [chmod +x tests/regression/rcutorture_urcu_signal_rperf_global.tap])
463AC_CONFIG_FILES([tests/regression/rcutorture_urcu_signal_rperf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_signal_rperf_percpu.tap])
464AC_CONFIG_FILES([tests/regression/rcutorture_urcu_signal_rperf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_signal_rperf_perthread.tap])
465AC_CONFIG_FILES([tests/regression/rcutorture_urcu_signal_stress_global.tap], [chmod +x tests/regression/rcutorture_urcu_signal_stress_global.tap])
466AC_CONFIG_FILES([tests/regression/rcutorture_urcu_signal_stress_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_signal_stress_percpu.tap])
467AC_CONFIG_FILES([tests/regression/rcutorture_urcu_signal_stress_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_signal_stress_perthread.tap])
468AC_CONFIG_FILES([tests/regression/rcutorture_urcu_signal_uperf_global.tap], [chmod +x tests/regression/rcutorture_urcu_signal_uperf_global.tap])
469AC_CONFIG_FILES([tests/regression/rcutorture_urcu_signal_uperf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_signal_uperf_percpu.tap])
470AC_CONFIG_FILES([tests/regression/rcutorture_urcu_signal_uperf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_signal_uperf_perthread.tap])
471
472
473AC_OUTPUT
474
475#
476# Mini-report on what will be built.
477#
478
479PPRINT_INIT
480PPRINT_SET_INDENT(1)
481PPRINT_SET_TS(38)
482
483AS_ECHO
484AS_ECHO("${PPRINT_COLOR_BLDBLU}Userspace-RCU $PACKAGE_VERSION${PPRINT_COLOR_RST}")
485AS_ECHO
486
487PPRINT_SUBTITLE([Features])
488
489PPRINT_PROP_STRING([Target architecture], $host_cpu)
490
491# SMP support enabled/disabled
492test "x$def_smp_support" = "xyes" && value=1 || value=0
493PPRINT_PROP_BOOL([SMP support], $value)
494
495# Memory fence support available
496test "x$config_rcu_have_fence" = "xyes" && value=1 || value=0
497PPRINT_PROP_BOOL([Memory fence instructions], $value)
498
499# Futex support available
500test "x$compat_futex_test" = "x0" && value=1 || value=0
501PPRINT_PROP_BOOL([Futex support], $value)
502
503# TLS
504test "x$def_tls_detect" = "x" && value="pthread_getspecific()" || value="$def_tls_detect"
505PPRINT_PROP_STRING([Thread Local Storage (TLS)], [$value])
506
507# clock_gettime() available
508test "x$config_rcu_have_clock_gettime" = "xyes" && value=1 || value=0
509PPRINT_PROP_BOOL([clock_gettime()], $value)
510
511# Require membarrier
512test "x$def_sys_membarrier_fallback" != "xyes" && value=1 || value=0
513PPRINT_PROP_BOOL([Require membarrier], $value)
514
515# RCU debug enabled/disabled
516test "x$enable_rcu_debug" = "xyes" && value=1 || value=0
517PPRINT_PROP_BOOL([Internal debugging], $value)
518
519# rculfhash iterator debug enabled/disabled
520test "x$enable_cds_lfht_iter_debug" = "xyes" && value=1 || value=0
521PPRINT_PROP_BOOL([Lock-free hash table iterator debugging], $value)
522
523PPRINT_PROP_BOOL([Multi-flavor support], 1)
524
525report_bindir="`eval eval echo $bindir`"
526report_libdir="`eval eval echo $libdir`"
527
528# Print the bindir and libdir this `make install' will install into.
529AS_ECHO
530PPRINT_SUBTITLE([Install directories])
531PPRINT_PROP_STRING([Binaries], [$report_bindir])
532PPRINT_PROP_STRING([Libraries], [$report_libdir])
533
Userspace RCU (urcu) for Linux
This page took 0.023793 seconds and 4 git commands to generate.