[urcu.git] / configure.ac

AC_PREREQ(2.59)
AC_INIT([userspace-rcu],[0.9.0],[mathieu dot desnoyers at efficios dot com], [], [http://liburcu.org/])

# Following the numbering scheme proposed by libtool for the library version
# http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
AC_SUBST([URCU_LIBRARY_VERSION], [5:0:1])

AC_CONFIG_HEADERS([include/config.h include/urcu/config.h])
AC_CONFIG_AUX_DIR([config])
AC_CONFIG_MACRO_DIR([m4])

AC_CANONICAL_TARGET
AC_CANONICAL_HOST

AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip nostdinc])
AM_MAINTAINER_MODE([enable])

# Enable silent rules if available (Introduced in AM 1.11)
m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])

AH_TEMPLATE([CONFIG_RCU_SMP], [Enable SMP support. With SMP support enabled, uniprocessors are also supported. With SMP support disabled, UP systems work fine, but the behavior of SMP systems is undefined.])
AH_TEMPLATE([CONFIG_RCU_HAVE_FENCE], [Defined when on a system that has memory fence instructions.])
AH_TEMPLATE([CONFIG_RCU_HAVE_FUTEX], [Defined when on a system with futex support.])
AH_TEMPLATE([CONFIG_RCU_COMPAT_ARCH], [Compatibility mode for i386 which lacks cmpxchg instruction.])
AH_TEMPLATE([CONFIG_RCU_ARM_HAVE_DMB], [Use the dmb instruction if available for use on ARM.])
AH_TEMPLATE([CONFIG_RCU_TLS], [TLS provided by the compiler.])
AH_TEMPLATE([CONFIG_RCU_HAVE_CLOCK_GETTIME], [clock_gettime() is detected.])

# Allow overriding storage used for TLS variables.
AC_ARG_ENABLE([compiler-tls],
	AS_HELP_STRING([--disable-compiler-tls], [Use pthread_getspecific() to emulate Thread Local Storage (TLS) variables.]),
	[def_compiler_tls=$enableval],
	[def_compiler_tls="yes"])

# If not overridden, use ax_tls.m4 to check if TLS is available.
AS_IF([test "x$def_compiler_tls" = "xyes"],
	[AX_TLS([def_tls_detect=$ac_cv_tls], [:])],
	[:])

AS_IF([test "x$def_tls_detect" = "x"],
	[:],
	[AC_DEFINE_UNQUOTED([CONFIG_RCU_TLS], $def_tls_detect)])

# Checks for C compiler
AC_USE_SYSTEM_EXTENSIONS
AC_PROG_CC
AC_PROG_CC_STDC

# Checks for programs.
AC_PROG_AWK
AC_PROG_MAKE_SET
AC_CHECK_PROGS(NPROC, [nproc gnproc])
AC_CHECK_PROGS(GETCONF, [getconf])
AS_IF([test "x$NPROC" != "x"],
	[NPROC_CMD=$NPROC],
	[AS_IF([test "x$GETCONF" != "x"],
		[NPROC_CMD="$GETCONF _NPROCESSORS_ONLN"],
		[NPROC_CMD="echo 1"]
	)]
)
AC_SUBST([NPROC_CMD], [$NPROC_CMD])

LT_INIT

# Checks for typedefs, structures, and compiler characteristics.
AC_C_INLINE
AC_TYPE_PID_T
AC_TYPE_SIZE_T
AC_TYPE_SSIZE_T
AC_TYPE_UINT16_T
AC_TYPE_INT32_T
AC_TYPE_UINT32_T
AC_TYPE_UINT64_T
AC_TYPE_UINT8_T

AX_C___ATTRIBUTE__
AS_IF([test "x$ax_cv___attribute__" = "xyes"],
	[:],
	[AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])

AX_PTHREAD(,[AC_MSG_ERROR([Could not configure pthreads support])])
LIBS="$PTHREAD_LIBS $LIBS"
CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
CC="$PTHREAD_CC"

# Checks for library functions.
AC_FUNC_MALLOC
AC_FUNC_MMAP
AC_FUNC_FORK
AC_CHECK_FUNCS([ \
	atexit \
	getcpuid \
	gettid \
	gettimeofday \
	memeset \
	memset \
	munmap \
	sched_getcpu \
	strerror \
	strtoul \
	sysconf \
])

