uatomic: style fix
[urcu.git] / configure.ac
CommitLineData
48d848c7
PMF
1# -*- Autoconf -*-
2# Process this file with autoconf to produce a configure script.
3
4
ae51baf2 5AC_INIT([userspace-rcu],[0.7.4],[mathieu dot desnoyers at efficios dot com])
98bc124a
YB
6
7# Following the numbering scheme proposed by libtool for the library version
8# http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
1de4df4b 9AC_SUBST([URCU_LIBRARY_VERSION], [2:0:0])
98bc124a 10
48d848c7 11AC_CONFIG_AUX_DIR([config])
a6412536 12AC_CONFIG_MACRO_DIR([config])
7d413817
MD
13AC_CANONICAL_TARGET
14AC_CANONICAL_HOST
48d848c7 15AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip])
806f8114
PB
16m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
17
a767fdc3
MD
18m4_include([config/ax_tls.m4])
19
48d848c7 20AC_CONFIG_SRCDIR([urcu.h])
7d413817 21
e72596d1
MD
22AC_CONFIG_HEADERS([config.h urcu/config.h])
23
02be5561
MD
24AH_TEMPLATE([CONFIG_RCU_SMP], [Enable SMP support. With SMP support enabled, uniprocessors are also supported. With SMP support disabled, UP systems work fine, but the behavior of SMP systems is undefined.])
25AH_TEMPLATE([CONFIG_RCU_HAVE_FENCE], [Defined when on a system that has memory fence instructions.])
26AH_TEMPLATE([CONFIG_RCU_HAVE_FUTEX], [Defined when on a system with futex support.])
a6412536
AM
27AH_TEMPLATE([CONFIG_RCU_COMPAT_ARCH], [Compatibility mode for i386 which lacks cmpxchg instruction.])
28AH_TEMPLATE([CONFIG_RCU_ARM_HAVE_DMB], [Use the dmb instruction if available for use on ARM.])
a767fdc3
MD
29AH_TEMPLATE([CONFIG_RCU_TLS], [TLS provided by the compiler.])
30
75478b32
MD
31# Allow overriding storage used for TLS variables.
32AC_ARG_ENABLE([compiler-tls],
33 AS_HELP_STRING([--disable-compiler-tls], [Use pthread_getspecific() to emulate Thread Local Storage (TLS) variables.]),
34 [def_compiler_tls=$enableval],
35 [def_compiler_tls="yes"])
36
37# If not overridden, use ax_tls.m4 to check if TLS is available.
38AS_IF([test "x$def_compiler_tls" = "xyes"],
39 [AX_TLS([def_tls_detect=$ac_cv_tls], [:])],
40 [:])
41
42AS_IF([test "x$def_tls_detect" = "x"],
43 [:],
44 [AC_DEFINE_UNQUOTED([CONFIG_RCU_TLS], $def_tls_detect)])
48d848c7
PMF
45
46# Checks for programs.
47AC_PROG_CC
48AC_PROG_MAKE_SET
b14a378a 49LT_INIT
48d848c7
PMF
50
51# Checks for typedefs, structures, and compiler characteristics.
52AC_C_INLINE
53AC_TYPE_PID_T
54AC_TYPE_SIZE_T
55
56# Checks for library functions.
57AC_FUNC_MALLOC
58AC_FUNC_MMAP
b57aee66 59AC_CHECK_FUNCS([bzero gettimeofday munmap sched_getcpu strtoul sysconf])
48d848c7
PMF
60
61# Find arch type
58e9f838 62AS_CASE([$host_cpu],
a6412536
AM
63 [i386], [ARCHTYPE="x86" && SUBARCHTYPE="x86compat"],
64 [i486], [ARCHTYPE="x86"],
65 [i586], [ARCHTYPE="x86"],
66 [i686], [ARCHTYPE="x86"],
67 [amd64], [ARCHTYPE="x86"],
68 [x86_64], [ARCHTYPE="x86"],
69 [powerpc], [ARCHTYPE="ppc"],
70 [ppc64], [ARCHTYPE="ppc"],
71 [powerpc64], [ARCHTYPE="ppc"],
72 [ppc], [ARCHTYPE="ppc"],
73 [s390], [ARCHTYPE="s390"],
74 [s390x], [ARCHTYPE="s390"],
75 [sparc64], [ARCHTYPE="sparc64"],
76 [alpha*], [ARCHTYPE="alpha"],
77 [ia64], [ARCHTYPE="gcc"],
78 [arm*], [ARCHTYPE="arm"],
e1259cb1 79 [mips*], [ARCHTYPE="mips"],
1000f1f4 80 [tile*], [ARCHTYPE="tile"],
a6412536
AM
81 [ARCHTYPE="unknown"]
82)
91b0650a 83
a6412536
AM
84AC_SUBST(ARCHTYPE)
85AC_SUBST(SUBARCHTYPE)
5e626e0e 86
a2e7bf9c 87UATOMICSRC=urcu/uatomic/$ARCHTYPE.h
1b9119f8 88ARCHSRC=urcu/arch/$ARCHTYPE.h
455b809a 89
a6412536
AM
90AS_IF([test "x$SUBARCHTYPE" = xx86compat],[
91 AC_DEFINE([CONFIG_RCU_COMPAT_ARCH], [1])
92])
93
58e9f838 94AS_IF([test "$host_cpu" = "armv7l"],[
a6412536
AM
95 CFLAGS="$CFLAGS -mcpu=cortex-a9 -mtune=cortex-a9 -O1"
96])
48d848c7 97
a6412536
AM
98# ARM-specific checks
99AS_IF([test "x$ARCHTYPE" = "xarm"],[
100 AC_MSG_CHECKING([for dmb instruction])
fe0707ab
MD
101 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
102 int main()
103 {
104 asm volatile("dmb":::"memory");
105 return 0;
106 }
107 ]])
108 ],[
a6412536
AM
109 AC_MSG_RESULT([yes])
110 AC_DEFINE([CONFIG_RCU_ARM_HAVE_DMB], [1])
111 ],[
112 AC_MSG_RESULT([no])
113 ])
114])
115
116# x86-specific checks
117AS_IF([test "x$ARCHTYPE" = "xx86"],[
118 AC_MSG_CHECKING([if architecture really supports the mfence instruction])
119 #For now, using lock; addl compatibility mode even for i686, because the
120 #Pentium III is seen as a i686, but lacks mfence instruction.
121 #Only using fence for x86_64.
58e9f838 122 AS_IF([test "x$host_cpu" != "xi386" -a "x$host_cpu" != "xi486" -a "x$host_cpu" != "xi586" -a "x$host_cpu" != "xi686"],[
a6412536
AM
123 AC_MSG_RESULT([yes])
124 AC_DEFINE([CONFIG_RCU_HAVE_FENCE], [1])
125 ],[
126 AC_MSG_RESULT([no])
127 ])
128])
129
130# Check if sys_futex() is available
131AC_MSG_CHECKING([for sys_futex()])
fe0707ab 132AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
a6412536 133 #include <sys/syscall.h>
a6412536
AM
134 #ifndef __NR_futex
135 #error "futexes not available"
136 #endif
fe0707ab 137 ]])
a6412536 138],[
0854ccff 139 AC_MSG_RESULT([yes])
02be5561 140 AC_DEFINE([CONFIG_RCU_HAVE_FUTEX], [1])
0854ccff 141 compat_futex_test=0
91b0650a 142],[
0854ccff
MD
143 AC_MSG_RESULT([no])
144 compat_futex_test=1
91b0650a 145])
0854ccff 146
a6412536
AM
147AM_CONDITIONAL([COMPAT_FUTEX], [test "x$compat_futex_test" = "x1"])
148AM_CONDITIONAL([COMPAT_ARCH], [test "x$SUBARCHTYPE" = "xx86compat"])
0854ccff 149
a6412536
AM
150# smp-support configure option
151AC_ARG_ENABLE([smp-support],
152 AS_HELP_STRING([--disable-smp-support], [Disable SMP support. Warning: only use this on uniprocessor systems. [default=enabled]]),
153 [def_smp_support=$enableval],
154 [def_smp_support="yes"])
155AS_IF([test "x$def_smp_support" = "xyes"], [AC_DEFINE([CONFIG_RCU_SMP], [1])])
7d413817 156
48d848c7 157
d8540fc5
PA
158# From the sched_setaffinity(2)'s man page:
159# ~~~~
160# The CPU affinity system calls were introduced in Linux kernel 2.5.8.
161# The library interfaces were introduced in glibc 2.3. Initially, the
162# glibc interfaces included a cpusetsize argument. In glibc 2.3.3,
163# the cpuset size argument was removed, but this argument was
164# restored in glibc 2.3.4.
165# ~~~~
166
167# In addition to that, some vendors ported the system call to 2.4
168# kernels.
169
170# Furthermore, when the function first appeared, the MASK argument was
171# an unsigned long pointer, while later it was made into a cpu_set_t
172# pointer. Systems that have the cpu_set_t version also should have
173# the CPU_ZERO, CPU_SET, etc. macros.
174
175# All this mess means we have to cater for at least 3 different
176# sched_setaffinity prototypes:
177
178# ~~~~
179# int sched_setaffinity (pid_t pid, unsigned int len, unsigned long *mask);
180# int sched_setaffinity (pid_t __pid, size_t __cpusetsize, const cpu_set_t *__cpuset);
181# int sched_setaffinity (pid_t __pid, const cpu_set_t *__mask);
182# ~~~~
183
a6412536
AM
184# Since we define _GNU_SOURCE in the sources, must do so too in the
185# autoconf tests, as defining _GNU_SOURCE or not exposes
186# sched_setaffinity bits differently.
d8540fc5
PA
187saved_CFLAGS=$CFLAGS
188CFLAGS="$CFLAGS -D_GNU_SOURCE"
189
190# First check if the function is available at all.
a6412536
AM
191AC_CHECK_FUNCS([sched_setaffinity],[
192 # Okay, we have it. Check if also have cpu_set_t. If we don't,
193 # then we have the first version using unsigned long, and no
194 # CPU_ZERO, etc. macros. If we do have cpu_set_t, we may have the
195 # version with 2 or 3 arguments. In that case, CPU_ZERO, etc.,
196 # should also be present, but we confirm nonetheless.
197
198 AC_CHECK_TYPES([cpu_set_t],[
199 # We do have it. Confirm that we have CPU_ZERO, and it actually works.
200 AC_MSG_CHECKING([whether CPU_ZERO works])
201 AH_TEMPLATE([HAVE_CPU_ZERO], [Defined to 1 if we have CPU_ZERO and it works])
ec5e2d14 202 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
a6412536
AM
203 #define _GNU_SOURCE
204 #include <sched.h>
fe0707ab
MD
205 int main()
206 {
207 cpu_set_t foo; CPU_ZERO (&foo);
208 return 0;
209 }
a6412536
AM
210 ]])
211 ],[
212 # Works!
213 AC_DEFINE(HAVE_CPU_ZERO, 1)
214 AC_MSG_RESULT([yes])
215 ],[
216 AC_MSG_RESULT([no])
217 ])
218
219 # Check how many arguments does sched_setaffinity take.
220 # Should be 3 or 2.
221 AC_MSG_CHECKING([how many arguments sched_setaffinity takes])
ec5e2d14 222 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
a6412536 223 #include <sched.h>
fe0707ab
MD
224 int main()
225 {
226 cpu_set_t foo;
227 sched_setaffinity (0, sizeof (foo), &foo);
228 return 0;
229 }
a6412536
AM
230 ]])
231 ],
232 [sched_set_affinity_args=3],
233 [sched_set_affinity_args=2])
234 AC_DEFINE_UNQUOTED(SCHED_SETAFFINITY_ARGS, $sched_set_affinity_args,
235 [Defined to sched_setaffinity's number of arguments.])
236 AC_MSG_RESULT([$sched_set_affinity_args])
237 ],[
238 # No cpu_set_t, always 3 args.
239 AC_DEFINE(SCHED_SETAFFINITY_ARGS, 3)
240 ],
241 [#include <sched.h>])
242])
d8540fc5
PA
243
244CFLAGS=$saved_CFLAGS
245
455b809a
PB
246AC_CONFIG_LINKS([
247 urcu/arch.h:$ARCHSRC
a2e7bf9c 248 urcu/uatomic.h:$UATOMICSRC
455b809a 249])
48d848c7
PMF
250AC_CONFIG_FILES([
251 Makefile
fe999c05 252 doc/Makefile
48d848c7 253 tests/Makefile
2260a36c
YB
254 liburcu.pc
255 liburcu-bp.pc
a6412536 256 liburcu-cds.pc
2260a36c
YB
257 liburcu-qsbr.pc
258 liburcu-mb.pc
259 liburcu-signal.pc
48d848c7
PMF
260])
261AC_OUTPUT
a6412536
AM
262
263# Report on selected configure options
264AS_IF([test "x$def_smp_support" = "xyes"],[
265 AS_ECHO("SMP support enabled.")
266],[
267 AS_ECHO("SMP support disabled.")
268])
75478b32
MD
269
270AS_IF([test "x$def_tls_detect" = "x"],[
271 AS_ECHO("Thread Local Storage (TLS): pthread_getspecific().")
272],[
273 AS_ECHO("Thread Local Storage (TLS): $def_tls_detect.")
274])
This page took 0.053846 seconds and 4 git commands to generate.