Add QSBR minimal example
[urcu.git] / configure.ac
CommitLineData
48d848c7
PMF
1# -*- Autoconf -*-
2# Process this file with autoconf to produce a configure script.
3
4
ae51baf2 5AC_INIT([userspace-rcu],[0.7.4],[mathieu dot desnoyers at efficios dot com])
98bc124a
YB
6
7# Following the numbering scheme proposed by libtool for the library version
8# http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
1de4df4b 9AC_SUBST([URCU_LIBRARY_VERSION], [2:0:0])
98bc124a 10
48d848c7 11AC_CONFIG_AUX_DIR([config])
a6412536 12AC_CONFIG_MACRO_DIR([config])
7d413817
MD
13AC_CANONICAL_TARGET
14AC_CANONICAL_HOST
48d848c7 15AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip])
806f8114
PB
16m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
17
a767fdc3
MD
18m4_include([config/ax_tls.m4])
19
48d848c7 20AC_CONFIG_SRCDIR([urcu.h])
7d413817 21
e72596d1
MD
22AC_CONFIG_HEADERS([config.h urcu/config.h])
23
02be5561
MD
24AH_TEMPLATE([CONFIG_RCU_SMP], [Enable SMP support. With SMP support enabled, uniprocessors are also supported. With SMP support disabled, UP systems work fine, but the behavior of SMP systems is undefined.])
25AH_TEMPLATE([CONFIG_RCU_HAVE_FENCE], [Defined when on a system that has memory fence instructions.])
26AH_TEMPLATE([CONFIG_RCU_HAVE_FUTEX], [Defined when on a system with futex support.])
a6412536
AM
27AH_TEMPLATE([CONFIG_RCU_COMPAT_ARCH], [Compatibility mode for i386 which lacks cmpxchg instruction.])
28AH_TEMPLATE([CONFIG_RCU_ARM_HAVE_DMB], [Use the dmb instruction if available for use on ARM.])
a767fdc3
MD
29AH_TEMPLATE([CONFIG_RCU_TLS], [TLS provided by the compiler.])
30
75478b32
MD
31# Allow overriding storage used for TLS variables.
32AC_ARG_ENABLE([compiler-tls],
33 AS_HELP_STRING([--disable-compiler-tls], [Use pthread_getspecific() to emulate Thread Local Storage (TLS) variables.]),
34 [def_compiler_tls=$enableval],
35 [def_compiler_tls="yes"])
36
37# If not overridden, use ax_tls.m4 to check if TLS is available.
38AS_IF([test "x$def_compiler_tls" = "xyes"],
39 [AX_TLS([def_tls_detect=$ac_cv_tls], [:])],
40 [:])
41
42AS_IF([test "x$def_tls_detect" = "x"],
43 [:],
44 [AC_DEFINE_UNQUOTED([CONFIG_RCU_TLS], $def_tls_detect)])
48d848c7
PMF
45
46# Checks for programs.
47AC_PROG_CC
48AC_PROG_MAKE_SET
b14a378a 49LT_INIT
48d848c7
PMF
50
51# Checks for typedefs, structures, and compiler characteristics.
52AC_C_INLINE
53AC_TYPE_PID_T
54AC_TYPE_SIZE_T
55
56# Checks for library functions.
57AC_FUNC_MALLOC
58AC_FUNC_MMAP
b57aee66 59AC_CHECK_FUNCS([bzero gettimeofday munmap sched_getcpu strtoul sysconf])
48d848c7
PMF
60
61# Find arch type
58e9f838 62AS_CASE([$host_cpu],
a6412536
AM
63 [i386], [ARCHTYPE="x86" && SUBARCHTYPE="x86compat"],
64 [i486], [ARCHTYPE="x86"],
65 [i586], [ARCHTYPE="x86"],
66 [i686], [ARCHTYPE="x86"],
67 [amd64], [ARCHTYPE="x86"],
68 [x86_64], [ARCHTYPE="x86"],
69 [powerpc], [ARCHTYPE="ppc"],
70 [ppc64], [ARCHTYPE="ppc"],
71 [powerpc64], [ARCHTYPE="ppc"],
72 [ppc], [ARCHTYPE="ppc"],
73 [s390], [ARCHTYPE="s390"],
74 [s390x], [ARCHTYPE="s390"],
171ff3a3 75 [sparc], [ARCHTYPE="sparc64"],
a6412536
AM
76 [sparc64], [ARCHTYPE="sparc64"],
77 [alpha*], [ARCHTYPE="alpha"],
78 [ia64], [ARCHTYPE="gcc"],
79 [arm*], [ARCHTYPE="arm"],
e1259cb1 80 [mips*], [ARCHTYPE="mips"],
274773cf 81 [tile*], [ARCHTYPE="gcc"],
a6412536
AM
82 [ARCHTYPE="unknown"]
83)
91b0650a 84
a6412536
AM
85AC_SUBST(ARCHTYPE)
86AC_SUBST(SUBARCHTYPE)
5e626e0e 87
a2e7bf9c 88UATOMICSRC=urcu/uatomic/$ARCHTYPE.h
1b9119f8 89ARCHSRC=urcu/arch/$ARCHTYPE.h
455b809a 90
a6412536
AM
91AS_IF([test "x$SUBARCHTYPE" = xx86compat],[
92 AC_DEFINE([CONFIG_RCU_COMPAT_ARCH], [1])
93])
94
58e9f838 95AS_IF([test "$host_cpu" = "armv7l"],[
a6412536
AM
96 CFLAGS="$CFLAGS -mcpu=cortex-a9 -mtune=cortex-a9 -O1"
97])
48d848c7 98
a6412536
AM
99# ARM-specific checks
100AS_IF([test "x$ARCHTYPE" = "xarm"],[
101 AC_MSG_CHECKING([for dmb instruction])
fe0707ab
MD
102 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
103 int main()
104 {
105 asm volatile("dmb":::"memory");
106 return 0;
107 }
108 ]])
109 ],[
a6412536
AM
110 AC_MSG_RESULT([yes])
111 AC_DEFINE([CONFIG_RCU_ARM_HAVE_DMB], [1])
112 ],[
113 AC_MSG_RESULT([no])
114 ])
115])
116
274773cf
SM
117# Tile-specific checks
118AS_IF([echo "$host_cpu" | grep "^tile"],[
119 AC_MSG_CHECKING([for Tile architecture type])
120 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
121 #ifndef __tilegx__
122 #error
123 #endif
124 ]])
125 ],[
126 AC_MSG_RESULT([ok])
127 ],[
128 AC_MSG_FAILURE([URCU has only been tested on the TileGx architecture. For other Tile* architectures, please run the tests first and report the results to the maintainer so that proper support can be added.])
129 ])
130])
131
a6412536
AM
132# x86-specific checks
133AS_IF([test "x$ARCHTYPE" = "xx86"],[
134 AC_MSG_CHECKING([if architecture really supports the mfence instruction])
135 #For now, using lock; addl compatibility mode even for i686, because the
136 #Pentium III is seen as a i686, but lacks mfence instruction.
137 #Only using fence for x86_64.
58e9f838 138 AS_IF([test "x$host_cpu" != "xi386" -a "x$host_cpu" != "xi486" -a "x$host_cpu" != "xi586" -a "x$host_cpu" != "xi686"],[
a6412536
AM
139 AC_MSG_RESULT([yes])
140 AC_DEFINE([CONFIG_RCU_HAVE_FENCE], [1])
141 ],[
142 AC_MSG_RESULT([no])
143 ])
144])
145
146# Check if sys_futex() is available
147AC_MSG_CHECKING([for sys_futex()])
fe0707ab 148AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
a6412536 149 #include <sys/syscall.h>
a6412536
AM
150 #ifndef __NR_futex
151 #error "futexes not available"
152 #endif
fe0707ab 153 ]])
a6412536 154],[
0854ccff 155 AC_MSG_RESULT([yes])
02be5561 156 AC_DEFINE([CONFIG_RCU_HAVE_FUTEX], [1])
0854ccff 157 compat_futex_test=0
91b0650a 158],[
0854ccff
MD
159 AC_MSG_RESULT([no])
160 compat_futex_test=1
91b0650a 161])
0854ccff 162
a6412536
AM
163AM_CONDITIONAL([COMPAT_FUTEX], [test "x$compat_futex_test" = "x1"])
164AM_CONDITIONAL([COMPAT_ARCH], [test "x$SUBARCHTYPE" = "xx86compat"])
0854ccff 165
a6412536
AM
166# smp-support configure option
167AC_ARG_ENABLE([smp-support],
168 AS_HELP_STRING([--disable-smp-support], [Disable SMP support. Warning: only use this on uniprocessor systems. [default=enabled]]),
169 [def_smp_support=$enableval],
170 [def_smp_support="yes"])
171AS_IF([test "x$def_smp_support" = "xyes"], [AC_DEFINE([CONFIG_RCU_SMP], [1])])
7d413817 172
48d848c7 173
d8540fc5
PA
174# From the sched_setaffinity(2)'s man page:
175# ~~~~
176# The CPU affinity system calls were introduced in Linux kernel 2.5.8.
177# The library interfaces were introduced in glibc 2.3. Initially, the
178# glibc interfaces included a cpusetsize argument. In glibc 2.3.3,
179# the cpuset size argument was removed, but this argument was
180# restored in glibc 2.3.4.
181# ~~~~
182
183# In addition to that, some vendors ported the system call to 2.4
184# kernels.
185
186# Furthermore, when the function first appeared, the MASK argument was
187# an unsigned long pointer, while later it was made into a cpu_set_t
188# pointer. Systems that have the cpu_set_t version also should have
189# the CPU_ZERO, CPU_SET, etc. macros.
190
191# All this mess means we have to cater for at least 3 different
192# sched_setaffinity prototypes:
193
194# ~~~~
195# int sched_setaffinity (pid_t pid, unsigned int len, unsigned long *mask);
196# int sched_setaffinity (pid_t __pid, size_t __cpusetsize, const cpu_set_t *__cpuset);
197# int sched_setaffinity (pid_t __pid, const cpu_set_t *__mask);
198# ~~~~
199
a6412536
AM
200# Since we define _GNU_SOURCE in the sources, must do so too in the
201# autoconf tests, as defining _GNU_SOURCE or not exposes
202# sched_setaffinity bits differently.
d8540fc5
PA
203saved_CFLAGS=$CFLAGS
204CFLAGS="$CFLAGS -D_GNU_SOURCE"
205
b3231c17
MD
206AC_CHECK_TYPES([cpu_set_t],
207 [have_cpu_set_t="yes"],
208 [have_cpu_set_t="no"],
209 [#include <sched.h>])
210
211# Confirm that we have CPU_ZERO, and it actually works.
212AC_MSG_CHECKING([whether CPU_ZERO works])
213AH_TEMPLATE([HAVE_CPU_ZERO], [Defined to 1 if we have CPU_ZERO and it works])
214AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
215 #define _GNU_SOURCE
216 #include <sched.h>
217 int main()
218 {
219 cpu_set_t foo; CPU_ZERO(&foo);
220 return 0;
221 }
222 ]])
223],[
224 AC_DEFINE(HAVE_CPU_ZERO, 1)
225 AC_MSG_RESULT([yes])
226],[
227 AC_MSG_RESULT([no])
228])
229
230# Confirm that we have CPU_SET, and it actually works.
231AC_MSG_CHECKING([whether CPU_SET works])
232AH_TEMPLATE([HAVE_CPU_SET], [Defined to 1 if we have CPU_SET and it works])
233AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
234 #define _GNU_SOURCE
235 #include <sched.h>
236 int main()
237 {
238 cpu_set_t foo, mask; CPU_SET(0, &foo);
239 return 0;
240 }
241 ]])
242],[
243 AC_DEFINE(HAVE_CPU_SET, 1)
244 AC_MSG_RESULT([yes])
245],[
246 AC_MSG_RESULT([no])
247])
248
d8540fc5 249# First check if the function is available at all.
a6412536
AM
250AC_CHECK_FUNCS([sched_setaffinity],[
251 # Okay, we have it. Check if also have cpu_set_t. If we don't,
252 # then we have the first version using unsigned long, and no
253 # CPU_ZERO, etc. macros. If we do have cpu_set_t, we may have the
254 # version with 2 or 3 arguments. In that case, CPU_ZERO, etc.,
255 # should also be present, but we confirm nonetheless.
256
b3231c17
MD
257 AS_IF([test "x$have_cpu_set_t" = "xyes"], [
258 # We do have it.
a6412536
AM
259 # Check how many arguments does sched_setaffinity take.
260 # Should be 3 or 2.
261 AC_MSG_CHECKING([how many arguments sched_setaffinity takes])
ec5e2d14 262 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
a6412536 263 #include <sched.h>
fe0707ab
MD
264 int main()
265 {
266 cpu_set_t foo;
b3231c17 267 sched_setaffinity(0, sizeof (foo), &foo);
fe0707ab
MD
268 return 0;
269 }
a6412536
AM
270 ]])
271 ],
272 [sched_set_affinity_args=3],
273 [sched_set_affinity_args=2])
b3231c17
MD
274 AC_DEFINE_UNQUOTED(SCHED_SETAFFINITY_ARGS,
275 $sched_set_affinity_args,
a6412536
AM
276 [Defined to sched_setaffinity's number of arguments.])
277 AC_MSG_RESULT([$sched_set_affinity_args])
278 ],[
279 # No cpu_set_t, always 3 args.
280 AC_DEFINE(SCHED_SETAFFINITY_ARGS, 3)
b3231c17 281 ])
a6412536 282])
d8540fc5
PA
283
284CFLAGS=$saved_CFLAGS
285
455b809a
PB
286AC_CONFIG_LINKS([
287 urcu/arch.h:$ARCHSRC
a2e7bf9c 288 urcu/uatomic.h:$UATOMICSRC
455b809a 289])
48d848c7
PMF
290AC_CONFIG_FILES([
291 Makefile
fe999c05 292 doc/Makefile
8bad63a0 293 doc/examples/Makefile
48d848c7 294 tests/Makefile
2260a36c
YB
295 liburcu.pc
296 liburcu-bp.pc
a6412536 297 liburcu-cds.pc
2260a36c
YB
298 liburcu-qsbr.pc
299 liburcu-mb.pc
300 liburcu-signal.pc
48d848c7
PMF
301])
302AC_OUTPUT
a6412536
AM
303
304# Report on selected configure options
305AS_IF([test "x$def_smp_support" = "xyes"],[
306 AS_ECHO("SMP support enabled.")
307],[
308 AS_ECHO("SMP support disabled.")
309])
75478b32
MD
310
311AS_IF([test "x$def_tls_detect" = "x"],[
312 AS_ECHO("Thread Local Storage (TLS): pthread_getspecific().")
313],[
314 AS_ECHO("Thread Local Storage (TLS): $def_tls_detect.")
315])
This page took 0.064273 seconds and 4 git commands to generate.