# Check for headers
AC_HEADER_STDBOOL
AC_CHECK_HEADERS([ \
	limits.h \
	stddef.h \
	sys/param.h \
	sys/time.h \
])

# Find arch type
AS_CASE([$host_cpu],
	[k1om], [ARCHTYPE="x86"],
	[i386], [ARCHTYPE="x86" && SUBARCHTYPE="x86compat"],
	[i486], [ARCHTYPE="x86"],
	[i586], [ARCHTYPE="x86"],
	[i686], [ARCHTYPE="x86"],
	[amd64], [ARCHTYPE="x86"],
	[x86_64], [ARCHTYPE="x86"],
	[powerpc], [ARCHTYPE="ppc"],
	[ppc64], [ARCHTYPE="ppc"],
	[powerpc64], [ARCHTYPE="ppc"],
	[powerpc64le], [ARCHTYPE="ppc"],
	[ppc], [ARCHTYPE="ppc"],
	[s390], [ARCHTYPE="s390"],
	[s390x], [ARCHTYPE="s390"],
	[sparc], [ARCHTYPE="sparc64"],
	[sparc64], [ARCHTYPE="sparc64"],
	[alpha*], [ARCHTYPE="alpha"],
	[ia64], [ARCHTYPE="ia64"],
	[arm*], [ARCHTYPE="arm"],
	[aarch64*], [ARCHTYPE="aarch64"],
	[mips*], [ARCHTYPE="mips"],
	[nios2*], [ARCHTYPE="nios2"],
	[tile*], [ARCHTYPE="tile"],
	[hppa*], [ARCHTYPE="hppa"],
	[ARCHTYPE="unknown"]
)

AS_CASE([$host],[*-cygwin*],
	[AM_CONDITIONAL(USE_CYGWIN, true)],
	[AM_CONDITIONAL(USE_CYGWIN, false)]
)

AC_SUBST(ARCHTYPE)
AC_SUBST(SUBARCHTYPE)

UATOMICSRC=include/urcu/uatomic/$ARCHTYPE.h
ARCHSRC=include/urcu/arch/$ARCHTYPE.h

AS_IF([test "x$SUBARCHTYPE" = xx86compat],[
	AC_DEFINE([CONFIG_RCU_COMPAT_ARCH], [1])
])

AS_IF([test "$host_cpu" = "armv7l"],[
	CFLAGS="$CFLAGS -mcpu=cortex-a9 -mtune=cortex-a9 -O1"
])

# ARM-specific checks
AS_IF([test "x$ARCHTYPE" = "xarm"],[
	AC_MSG_CHECKING([for dmb instruction])
	AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
				int main()
				{
					asm volatile("dmb":::"memory");
					return 0;
				}
		]])
	],[
		AC_MSG_RESULT([yes])
		AC_DEFINE([CONFIG_RCU_ARM_HAVE_DMB], [1])
	],[
		AC_MSG_RESULT([no])
	])
])

# Tile-specific checks
AS_IF([echo "$host_cpu" | grep "^tile"],[
	AC_MSG_CHECKING([for Tile architecture type])
	AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
				#ifndef __tilegx__
				#error
				#endif
		]])
	],[
		AC_MSG_RESULT([ok])
	],[
		AC_MSG_FAILURE([URCU has only been tested on the TileGx architecture. For other Tile* architectures, please run the tests first and report the results to the maintainer so that proper support can be added.])
	])
])

# x86-specific checks
AS_IF([test "x$ARCHTYPE" = "xx86"],[
	AC_MSG_CHECKING([if architecture really supports the mfence instruction])
	#For now, using lock; addl compatibility mode even for i686, because the
	#Pentium III is seen as a i686, but lacks mfence instruction.
	#Only using fence for x86_64.
	#
	#k1om is the name for the Intel MIC family (Xeon Phi). It is an x86_64
	#variant but lacks fence instructions.
	AS_IF([test "x$host_cpu" != "xi386" -a "x$host_cpu" != "xi486" -a "x$host_cpu" != "xi586" -a "x$host_cpu" != "xi686" -a "x$host_vendor" != "xk1om" -a "x$host_cpu" != "xk1om"],[
		AC_MSG_RESULT([yes])
		AC_DEFINE([CONFIG_RCU_HAVE_FENCE], [1])
	],[
		AC_MSG_RESULT([no])
	])
])

# Check if sys_futex() is available
AC_MSG_CHECKING([for sys_futex()])
AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
		#include <sys/syscall.h>
		#ifndef __NR_futex
		#error "futexes not available"
		#endif
	]])
],[
	AC_MSG_RESULT([yes])
	AC_DEFINE([CONFIG_RCU_HAVE_FUTEX], [1])
	compat_futex_test=0
],[
	AC_MSG_RESULT([no])
	compat_futex_test=1
])

# Search for clock_gettime
AC_SEARCH_LIBS([clock_gettime], [rt], [
	AC_DEFINE([CONFIG_RCU_HAVE_CLOCK_GETTIME], [1])
], [])

AM_CONDITIONAL([COMPAT_FUTEX], [test "x$compat_futex_test" = "x1"])
AM_CONDITIONAL([COMPAT_ARCH], [test "x$SUBARCHTYPE" = "xx86compat"])
AM_CONDITIONAL([NO_SHARED], [test "x$enable_shared" = "xno"])

# smp-support configure option
AC_ARG_ENABLE([smp-support], 
	AS_HELP_STRING([--disable-smp-support], [Disable SMP support. Warning: only use this on uniprocessor systems. [default=enabled]]),
	[def_smp_support=$enableval],
	[def_smp_support="yes"])
AS_IF([test "x$def_smp_support" = "xyes"], [AC_DEFINE([CONFIG_RCU_SMP], [1])])


# From the sched_setaffinity(2)'s man page:
# ~~~~
# The CPU affinity system calls were introduced in Linux kernel 2.5.8.
# The library interfaces were introduced in glibc 2.3.  Initially, the
# glibc interfaces included a cpusetsize argument.  In glibc 2.3.3,
# the cpuset size argument was removed, but this argument was
# restored in glibc 2.3.4.
# ~~~~

# In addition to that, some vendors ported the system call to 2.4
# kernels.

# Furthermore, when the function first appeared, the MASK argument was
# an unsigned long pointer, while later it was made into a cpu_set_t
# pointer.  Systems that have the cpu_set_t version also should have
# the CPU_ZERO, CPU_SET, etc. macros.

# All this mess means we have to cater for at least 3 different
# sched_setaffinity prototypes:

# ~~~~
#  int sched_setaffinity (pid_t pid, unsigned int len, unsigned long *mask);
#  int sched_setaffinity (pid_t __pid, size_t __cpusetsize, const cpu_set_t *__cpuset);
#  int sched_setaffinity (pid_t __pid, const cpu_set_t *__mask);
# ~~~~

AC_CHECK_TYPES([cpu_set_t],
	[have_cpu_set_t="yes"],
	[have_cpu_set_t="no"],
	[#include <sched.h>])

# Confirm that we have CPU_ZERO, and it actually works.
AC_MSG_CHECKING([whether CPU_ZERO works])
AH_TEMPLATE([HAVE_CPU_ZERO], [Defined to 1 if we have CPU_ZERO and it works])
AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
		#include <sched.h>
		int main()
		{
			cpu_set_t foo; CPU_ZERO(&foo);
			return 0;
		}
	]])
],[
	AC_DEFINE(HAVE_CPU_ZERO, 1)
	AC_MSG_RESULT([yes])
],[
	AC_MSG_RESULT([no])
])

# Confirm that we have CPU_SET, and it actually works.
AC_MSG_CHECKING([whether CPU_SET works])
AH_TEMPLATE([HAVE_CPU_SET], [Defined to 1 if we have CPU_SET and it works])
AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
		#include <sched.h>
		int main()
		{
			cpu_set_t foo, mask; CPU_SET(0, &foo);
			return 0;
		}
	]])
],[
	AC_DEFINE(HAVE_CPU_SET, 1)
	AC_MSG_RESULT([yes])
],[
	AC_MSG_RESULT([no])
])

# First check if the function is available at all.
AC_CHECK_FUNCS([sched_setaffinity],[
	# Okay, we have it.  Check if also have cpu_set_t.  If we don't,
	# then we have the first version using unsigned long, and no
	# CPU_ZERO, etc. macros.  If we do have cpu_set_t, we may have the
	# version with 2 or 3 arguments.  In that case, CPU_ZERO, etc.,
	# should also be present, but we confirm nonetheless.

	AS_IF([test "x$have_cpu_set_t" = "xyes"], [
		# We do have it.
		# Check how many arguments does sched_setaffinity take.
		# Should be 3 or 2.
		AC_MSG_CHECKING([how many arguments sched_setaffinity takes])
		AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
				#include <sched.h>
				int main()
				{
					cpu_set_t foo;
					sched_setaffinity(0, sizeof (foo), &foo);
					return 0;
				}
			]])
		],
		[sched_set_affinity_args=3],
		[sched_set_affinity_args=2])
		AC_DEFINE_UNQUOTED(SCHED_SETAFFINITY_ARGS,
			$sched_set_affinity_args,
			[Defined to sched_setaffinity's number of arguments.])
		AC_MSG_RESULT([$sched_set_affinity_args])
	],[
		# No cpu_set_t, always 3 args.
		AC_DEFINE(SCHED_SETAFFINITY_ARGS, 3)
	])
])

DEFAULT_INCLUDES="-include config.h"
AC_SUBST(DEFAULT_INCLUDES)

AC_CONFIG_LINKS([
	include/urcu/arch.h:$ARCHSRC
	include/urcu/uatomic.h:$UATOMICSRC
])
AC_CONFIG_FILES([
	Makefile
	doc/Makefile
	doc/examples/Makefile
	include/Makefile
	src/Makefile
	tests/Makefile
	tests/common/Makefile
	tests/unit/Makefile
	tests/benchmark/Makefile
	tests/regression/Makefile
	tests/regression/regression_tests
	tests/utils/Makefile
	src/liburcu.pc
	src/liburcu-bp.pc
	src/liburcu-cds.pc
	src/liburcu-qsbr.pc
	src/liburcu-mb.pc
	src/liburcu-signal.pc
])
AC_OUTPUT

# Report on selected configure options
AS_IF([test "x$def_smp_support" = "xyes"],[
	AS_ECHO("SMP support enabled.")
],[
	AS_ECHO("SMP support disabled.")
])

AS_IF([test "x$def_tls_detect" = "x"],[
	AS_ECHO("Thread Local Storage (TLS): pthread_getspecific().")
],[
	AS_ECHO("Thread Local Storage (TLS): $def_tls_detect.")
])
Commit	Line	Data
074c3a1b	1	AC_PREREQ(2.59)
1ef91570	2	AC_INIT([userspace-rcu],[0.9.0],[mathieu dot desnoyers at efficios dot com], [], [http://liburcu.org/])
98bc124a YB	3
	4	# Following the numbering scheme proposed by libtool for the library version
	5	# http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
9e5f4ff4	6	AC_SUBST([URCU_LIBRARY_VERSION], [5:0:1])
98bc124a	7
6893800a	8	AC_CONFIG_HEADERS([include/config.h include/urcu/config.h])
48d848c7	9	AC_CONFIG_AUX_DIR([config])
074c3a1b MJ	10	AC_CONFIG_MACRO_DIR([m4])
074c3a1b MJ	11
7d413817 MD	12	AC_CANONICAL_TARGET
7d413817 MD	13	AC_CANONICAL_HOST
074c3a1b	14
6893800a	15	AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip nostdinc])
35eb2d6c	16	AM_MAINTAINER_MODE([enable])
7d413817	17
074c3a1b MJ	18	# Enable silent rules if available (Introduced in AM 1.11)
074c3a1b MJ	19	m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
e72596d1	20
02be5561 MD	21	AH_TEMPLATE([CONFIG_RCU_SMP], [Enable SMP support. With SMP support enabled, uniprocessors are also supported. With SMP support disabled, UP systems work fine, but the behavior of SMP systems is undefined.])
	22	AH_TEMPLATE([CONFIG_RCU_HAVE_FENCE], [Defined when on a system that has memory fence instructions.])
	23	AH_TEMPLATE([CONFIG_RCU_HAVE_FUTEX], [Defined when on a system with futex support.])
a6412536 AM	24	AH_TEMPLATE([CONFIG_RCU_COMPAT_ARCH], [Compatibility mode for i386 which lacks cmpxchg instruction.])
a6412536 AM	25	AH_TEMPLATE([CONFIG_RCU_ARM_HAVE_DMB], [Use the dmb instruction if available for use on ARM.])
a767fdc3	26	AH_TEMPLATE([CONFIG_RCU_TLS], [TLS provided by the compiler.])
a0307b90	27	AH_TEMPLATE([CONFIG_RCU_HAVE_CLOCK_GETTIME], [clock_gettime() is detected.])
a767fdc3	28
75478b32 MD	29	# Allow overriding storage used for TLS variables.
	30	AC_ARG_ENABLE([compiler-tls],
	31	AS_HELP_STRING([--disable-compiler-tls], [Use pthread_getspecific() to emulate Thread Local Storage (TLS) variables.]),
	32	[def_compiler_tls=$enableval],
	33	[def_compiler_tls="yes"])
	34
	35	# If not overridden, use ax_tls.m4 to check if TLS is available.
	36	AS_IF([test "x$def_compiler_tls" = "xyes"],
	37	[AX_TLS([def_tls_detect=$ac_cv_tls], [:])],
	38	[:])
	39
	40	AS_IF([test "x$def_tls_detect" = "x"],
	41	[:],
	42	[AC_DEFINE_UNQUOTED([CONFIG_RCU_TLS], $def_tls_detect)])
48d848c7	43
074c3a1b MJ	44	# Checks for C compiler
074c3a1b MJ	45	AC_USE_SYSTEM_EXTENSIONS
48d848c7	46	AC_PROG_CC
074c3a1b MJ	47	AC_PROG_CC_STDC
	48
	49	# Checks for programs.
27d5e306	50	AC_PROG_AWK
48d848c7	51	AC_PROG_MAKE_SET
074c3a1b	52	AC_CHECK_PROGS(NPROC, [nproc gnproc])
2350bf7b MJ	53	AC_CHECK_PROGS(GETCONF, [getconf])
	54	AS_IF([test "x$NPROC" != "x"],
	55	[NPROC_CMD=$NPROC],
	56	[AS_IF([test "x$GETCONF" != "x"],
	57	[NPROC_CMD="$GETCONF _NPROCESSORS_ONLN"],
	58	[NPROC_CMD="echo 1"]
	59	)]
	60	)
	61	AC_SUBST([NPROC_CMD], [$NPROC_CMD])
	62
b14a378a	63	LT_INIT
48d848c7 PMF	64
	65	# Checks for typedefs, structures, and compiler characteristics.
	66	AC_C_INLINE
	67	AC_TYPE_PID_T
	68	AC_TYPE_SIZE_T
27d5e306 MJ	69	AC_TYPE_SSIZE_T
27d5e306 MJ	70	AC_TYPE_UINT16_T
991d28ca JR	71	AC_TYPE_INT32_T
	72	AC_TYPE_UINT32_T
	73	AC_TYPE_UINT64_T
	74	AC_TYPE_UINT8_T
48d848c7	75
074c3a1b MJ	76	AX_C___ATTRIBUTE__
	77	AS_IF([test "x$ax_cv___attribute__" = "xyes"],
	78	[:],
	79	[AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])
	80
	81	AX_PTHREAD(,[AC_MSG_ERROR([Could not configure pthreads support])])
	82	LIBS="$PTHREAD_LIBS $LIBS"
	83	CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
	84	CC="$PTHREAD_CC"
	85
48d848c7 PMF	86	# Checks for library functions.
	87	AC_FUNC_MALLOC
	88	AC_FUNC_MMAP
27d5e306 MJ	89	AC_FUNC_FORK
	90	AC_CHECK_FUNCS([ \
	91	atexit \
27d5e306 MJ	92	getcpuid \
	93	gettid \
	94	gettimeofday \
	95	memeset \
	96	memset \
	97	munmap \
	98	sched_getcpu \
	99	strerror \
	100	strtoul \
	101	sysconf \
	102	])
48d848c7	103
bb6afa9a	104	# Check for headers
7dea28e7	105	AC_HEADER_STDBOOL
27d5e306 MJ	106	AC_CHECK_HEADERS([ \
	107	limits.h \
	108	stddef.h \
	109	sys/param.h \
	110	sys/time.h \
	111	])
bb6afa9a	112
48d848c7	113	# Find arch type
58e9f838	114	AS_CASE([$host_cpu],
52fe6e60	115	[k1om], [ARCHTYPE="x86"],
a6412536 AM	116	[i386], [ARCHTYPE="x86" && SUBARCHTYPE="x86compat"],
	117	[i486], [ARCHTYPE="x86"],
	118	[i586], [ARCHTYPE="x86"],
	119	[i686], [ARCHTYPE="x86"],
	120	[amd64], [ARCHTYPE="x86"],
	121	[x86_64], [ARCHTYPE="x86"],
	122	[powerpc], [ARCHTYPE="ppc"],
	123	[ppc64], [ARCHTYPE="ppc"],
	124	[powerpc64], [ARCHTYPE="ppc"],
61126bd9	125	[powerpc64le], [ARCHTYPE="ppc"],
a6412536 AM	126	[ppc], [ARCHTYPE="ppc"],
	127	[s390], [ARCHTYPE="s390"],
	128	[s390x], [ARCHTYPE="s390"],
171ff3a3	129	[sparc], [ARCHTYPE="sparc64"],
a6412536 AM	130	[sparc64], [ARCHTYPE="sparc64"],
a6412536 AM	131	[alpha*], [ARCHTYPE="alpha"],
c21a8d01	132	[ia64], [ARCHTYPE="ia64"],
a6412536	133	[arm*], [ARCHTYPE="arm"],
d1c67842	134	[aarch64*], [ARCHTYPE="aarch64"],
e1259cb1	135	[mips*], [ARCHTYPE="mips"],
859050b3	136	[nios2*], [ARCHTYPE="nios2"],
c23069c6	137	[tile*], [ARCHTYPE="tile"],
13e0bc72	138	[hppa*], [ARCHTYPE="hppa"],
a6412536 AM	139	[ARCHTYPE="unknown"]
a6412536 AM	140	)
91b0650a	141
b129d5d7 SB	142	AS_CASE([$host],[-cygwin],
	143	[AM_CONDITIONAL(USE_CYGWIN, true)],
	144	[AM_CONDITIONAL(USE_CYGWIN, false)]
	145	)
	146
a6412536 AM	147	AC_SUBST(ARCHTYPE)
a6412536 AM	148	AC_SUBST(SUBARCHTYPE)
5e626e0e	149
6893800a MJ	150	UATOMICSRC=include/urcu/uatomic/$ARCHTYPE.h
6893800a MJ	151	ARCHSRC=include/urcu/arch/$ARCHTYPE.h
455b809a	152
a6412536 AM	153	AS_IF([test "x$SUBARCHTYPE" = xx86compat],[
	154	AC_DEFINE([CONFIG_RCU_COMPAT_ARCH], [1])
	155	])
	156
58e9f838	157	AS_IF([test "$host_cpu" = "armv7l"],[
a6412536 AM	158	CFLAGS="$CFLAGS -mcpu=cortex-a9 -mtune=cortex-a9 -O1"
a6412536 AM	159	])
48d848c7	160
a6412536 AM	161	# ARM-specific checks
	162	AS_IF([test "x$ARCHTYPE" = "xarm"],[
	163	AC_MSG_CHECKING([for dmb instruction])
fe0707ab MD	164	AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
	165	int main()
	166	{
	167	asm volatile("dmb":::"memory");
	168	return 0;
	169	}
	170	]])
	171	],[
a6412536 AM	172	AC_MSG_RESULT([yes])
	173	AC_DEFINE([CONFIG_RCU_ARM_HAVE_DMB], [1])
	174	],[
	175	AC_MSG_RESULT([no])
	176	])
	177	])
	178
274773cf SM	179	# Tile-specific checks
	180	AS_IF([echo "$host_cpu" \| grep "^tile"],[
	181	AC_MSG_CHECKING([for Tile architecture type])
	182	AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
	183	#ifndef __tilegx__
	184	#error
	185	#endif
	186	]])
	187	],[
	188	AC_MSG_RESULT([ok])
	189	],[
	190	AC_MSG_FAILURE([URCU has only been tested on the TileGx architecture. For other Tile* architectures, please run the tests first and report the results to the maintainer so that proper support can be added.])
	191	])
	192	])
	193
a6412536 AM	194	# x86-specific checks
	195	AS_IF([test "x$ARCHTYPE" = "xx86"],[
	196	AC_MSG_CHECKING([if architecture really supports the mfence instruction])
	197	#For now, using lock; addl compatibility mode even for i686, because the
	198	#Pentium III is seen as a i686, but lacks mfence instruction.
	199	#Only using fence for x86_64.
8496c886 SM	200	#
	201	#k1om is the name for the Intel MIC family (Xeon Phi). It is an x86_64
	202	#variant but lacks fence instructions.
52fe6e60	203	AS_IF([test "x$host_cpu" != "xi386" -a "x$host_cpu" != "xi486" -a "x$host_cpu" != "xi586" -a "x$host_cpu" != "xi686" -a "x$host_vendor" != "xk1om" -a "x$host_cpu" != "xk1om"],[
a6412536 AM	204	AC_MSG_RESULT([yes])
	205	AC_DEFINE([CONFIG_RCU_HAVE_FENCE], [1])
	206	],[
	207	AC_MSG_RESULT([no])
	208	])
	209	])
	210
	211	# Check if sys_futex() is available
	212	AC_MSG_CHECKING([for sys_futex()])
fe0707ab	213	AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
a6412536	214	#include <sys/syscall.h>
a6412536 AM	215	#ifndef __NR_futex
	216	#error "futexes not available"
	217	#endif
fe0707ab	218	]])
a6412536	219	],[
0854ccff	220	AC_MSG_RESULT([yes])
02be5561	221	AC_DEFINE([CONFIG_RCU_HAVE_FUTEX], [1])
0854ccff	222	compat_futex_test=0
91b0650a	223	],[
0854ccff MD	224	AC_MSG_RESULT([no])
0854ccff MD	225	compat_futex_test=1
91b0650a	226	])
0854ccff	227
8be0fb5f	228	# Search for clock_gettime
a0307b90 MD	229	AC_SEARCH_LIBS([clock_gettime], [rt], [
	230	AC_DEFINE([CONFIG_RCU_HAVE_CLOCK_GETTIME], [1])
	231	], [])
8be0fb5f	232
a6412536 AM	233	AM_CONDITIONAL([COMPAT_FUTEX], [test "x$compat_futex_test" = "x1"])
a6412536 AM	234	AM_CONDITIONAL([COMPAT_ARCH], [test "x$SUBARCHTYPE" = "xx86compat"])
2f49a496	235	AM_CONDITIONAL([NO_SHARED], [test "x$enable_shared" = "xno"])
0854ccff	236
a6412536 AM	237	# smp-support configure option
	238	AC_ARG_ENABLE([smp-support],
	239	AS_HELP_STRING([--disable-smp-support], [Disable SMP support. Warning: only use this on uniprocessor systems. [default=enabled]]),
	240	[def_smp_support=$enableval],
	241	[def_smp_support="yes"])
	242	AS_IF([test "x$def_smp_support" = "xyes"], [AC_DEFINE([CONFIG_RCU_SMP], [1])])
7d413817	243
48d848c7	244
d8540fc5 PA	245	# From the sched_setaffinity(2)'s man page:
	246	# ~~~~
	247	# The CPU affinity system calls were introduced in Linux kernel 2.5.8.
	248	# The library interfaces were introduced in glibc 2.3. Initially, the
	249	# glibc interfaces included a cpusetsize argument. In glibc 2.3.3,
	250	# the cpuset size argument was removed, but this argument was
	251	# restored in glibc 2.3.4.
	252	# ~~~~
	253
	254	# In addition to that, some vendors ported the system call to 2.4
	255	# kernels.
	256
	257	# Furthermore, when the function first appeared, the MASK argument was
	258	# an unsigned long pointer, while later it was made into a cpu_set_t
	259	# pointer. Systems that have the cpu_set_t version also should have
	260	# the CPU_ZERO, CPU_SET, etc. macros.
	261
	262	# All this mess means we have to cater for at least 3 different
	263	# sched_setaffinity prototypes:
	264
	265	# ~~~~
	266	# int sched_setaffinity (pid_t pid, unsigned int len, unsigned long *mask);
	267	# int sched_setaffinity (pid_t __pid, size_t __cpusetsize, const cpu_set_t *__cpuset);
	268	# int sched_setaffinity (pid_t __pid, const cpu_set_t *__mask);
	269	# ~~~~
	270
b3231c17 MD	271	AC_CHECK_TYPES([cpu_set_t],
	272	[have_cpu_set_t="yes"],
	273	[have_cpu_set_t="no"],
	274	[#include <sched.h>])
	275
	276	# Confirm that we have CPU_ZERO, and it actually works.
	277	AC_MSG_CHECKING([whether CPU_ZERO works])
	278	AH_TEMPLATE([HAVE_CPU_ZERO], [Defined to 1 if we have CPU_ZERO and it works])
	279	AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
b3231c17 MD	280	#include <sched.h>
	281	int main()
	282	{
	283	cpu_set_t foo; CPU_ZERO(&foo);
	284	return 0;
	285	}
	286	]])
	287	],[
	288	AC_DEFINE(HAVE_CPU_ZERO, 1)
	289	AC_MSG_RESULT([yes])
	290	],[
	291	AC_MSG_RESULT([no])
	292	])
	293
	294	# Confirm that we have CPU_SET, and it actually works.
	295	AC_MSG_CHECKING([whether CPU_SET works])
	296	AH_TEMPLATE([HAVE_CPU_SET], [Defined to 1 if we have CPU_SET and it works])
	297	AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
b3231c17 MD	298	#include <sched.h>
	299	int main()
	300	{
	301	cpu_set_t foo, mask; CPU_SET(0, &foo);
	302	return 0;
	303	}
	304	]])
	305	],[
	306	AC_DEFINE(HAVE_CPU_SET, 1)
	307	AC_MSG_RESULT([yes])
	308	],[
	309	AC_MSG_RESULT([no])
	310	])
	311
d8540fc5	312	# First check if the function is available at all.
a6412536 AM	313	AC_CHECK_FUNCS([sched_setaffinity],[
	314	# Okay, we have it. Check if also have cpu_set_t. If we don't,
	315	# then we have the first version using unsigned long, and no
	316	# CPU_ZERO, etc. macros. If we do have cpu_set_t, we may have the
	317	# version with 2 or 3 arguments. In that case, CPU_ZERO, etc.,
	318	# should also be present, but we confirm nonetheless.
	319
b3231c17 MD	320	AS_IF([test "x$have_cpu_set_t" = "xyes"], [
b3231c17 MD	321	# We do have it.
a6412536 AM	322	# Check how many arguments does sched_setaffinity take.
	323	# Should be 3 or 2.
	324	AC_MSG_CHECKING([how many arguments sched_setaffinity takes])
ec5e2d14	325	AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
a6412536	326	#include <sched.h>
fe0707ab MD	327	int main()
	328	{
	329	cpu_set_t foo;
b3231c17	330	sched_setaffinity(0, sizeof (foo), &foo);
fe0707ab MD	331	return 0;
fe0707ab MD	332	}
a6412536 AM	333	]])
	334	],
	335	[sched_set_affinity_args=3],
	336	[sched_set_affinity_args=2])
b3231c17 MD	337	AC_DEFINE_UNQUOTED(SCHED_SETAFFINITY_ARGS,
b3231c17 MD	338	$sched_set_affinity_args,
a6412536 AM	339	[Defined to sched_setaffinity's number of arguments.])
	340	AC_MSG_RESULT([$sched_set_affinity_args])
	341	],[
	342	# No cpu_set_t, always 3 args.
	343	AC_DEFINE(SCHED_SETAFFINITY_ARGS, 3)
b3231c17	344	])
a6412536	345	])
d8540fc5	346
6893800a MJ	347	DEFAULT_INCLUDES="-include config.h"
6893800a MJ	348	AC_SUBST(DEFAULT_INCLUDES)
d8540fc5	349
455b809a	350	AC_CONFIG_LINKS([
6893800a MJ	351	include/urcu/arch.h:$ARCHSRC
6893800a MJ	352	include/urcu/uatomic.h:$UATOMICSRC
455b809a	353	])
48d848c7 PMF	354	AC_CONFIG_FILES([
48d848c7 PMF	355	Makefile
fe999c05	356	doc/Makefile
8bad63a0	357	doc/examples/Makefile
6893800a MJ	358	include/Makefile
6893800a MJ	359	src/Makefile
48d848c7	360	tests/Makefile
f5ab766e MD	361	tests/common/Makefile
	362	tests/unit/Makefile
	363	tests/benchmark/Makefile
	364	tests/regression/Makefile
074c3a1b	365	tests/regression/regression_tests
1b387491	366	tests/utils/Makefile
6893800a MJ	367	src/liburcu.pc
	368	src/liburcu-bp.pc
	369	src/liburcu-cds.pc
	370	src/liburcu-qsbr.pc
	371	src/liburcu-mb.pc
	372	src/liburcu-signal.pc
48d848c7 PMF	373	])
48d848c7 PMF	374	AC_OUTPUT
a6412536 AM	375
	376	# Report on selected configure options
	377	AS_IF([test "x$def_smp_support" = "xyes"],[
	378	AS_ECHO("SMP support enabled.")
	379	],[
	380	AS_ECHO("SMP support disabled.")
	381	])
75478b32 MD	382
	383	AS_IF([test "x$def_tls_detect" = "x"],[
	384	AS_ECHO("Thread Local Storage (TLS): pthread_getspecific().")
	385	],[
	386	AS_ECHO("Thread Local Storage (TLS): $def_tls_detect.")
	387	])