[lttng-ust.git] / configure.ac

dnl                                               -*- Autoconf -*-
dnl Process this file with autoconf to produce a configure script.

dnl Version infos
m4_define([V_MAJOR], [2])
m4_define([V_MINOR], [8])
m4_define([V_PATCH], [0])
m4_define([V_EXTRA], [pre])
m4_define([V_STRING], [V_MAJOR.V_MINOR.V_PATCH])
m4_ifdef([V_EXTRA], [m4_append([V_STRING], [-V_EXTRA])])
m4_define([V_NAME], [[Herbe à Détourne]])
m4_define([V_DESC], [[Brewed with unrestrained amounts of Citra hop, the Herbe à Détourne is a fantastic New World Tripel brewed by "Dieu du Ciel!". Aromas of mango, cantaloupe melon and passion fruit, combined with a controlled bitter finish, unite in making this smooth golden-orange beer stand apart.]])

AC_INIT([lttng-ust],V_STRING,[mathieu dot desnoyers at efficios dot com])

# Following the numbering scheme proposed by libtool for the library version
# http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
# This is the library version of liblttng-ust.
AC_SUBST([LTTNG_UST_LIBRARY_VERSION], [0:0:0])
# note: remember to update tracepoint.h dlopen() to match this version
# number. TODO: eventually automate by exporting the major number.

# This is the library version of liblttng-ust-ctl, used internally by
# liblttng-ust, lttng-sessiond, and lttng-consumerd.
AC_SUBST([LTTNG_UST_CTL_LIBRARY_VERSION], [2:0:0])

AC_CONFIG_AUX_DIR([config])
AC_CANONICAL_TARGET
AC_CANONICAL_HOST
AC_CONFIG_MACRO_DIR([config])
AM_INIT_AUTOMAKE([1.9 foreign dist-bzip2 no-dist-gzip tar-ustar])
AM_MAINTAINER_MODE([enable])
m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
AC_CONFIG_SRCDIR([include/lttng/tracepoint.h])

# Configuration options, which will be installed in the config.h
AC_CONFIG_HEADERS([config.h include/lttng/ust-config.h])
AH_TEMPLATE([LTTNG_UST_HAVE_EFFICIENT_UNALIGNED_ACCESS], [Use efficient unaligned access.])
AH_TEMPLATE([LTTNG_UST_HAVE_SDT_INTEGRATION], [SystemTap integration via sdt.h])
AH_TEMPLATE([LTTNG_UST_HAVE_PERF_EVENT], [Perf event integration via perf_event.h])

dnl Substitute minor/major/patchlevel version numbers
AC_SUBST([MAJOR_VERSION], [V_MAJOR])
AC_SUBST([MINOR_VERSION], [V_MINOR])
AC_SUBST([PATCHLEVEL_VERSION], [V_PATCH])

AC_PROG_SED
AC_PROG_GREP
AC_PROG_LN_S

# libtool link_all_deplibs fixup. See http://bugs.lttng.org/issues/321.
AC_ARG_ENABLE([libtool-linkdep-fixup],
	AS_HELP_STRING([--disable-libtool-linkdep-fixup],
			[disable the libtool fixup for linking all dependent libraries (link_all_deplibs)]),
	[libtool_fixup=$enableval],
	[libtool_fixup=yes])

AS_IF([test "x$libtool_fixup" = "xyes"],
	    [
	    libtool_m4="$srcdir/config/libtool.m4"
	    libtool_flag_pattern=".*link_all_deplibs\s*,\s*\$1\s*)"
	    AC_MSG_CHECKING([for occurence(s) of link_all_deplibs = no in $libtool_m4])
	    libtool_flag_pattern_count=$(grep -c "$libtool_flag_pattern\s*=\s*no" $libtool_m4)
	    AS_IF([test $libtool_flag_pattern_count -ne 0],
	    [
		  AC_MSG_RESULT([$libtool_flag_pattern_count])
		  AC_MSG_WARN([the detected libtool will not link all dependencies, forcing link_all_deplibs = unknown])
		  sed -i "s/\($libtool_flag_pattern\)\s*=\s*no/\1=unknown/g" $libtool_m4
		  ],
		  [
		  AC_MSG_RESULT([none])
		  ])
	    ])

AM_CONDITIONAL([NO_SHARED], [test "x$enable_shared" = "xno"])

# Checks for programs.
AC_PROG_CC
AC_PROG_CXX
AC_PROG_MAKE_SET
LT_INIT

# rw_PROG_CXX_WORKS
# Check whether the C++ compiler works.
AC_CACHE_CHECK([whether the C++ compiler works],
		[rw_cv_prog_cxx_works],
		[AC_LANG_PUSH([C++])
		AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
				[check_cxx_designated_initializers=yes],
				[rw_cv_prog_cxx_works=no])
		AS_IF([test "x$check_cxx_designated_initializers" = "xyes"], [
			AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
				struct foo { int a; int b; };
				void fct(void)
				{
					struct foo f = { .a = 0, .b = 1 };
				}
			]])],[
				rw_cv_prog_cxx_works=yes
			],[
				rw_cv_prog_cxx_works=no
			])
		])
		AC_LANG_POP([C++])])

AM_CONDITIONAL([CXX_WORKS], [test "x$rw_cv_prog_cxx_works" = "xyes"])

# Check if the compiler support weak symbols
AX_SYS_WEAK_ALIAS

AS_IF([test "x${ax_cv_sys_weak_alias}" = "xno"], [
	AC_MSG_ERROR([Your platform doesn't support weak symbols.])
])

# Checks for libraries.
AC_CHECK_LIB([dl], [dlopen],
[
	have_libdl=yes
],
[
	#libdl not found, check for dlopen in libc.
	AC_CHECK_LIB([c], [dlopen],
	[
		have_libc_dl=yes
	],
	[
		AC_MSG_ERROR([Cannot find dlopen in libdl nor libc. Use [LDFLAGS]=-Ldir to specify their location.])
	])
])
AM_CONDITIONAL([LTTNG_UST_BUILD_WITH_LIBDL], [test "x$have_libdl" = "xyes"])
AM_CONDITIONAL([LTTNG_UST_BUILD_WITH_LIBC_DL], [test "x$have_libc_dl" = "xyes"])

AC_CHECK_LIB([pthread], [pthread_create])

# Check for dlfcn.h
AC_CHECK_HEADER([dlfcn.h])
AS_IF([test "x${ac_cv_header_dlfcn_h}" = "xyes"],
	[AC_CHECK_DECLS([RTLD_DI_LINKMAP],,,
		[#define _GNU_SOURCE /* Required on Linux to get GNU extensions */
		#include <dlfcn.h>])
	],
	[ac_cv_have_decl_RTLD_DI_LINKMAP="no"])
AM_CONDITIONAL([HAVE_DLINFO], [test "x${ac_cv_have_decl_RTLD_DI_LINKMAP}" = "xyes"])

# Checks for header files.
dnl AC_CHECK_HEADERS([fcntl.h stdint.h stdlib.h string.h sys/socket.h sys/time.h unistd.h])

# Checks for typedefs, structures, and compiler characteristics.
AC_C_INLINE
dnl AC_TYPE_INT16_T
dnl AC_TYPE_INT32_T
dnl AC_TYPE_INT64_T
dnl AC_TYPE_INT8_T
dnl AC_TYPE_PID_T
dnl AC_TYPE_SIZE_T
dnl AC_TYPE_SSIZE_T
dnl AC_TYPE_UINT16_T
dnl AC_TYPE_UINT32_T
dnl AC_TYPE_UINT64_T
dnl AC_TYPE_UINT8_T
dnl AC_CHECK_TYPES([ptrdiff_t])

# Checks for library functions.
AC_FUNC_MALLOC
AC_CHECK_FUNCS([gettimeofday munmap socket strerror strtol sched_getcpu sysconf])

CFLAGS="-Wall $CFLAGS"

# URCU

# urcu - check if we just find the headers it out of the box.
AC_CHECK_HEADERS([urcu-bp.h], [], [AC_MSG_ERROR([Cannot find [URCU] headers (urcu-bp.h). Use [CPPFLAGS]=-Idir to specify their location.
This error can also occur when the liburcu package's configure script has not been run.])])

# urcu-cds - check that URCU Concurrent Data Structure lib is available to compilation
# Part of Userspace RCU library 0.7.2 or better.
AC_CHECK_LIB([urcu-cds], [_cds_lfht_new], [], [AC_MSG_ERROR([Cannot find
liburcu-cds lib, part of Userspace RCU 0.7 or better. Use [LDFLAGS]=-Ldir to specify its location.])])

AC_MSG_CHECKING([caa_likely()])
AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
#include <urcu/compiler.h>
void fct(void)
{
	if (caa_likely(1)) {
	}
}
]])],[
	AC_MSG_RESULT([yes])
],[
	AC_MSG_RESULT([no])
	AC_MSG_ERROR([Please upgrade your version of liburcu to 0.6.6 or better])

])

# urcu - check that URCU lib is available to compilation
AC_CHECK_LIB([urcu-bp], [synchronize_rcu_bp], [], [AC_MSG_ERROR([Cannot find liburcu-bp lib. Use [LDFLAGS]=-Ldir to specify its location.])])

# urcu - check that URCU lib is at least version 0.6
AC_CHECK_LIB([urcu-bp], [call_rcu_bp], [], [AC_MSG_ERROR([liburcu 0.6 or newer is needed, please update your version or use [LDFLAGS]=-Ldir to specify the right location.])])

# optional linux/perf_event.h
AC_CHECK_HEADERS([linux/perf_event.h], [have_perf_event=yes], [])

# Perf event counters are only supported on x86 so far.
AC_MSG_CHECKING([UST support for architecture perf event counters])
AS_CASE([$host_cpu],
	[i[[3456]]86], [UST_SUPPORT_FOR_ARCH_PERF_EVENT_COUNTERS=yes],
	[x86_64], [UST_SUPPORT_FOR_ARCH_PERF_EVENT_COUNTERS=yes],
	[amd64], [UST_SUPPORT_FOR_ARCH_PERF_EVENT_COUNTERS=yes],
	[UST_SUPPORT_FOR_ARCH_PERF_EVENT_COUNTERS=no])
AC_MSG_RESULT([$UST_SUPPORT_FOR_ARCH_PERF_EVENT_COUNTERS])

AM_CONDITIONAL([HAVE_PERF_EVENT], [test "x$have_perf_event" = "xyes" && test "x$UST_SUPPORT_FOR_ARCH_PERF_EVENT_COUNTERS" = "xyes"])

AS_IF([test "x$have_perf_event" = "xyes" && test "x$UST_SUPPORT_FOR_ARCH_PERF_EVENT_COUNTERS" = "xyes"], [
	AC_DEFINE([LTTNG_UST_HAVE_PERF_EVENT], [1])
])

AC_MSG_CHECKING([host system alignment requirements])
AS_CASE([$host_cpu],
	[i[[3456]]86], [],
	[x86_64], [],
	[amd64], [],
	[powerpc], [],
	[ppc64], [],
	[ppc64le], [],
	[powerpc64], [],
	[powerpc64le], [],
	[s390], [NO_UNALIGNED_ACCESS=1],
	[s390x], [NO_UNALIGNED_ACCESS=1],
	[arm*], [NO_UNALIGNED_ACCESS=1],
	[aarch64], [NO_UNALIGNED_ACCESS=1],
	[mips*], [NO_UNALIGNED_ACCESS=1],
	[tile*], [NO_UNALIGNED_ACCESS=1],
	[
		UNSUPPORTED_ARCH=1
		NO_UNALIGNED_ACCESS=1
	])
AC_MSG_RESULT([$host_cpu])

AS_IF([test "x$NO_UNALIGNED_ACCESS" = "x"], [
	AC_DEFINE([LTTNG_UST_HAVE_EFFICIENT_UNALIGNED_ACCESS], [1])
])

# Check for JNI header files if requested
AC_ARG_ENABLE([jni-interface],
	[AS_HELP_STRING([--enable-jni-interface],[build JNI interface between C and Java. Needs Java include files [default=no]])],
	[jni_interface=$enableval],
	[jni_interface=no]
)

AM_CONDITIONAL([BUILD_JNI_INTERFACE], [test "x$jni_interface" = "xyes"])


AC_ARG_ENABLE([java-agent-jul],
	[AS_HELP_STRING([--enable-java-agent-jul],[build the LTTng UST Java agent with JUL support [default=no]])],
	[java_agent_jul=$enableval],
	[java_agent_jul=no]
)

AC_ARG_ENABLE([java-agent-log4j],
	[AS_HELP_STRING([--enable-java-agent-log4j],[build the LTTng UST Java agent with Log4j support [default=no]])],
	[java_agent_log4j=$enableval],
	[java_agent_log4j=no]
)

AC_ARG_ENABLE([java-agent-all],
	[AS_HELP_STRING([--enable-java-agent-all],[build the LTTng UST Java agent with all supported backends [default=no]])],
	[java_agent_jul=$enableval
	 java_agent_log4j=$enableval],
	[:]
)


AM_CONDITIONAL([BUILD_JAVA_AGENT], [test "x$java_agent_jul" = "xyes" || test "x$java_agent_log4j" = "xyes"])
AM_CONDITIONAL([BUILD_JAVA_AGENT_WITH_JUL], [test "x$java_agent_jul" = "xyes"])
AM_CONDITIONAL([BUILD_JAVA_AGENT_WITH_LOG4J], [test "x$java_agent_log4j" = "xyes"])

AS_IF([test "x$jni_interface" = "xyes" || test "x$java_agent_jul" = "xyes" || test "x$java_agent_log4j" = "xyes"], [
	AX_JAVA_OPTIONS
	AX_PROG_JAVAC
	AX_PROG_JAVA
	AX_PROG_JAR

	AX_JNI_INCLUDE_DIR
	for JNI_INCLUDE_DIR in $JNI_INCLUDE_DIRS
	do
		CPPFLAGS="$CPPFLAGS -I$JNI_INCLUDE_DIR"
	done

	AX_PROG_JAVAH
])

AS_IF([test "x$java_agent_log4j" = "xyes"], [
	AX_CHECK_CLASSPATH

	AX_CHECK_CLASS([org.apache.log4j.Logger])

	AS_IF([test "x$ac_cv_class_org_apache_log4j_Logger" = "xno"], [
		AC_MSG_ERROR([The UST Java agent support for log4j was requested but the Log4j classes were not found. Please specify the location of the Log4j jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/log4j.jar"])
	])
])

# Option to build the python agent
AC_ARG_ENABLE([python-agent],
	[AS_HELP_STRING([--enable-python-agent],[build the LTTng UST Python agent [default=no]])],
    [python_agent=$enableval],
	[:]
)
AM_CONDITIONAL([BUILD_PYTHON_AGENT], [test "x$python_agent" = "xyes"])
AS_IF([test "x$python_agent" = "xyes"], [
	AM_PATH_PYTHON([2.7])
])

# sdt.h integration
AC_ARG_WITH([sdt],
	[AS_HELP_STRING([--with-sdt],[provide SystemTap integration via sdt.h [default=no]])],
	[with_sdt=$withval],
	[with_sdt="no"]
)

AS_IF([test "x$with_sdt" = "xyes"],[
	AC_MSG_CHECKING([STAP_PROBEV()])
	AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
	#define SDT_USE_VARIADIC
	#include <sys/sdt.h>
	void fct(void)
	{
		STAP_PROBEV(provider,name,1,2,3,4,5,6,7,8,9,10);
	}
	]])],[
		AC_MSG_RESULT([yes])
		AC_DEFINE([LTTNG_UST_HAVE_SDT_INTEGRATION], [1])
	],[
		AC_MSG_RESULT([no])
		AC_MSG_ERROR([The sdt.h integration was requested but the STAP_PROBEV define cannot be used. Make sure it is installed, and up to date, or use CPPFLAGS=-I/path/ to specify a non-standard path to sys/sdt.h])
	])
])

AC_MSG_CHECKING([whether shared libraries are enabled])
AS_IF([test "x$enable_shared" = "xyes"],
	[
		AC_MSG_RESULT([yes])
	],
	[
		AC_MSG_RESULT([no])
		AC_MSG_ERROR([LTTng-UST requires shared libraries to be enabled])
	])

AC_ARG_WITH([lttng-system-rundir],
	AS_HELP_STRING([--with-lttng-system-rundir],
	[Location of the system directory where LTTng-UST expects the system-wide lttng-sessiond runtime files. The default is "/var/run/lttng".]),
	[lttng_system_rundir="$withval"],
	[lttng_system_rundir="/var/run/lttng"])
AC_DEFINE_UNQUOTED([LTTNG_SYSTEM_RUNDIR], ["$lttng_system_rundir"],
	[LTTng system runtime directory])

AC_CHECK_PROG([BUILD_GEN_TP_EXAMPLES],[python],["yes"])
AM_CONDITIONAL([BUILD_GEN_TP_EXAMPLES], [test "x$BUILD_GEN_TP_EXAMPLES" = "xyes"])

AC_CONFIG_FILES([
	Makefile
	doc/Makefile
	doc/examples/Makefile
	include/Makefile
	include/lttng/ust-version.h
	snprintf/Makefile
	libringbuffer/Makefile
	liblttng-ust-comm/Makefile
	liblttng-ust/Makefile
	liblttng-ust-ctl/Makefile
	liblttng-ust-fork/Makefile
	liblttng-ust-dl/Makefile
	liblttng-ust-java/Makefile
	liblttng-ust-java-agent/Makefile
	liblttng-ust-java-agent/java/Makefile
	liblttng-ust-java-agent/java/lttng-ust-agent-common/Makefile
	liblttng-ust-java-agent/java/lttng-ust-agent-jul/Makefile
	liblttng-ust-java-agent/java/lttng-ust-agent-log4j/Makefile
	liblttng-ust-java-agent/jni/Makefile
	liblttng-ust-java-agent/jni/common/Makefile
	liblttng-ust-java-agent/jni/jul/Makefile
	liblttng-ust-java-agent/jni/log4j/Makefile
	liblttng-ust-libc-wrapper/Makefile
	liblttng-ust-cyg-profile/Makefile
	liblttng-ust-python-agent/Makefile
	python-lttngust/Makefile
	python-lttngust/setup.py
	python-lttngust/lttngust/__init__.py
	tools/Makefile
	tests/Makefile
	tests/ctf-types/Makefile
	tests/hello/Makefile
	tests/hello.cxx/Makefile
	tests/same_line_tracepoint/Makefile
	tests/snprintf/Makefile
	tests/ust-elf/Makefile
	tests/benchmark/Makefile
	tests/utils/Makefile
	tests/test-app-ctx/Makefile
	lttng-ust.pc
])

# Create link for python agent for the VPATH guru.
AC_CONFIG_LINKS([
	python-lttngust/lttngust/agent.py:python-lttngust/lttngust/agent.py
	python-lttngust/lttngust/cmd.py:python-lttngust/lttngust/cmd.py
	python-lttngust/lttngust/debug.py:python-lttngust/lttngust/debug.py
	python-lttngust/lttngust/loghandler.py:python-lttngust/lttngust/loghandler.py
])

AC_OUTPUT

AS_ECHO(["m4_bpatsubst(V_NAME, ["], [\\"])"])
AS_ECHO()
AS_ECHO(["m4_bpatsubst(V_DESC, ["], [\\"])"])

# Report on the configuration options
AS_ECHO()
AS_ECHO(["LTTng-UST will be built with the following options:"])

AS_ECHO()

AS_ECHO_N(["Java agent (JUL support): "])
AS_IF([test "x$java_agent_jul" = "xyes"], [AS_ECHO(["Enabled"])], [AS_ECHO(["Disabled"])])

AS_ECHO_N(["Java agent (Log4j support): "])
AS_IF([test "x$java_agent_log4j" = "xyes"], [AS_ECHO(["Enabled"])], [AS_ECHO(["Disabled"])])

AS_ECHO_N(["JNI interface (JNI): "])
AS_IF([test "x$jni_interface" = "xyes"], [AS_ECHO(["Enabled"])], [AS_ECHO(["Disabled"])])

AS_ECHO_N(["Python ($PYTHON) agent: "])
AS_IF([test "x$python_agent" = "xyes"], [AS_ECHO(["Enabled"])], [AS_ECHO(["Disabled"])])

AS_ECHO_N(["sdt.h integration: "])
AS_IF([test "x$with_sdt" = "xyes"], [AS_ECHO(["Enabled"])], [AS_ECHO(["Disabled"])])

AS_ECHO(["Architecture: $host_cpu"])
AS_ECHO_N(["Efficient unaligned memory access: "])
AS_IF([test "x$NO_UNALIGNED_ACCESS" != "x1"], [AS_ECHO(["yes"])], [AS_IF([test "x$UNSUPPORTED_ARCH" != "x1"], [AS_ECHO(["no"])], [AS_ECHO(["unknown"])])])
AS_IF([test "x$UNSUPPORTED_ARCH" = "x1"], [AC_MSG_WARN([Your architecture ($host_cpu) is unsupported, using safe default of no unaligned access])])
AS_ECHO()

AS_ECHO(["Type 'make' to compile."])
Commit	Line	Data
	1	dnl -- Autoconf --
	2	dnl Process this file with autoconf to produce a configure script.
	3
	4	dnl Version infos
	5	m4_define([V_MAJOR], [2])
	6	m4_define([V_MINOR], [8])
	7	m4_define([V_PATCH], [0])
	8	m4_define([V_EXTRA], [pre])
	9	m4_define([V_STRING], [V_MAJOR.V_MINOR.V_PATCH])
	10	m4_ifdef([V_EXTRA], [m4_append([V_STRING], [-V_EXTRA])])
	11	m4_define([V_NAME], [[Herbe à Détourne]])
	12	m4_define([V_DESC], [[Brewed with unrestrained amounts of Citra hop, the Herbe à Détourne is a fantastic New World Tripel brewed by "Dieu du Ciel!". Aromas of mango, cantaloupe melon and passion fruit, combined with a controlled bitter finish, unite in making this smooth golden-orange beer stand apart.]])
	13
	14	AC_INIT([lttng-ust],V_STRING,[mathieu dot desnoyers at efficios dot com])
	15
	16	# Following the numbering scheme proposed by libtool for the library version
	17	# http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
	18	# This is the library version of liblttng-ust.
	19	AC_SUBST([LTTNG_UST_LIBRARY_VERSION], [0:0:0])
	20	# note: remember to update tracepoint.h dlopen() to match this version
	21	# number. TODO: eventually automate by exporting the major number.
	22
	23	# This is the library version of liblttng-ust-ctl, used internally by
	24	# liblttng-ust, lttng-sessiond, and lttng-consumerd.
	25	AC_SUBST([LTTNG_UST_CTL_LIBRARY_VERSION], [2:0:0])
	26
	27	AC_CONFIG_AUX_DIR([config])
	28	AC_CANONICAL_TARGET
	29	AC_CANONICAL_HOST
	30	AC_CONFIG_MACRO_DIR([config])
	31	AM_INIT_AUTOMAKE([1.9 foreign dist-bzip2 no-dist-gzip tar-ustar])
	32	AM_MAINTAINER_MODE([enable])
	33	m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
	34	AC_CONFIG_SRCDIR([include/lttng/tracepoint.h])
	35
	36	# Configuration options, which will be installed in the config.h
	37	AC_CONFIG_HEADERS([config.h include/lttng/ust-config.h])
	38	AH_TEMPLATE([LTTNG_UST_HAVE_EFFICIENT_UNALIGNED_ACCESS], [Use efficient unaligned access.])
	39	AH_TEMPLATE([LTTNG_UST_HAVE_SDT_INTEGRATION], [SystemTap integration via sdt.h])
	40	AH_TEMPLATE([LTTNG_UST_HAVE_PERF_EVENT], [Perf event integration via perf_event.h])
	41
	42	dnl Substitute minor/major/patchlevel version numbers
	43	AC_SUBST([MAJOR_VERSION], [V_MAJOR])
	44	AC_SUBST([MINOR_VERSION], [V_MINOR])
	45	AC_SUBST([PATCHLEVEL_VERSION], [V_PATCH])
	46
	47	AC_PROG_SED
	48	AC_PROG_GREP
	49	AC_PROG_LN_S
	50
	51	# libtool link_all_deplibs fixup. See http://bugs.lttng.org/issues/321.
	52	AC_ARG_ENABLE([libtool-linkdep-fixup],
	53	AS_HELP_STRING([--disable-libtool-linkdep-fixup],
	54	[disable the libtool fixup for linking all dependent libraries (link_all_deplibs)]),
	55	[libtool_fixup=$enableval],
	56	[libtool_fixup=yes])
	57
	58	AS_IF([test "x$libtool_fixup" = "xyes"],
	59	[
	60	libtool_m4="$srcdir/config/libtool.m4"
	61	libtool_flag_pattern=".link_all_deplibs\s,\s\$1\s)"
	62	AC_MSG_CHECKING([for occurence(s) of link_all_deplibs = no in $libtool_m4])
	63	libtool_flag_pattern_count=$(grep -c "$libtool_flag_pattern\s=\sno" $libtool_m4)
	64	AS_IF([test $libtool_flag_pattern_count -ne 0],
	65	[
	66	AC_MSG_RESULT([$libtool_flag_pattern_count])
	67	AC_MSG_WARN([the detected libtool will not link all dependencies, forcing link_all_deplibs = unknown])
	68	sed -i "s/\($libtool_flag_pattern\)\s=\sno/\1=unknown/g" $libtool_m4
	69	],
	70	[
	71	AC_MSG_RESULT([none])
	72	])
	73	])
	74
	75	AM_CONDITIONAL([NO_SHARED], [test "x$enable_shared" = "xno"])
	76
	77	# Checks for programs.
	78	AC_PROG_CC
	79	AC_PROG_CXX
	80	AC_PROG_MAKE_SET
	81	LT_INIT
	82
	83	# rw_PROG_CXX_WORKS
	84	# Check whether the C++ compiler works.
	85	AC_CACHE_CHECK([whether the C++ compiler works],
	86	[rw_cv_prog_cxx_works],
	87	[AC_LANG_PUSH([C++])
	88	AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
	89	[check_cxx_designated_initializers=yes],
	90	[rw_cv_prog_cxx_works=no])
	91	AS_IF([test "x$check_cxx_designated_initializers" = "xyes"], [
	92	AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
	93	struct foo { int a; int b; };
	94	void fct(void)
	95	{
	96	struct foo f = { .a = 0, .b = 1 };
	97	}
	98	]])],[
	99	rw_cv_prog_cxx_works=yes
	100	],[
	101	rw_cv_prog_cxx_works=no
	102	])
	103	])
	104	AC_LANG_POP([C++])])
	105
	106	AM_CONDITIONAL([CXX_WORKS], [test "x$rw_cv_prog_cxx_works" = "xyes"])
	107
	108	# Check if the compiler support weak symbols
	109	AX_SYS_WEAK_ALIAS
	110
	111	AS_IF([test "x${ax_cv_sys_weak_alias}" = "xno"], [
	112	AC_MSG_ERROR([Your platform doesn't support weak symbols.])
	113	])
	114
	115	# Checks for libraries.
	116	AC_CHECK_LIB([dl], [dlopen],
	117	[
	118	have_libdl=yes
	119	],
	120	[
	121	#libdl not found, check for dlopen in libc.
	122	AC_CHECK_LIB([c], [dlopen],
	123	[
	124	have_libc_dl=yes
	125	],
	126	[
	127	AC_MSG_ERROR([Cannot find dlopen in libdl nor libc. Use [LDFLAGS]=-Ldir to specify their location.])
	128	])
	129	])
	130	AM_CONDITIONAL([LTTNG_UST_BUILD_WITH_LIBDL], [test "x$have_libdl" = "xyes"])
	131	AM_CONDITIONAL([LTTNG_UST_BUILD_WITH_LIBC_DL], [test "x$have_libc_dl" = "xyes"])
	132
	133	AC_CHECK_LIB([pthread], [pthread_create])
	134
	135	# Check for dlfcn.h
	136	AC_CHECK_HEADER([dlfcn.h])
	137	AS_IF([test "x${ac_cv_header_dlfcn_h}" = "xyes"],
	138	[AC_CHECK_DECLS([RTLD_DI_LINKMAP],,,
	139	[#define _GNU_SOURCE /* Required on Linux to get GNU extensions */
	140	#include <dlfcn.h>])
	141	],
	142	[ac_cv_have_decl_RTLD_DI_LINKMAP="no"])
	143	AM_CONDITIONAL([HAVE_DLINFO], [test "x${ac_cv_have_decl_RTLD_DI_LINKMAP}" = "xyes"])
	144
	145	# Checks for header files.
	146	dnl AC_CHECK_HEADERS([fcntl.h stdint.h stdlib.h string.h sys/socket.h sys/time.h unistd.h])
	147
	148	# Checks for typedefs, structures, and compiler characteristics.
	149	AC_C_INLINE
	150	dnl AC_TYPE_INT16_T
	151	dnl AC_TYPE_INT32_T
	152	dnl AC_TYPE_INT64_T
	153	dnl AC_TYPE_INT8_T
	154	dnl AC_TYPE_PID_T
	155	dnl AC_TYPE_SIZE_T
	156	dnl AC_TYPE_SSIZE_T
	157	dnl AC_TYPE_UINT16_T
	158	dnl AC_TYPE_UINT32_T
	159	dnl AC_TYPE_UINT64_T
	160	dnl AC_TYPE_UINT8_T
	161	dnl AC_CHECK_TYPES([ptrdiff_t])
	162
	163	# Checks for library functions.
	164	AC_FUNC_MALLOC
	165	AC_CHECK_FUNCS([gettimeofday munmap socket strerror strtol sched_getcpu sysconf])
	166
	167	CFLAGS="-Wall $CFLAGS"
	168
	169	# URCU
	170
	171	# urcu - check if we just find the headers it out of the box.
	172	AC_CHECK_HEADERS([urcu-bp.h], [], [AC_MSG_ERROR([Cannot find [URCU] headers (urcu-bp.h). Use [CPPFLAGS]=-Idir to specify their location.
	173	This error can also occur when the liburcu package's configure script has not been run.])])
	174
	175	# urcu-cds - check that URCU Concurrent Data Structure lib is available to compilation
	176	# Part of Userspace RCU library 0.7.2 or better.
	177	AC_CHECK_LIB([urcu-cds], [_cds_lfht_new], [], [AC_MSG_ERROR([Cannot find
	178	liburcu-cds lib, part of Userspace RCU 0.7 or better. Use [LDFLAGS]=-Ldir to specify its location.])])
	179
	180	AC_MSG_CHECKING([caa_likely()])
	181	AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
	182	#include <urcu/compiler.h>
	183	void fct(void)
	184	{
	185	if (caa_likely(1)) {
	186	}
	187	}
	188	]])],[
	189	AC_MSG_RESULT([yes])
	190	],[
	191	AC_MSG_RESULT([no])
	192	AC_MSG_ERROR([Please upgrade your version of liburcu to 0.6.6 or better])
	193
	194	])
	195
	196	# urcu - check that URCU lib is available to compilation
	197	AC_CHECK_LIB([urcu-bp], [synchronize_rcu_bp], [], [AC_MSG_ERROR([Cannot find liburcu-bp lib. Use [LDFLAGS]=-Ldir to specify its location.])])
	198
	199	# urcu - check that URCU lib is at least version 0.6
	200	AC_CHECK_LIB([urcu-bp], [call_rcu_bp], [], [AC_MSG_ERROR([liburcu 0.6 or newer is needed, please update your version or use [LDFLAGS]=-Ldir to specify the right location.])])
	201
	202	# optional linux/perf_event.h
	203	AC_CHECK_HEADERS([linux/perf_event.h], [have_perf_event=yes], [])
	204
	205	# Perf event counters are only supported on x86 so far.
	206	AC_MSG_CHECKING([UST support for architecture perf event counters])
	207	AS_CASE([$host_cpu],
	208	[i[[3456]]86], [UST_SUPPORT_FOR_ARCH_PERF_EVENT_COUNTERS=yes],
	209	[x86_64], [UST_SUPPORT_FOR_ARCH_PERF_EVENT_COUNTERS=yes],
	210	[amd64], [UST_SUPPORT_FOR_ARCH_PERF_EVENT_COUNTERS=yes],
	211	[UST_SUPPORT_FOR_ARCH_PERF_EVENT_COUNTERS=no])
	212	AC_MSG_RESULT([$UST_SUPPORT_FOR_ARCH_PERF_EVENT_COUNTERS])
	213
	214	AM_CONDITIONAL([HAVE_PERF_EVENT], [test "x$have_perf_event" = "xyes" && test "x$UST_SUPPORT_FOR_ARCH_PERF_EVENT_COUNTERS" = "xyes"])
	215
	216	AS_IF([test "x$have_perf_event" = "xyes" && test "x$UST_SUPPORT_FOR_ARCH_PERF_EVENT_COUNTERS" = "xyes"], [
	217	AC_DEFINE([LTTNG_UST_HAVE_PERF_EVENT], [1])
	218	])
	219
	220	AC_MSG_CHECKING([host system alignment requirements])
	221	AS_CASE([$host_cpu],
	222	[i[[3456]]86], [],
	223	[x86_64], [],
	224	[amd64], [],
	225	[powerpc], [],
	226	[ppc64], [],
	227	[ppc64le], [],
	228	[powerpc64], [],
	229	[powerpc64le], [],
	230	[s390], [NO_UNALIGNED_ACCESS=1],
	231	[s390x], [NO_UNALIGNED_ACCESS=1],
	232	[arm*], [NO_UNALIGNED_ACCESS=1],
	233	[aarch64], [NO_UNALIGNED_ACCESS=1],
	234	[mips*], [NO_UNALIGNED_ACCESS=1],
	235	[tile*], [NO_UNALIGNED_ACCESS=1],
	236	[
	237	UNSUPPORTED_ARCH=1
	238	NO_UNALIGNED_ACCESS=1
	239	])
	240	AC_MSG_RESULT([$host_cpu])
	241
	242	AS_IF([test "x$NO_UNALIGNED_ACCESS" = "x"], [
	243	AC_DEFINE([LTTNG_UST_HAVE_EFFICIENT_UNALIGNED_ACCESS], [1])
	244	])
	245
	246	# Check for JNI header files if requested
	247	AC_ARG_ENABLE([jni-interface],
	248	[AS_HELP_STRING([--enable-jni-interface],[build JNI interface between C and Java. Needs Java include files [default=no]])],
	249	[jni_interface=$enableval],
	250	[jni_interface=no]
	251	)
	252
	253	AM_CONDITIONAL([BUILD_JNI_INTERFACE], [test "x$jni_interface" = "xyes"])
	254
	255
	256	AC_ARG_ENABLE([java-agent-jul],
	257	[AS_HELP_STRING([--enable-java-agent-jul],[build the LTTng UST Java agent with JUL support [default=no]])],
	258	[java_agent_jul=$enableval],
	259	[java_agent_jul=no]
	260	)
	261
	262	AC_ARG_ENABLE([java-agent-log4j],
	263	[AS_HELP_STRING([--enable-java-agent-log4j],[build the LTTng UST Java agent with Log4j support [default=no]])],
	264	[java_agent_log4j=$enableval],
	265	[java_agent_log4j=no]
	266	)
	267
	268	AC_ARG_ENABLE([java-agent-all],
	269	[AS_HELP_STRING([--enable-java-agent-all],[build the LTTng UST Java agent with all supported backends [default=no]])],
	270	[java_agent_jul=$enableval
	271	java_agent_log4j=$enableval],
	272	[:]
	273	)
	274
	275
	276	AM_CONDITIONAL([BUILD_JAVA_AGENT], [test "x$java_agent_jul" = "xyes" \|\| test "x$java_agent_log4j" = "xyes"])
	277	AM_CONDITIONAL([BUILD_JAVA_AGENT_WITH_JUL], [test "x$java_agent_jul" = "xyes"])
	278	AM_CONDITIONAL([BUILD_JAVA_AGENT_WITH_LOG4J], [test "x$java_agent_log4j" = "xyes"])
	279
	280	AS_IF([test "x$jni_interface" = "xyes" \|\| test "x$java_agent_jul" = "xyes" \|\| test "x$java_agent_log4j" = "xyes"], [
	281	AX_JAVA_OPTIONS
	282	AX_PROG_JAVAC
	283	AX_PROG_JAVA
	284	AX_PROG_JAR
	285
	286	AX_JNI_INCLUDE_DIR
	287	for JNI_INCLUDE_DIR in $JNI_INCLUDE_DIRS
	288	do
	289	CPPFLAGS="$CPPFLAGS -I$JNI_INCLUDE_DIR"
	290	done
	291
	292	AX_PROG_JAVAH
	293	])
	294
	295	AS_IF([test "x$java_agent_log4j" = "xyes"], [
	296	AX_CHECK_CLASSPATH
	297
	298	AX_CHECK_CLASS([org.apache.log4j.Logger])
	299
	300	AS_IF([test "x$ac_cv_class_org_apache_log4j_Logger" = "xno"], [
	301	AC_MSG_ERROR([The UST Java agent support for log4j was requested but the Log4j classes were not found. Please specify the location of the Log4j jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/log4j.jar"])
	302	])
	303	])
	304
	305	# Option to build the python agent
	306	AC_ARG_ENABLE([python-agent],
	307	[AS_HELP_STRING([--enable-python-agent],[build the LTTng UST Python agent [default=no]])],
	308	[python_agent=$enableval],
	309	[:]
	310	)
	311	AM_CONDITIONAL([BUILD_PYTHON_AGENT], [test "x$python_agent" = "xyes"])
	312	AS_IF([test "x$python_agent" = "xyes"], [
	313	AM_PATH_PYTHON([2.7])
	314	])
	315
	316	# sdt.h integration
	317	AC_ARG_WITH([sdt],
	318	[AS_HELP_STRING([--with-sdt],[provide SystemTap integration via sdt.h [default=no]])],
	319	[with_sdt=$withval],
	320	[with_sdt="no"]
	321	)
	322
	323	AS_IF([test "x$with_sdt" = "xyes"],[
	324	AC_MSG_CHECKING([STAP_PROBEV()])
	325	AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
	326	#define SDT_USE_VARIADIC
	327	#include <sys/sdt.h>
	328	void fct(void)
	329	{
	330	STAP_PROBEV(provider,name,1,2,3,4,5,6,7,8,9,10);
	331	}
	332	]])],[
	333	AC_MSG_RESULT([yes])
	334	AC_DEFINE([LTTNG_UST_HAVE_SDT_INTEGRATION], [1])
	335	],[
	336	AC_MSG_RESULT([no])
	337	AC_MSG_ERROR([The sdt.h integration was requested but the STAP_PROBEV define cannot be used. Make sure it is installed, and up to date, or use CPPFLAGS=-I/path/ to specify a non-standard path to sys/sdt.h])
	338	])
	339	])
	340
	341	AC_MSG_CHECKING([whether shared libraries are enabled])
	342	AS_IF([test "x$enable_shared" = "xyes"],
	343	[
	344	AC_MSG_RESULT([yes])
	345	],
	346	[
	347	AC_MSG_RESULT([no])
	348	AC_MSG_ERROR([LTTng-UST requires shared libraries to be enabled])
	349	])
	350
	351	AC_ARG_WITH([lttng-system-rundir],
	352	AS_HELP_STRING([--with-lttng-system-rundir],
	353	[Location of the system directory where LTTng-UST expects the system-wide lttng-sessiond runtime files. The default is "/var/run/lttng".]),
	354	[lttng_system_rundir="$withval"],
	355	[lttng_system_rundir="/var/run/lttng"])
	356	AC_DEFINE_UNQUOTED([LTTNG_SYSTEM_RUNDIR], ["$lttng_system_rundir"],
	357	[LTTng system runtime directory])
	358
	359	AC_CHECK_PROG([BUILD_GEN_TP_EXAMPLES],[python],["yes"])
	360	AM_CONDITIONAL([BUILD_GEN_TP_EXAMPLES], [test "x$BUILD_GEN_TP_EXAMPLES" = "xyes"])
	361
	362	AC_CONFIG_FILES([
	363	Makefile
	364	doc/Makefile
	365	doc/examples/Makefile
	366	include/Makefile
	367	include/lttng/ust-version.h
	368	snprintf/Makefile
	369	libringbuffer/Makefile
	370	liblttng-ust-comm/Makefile
	371	liblttng-ust/Makefile
	372	liblttng-ust-ctl/Makefile
	373	liblttng-ust-fork/Makefile
	374	liblttng-ust-dl/Makefile
	375	liblttng-ust-java/Makefile
	376	liblttng-ust-java-agent/Makefile
	377	liblttng-ust-java-agent/java/Makefile
	378	liblttng-ust-java-agent/java/lttng-ust-agent-common/Makefile
	379	liblttng-ust-java-agent/java/lttng-ust-agent-jul/Makefile
	380	liblttng-ust-java-agent/java/lttng-ust-agent-log4j/Makefile
	381	liblttng-ust-java-agent/jni/Makefile
	382	liblttng-ust-java-agent/jni/common/Makefile
	383	liblttng-ust-java-agent/jni/jul/Makefile
	384	liblttng-ust-java-agent/jni/log4j/Makefile
	385	liblttng-ust-libc-wrapper/Makefile
	386	liblttng-ust-cyg-profile/Makefile
	387	liblttng-ust-python-agent/Makefile
	388	python-lttngust/Makefile
	389	python-lttngust/setup.py
	390	python-lttngust/lttngust/__init__.py
	391	tools/Makefile
	392	tests/Makefile
	393	tests/ctf-types/Makefile
	394	tests/hello/Makefile
	395	tests/hello.cxx/Makefile
	396	tests/same_line_tracepoint/Makefile
	397	tests/snprintf/Makefile
	398	tests/ust-elf/Makefile
	399	tests/benchmark/Makefile
	400	tests/utils/Makefile
	401	tests/test-app-ctx/Makefile
	402	lttng-ust.pc
	403	])
	404
	405	# Create link for python agent for the VPATH guru.
	406	AC_CONFIG_LINKS([
	407	python-lttngust/lttngust/agent.py:python-lttngust/lttngust/agent.py
	408	python-lttngust/lttngust/cmd.py:python-lttngust/lttngust/cmd.py
	409	python-lttngust/lttngust/debug.py:python-lttngust/lttngust/debug.py
	410	python-lttngust/lttngust/loghandler.py:python-lttngust/lttngust/loghandler.py
	411	])
	412
	413	AC_OUTPUT
	414
	415	AS_ECHO(["m4_bpatsubst(V_NAME, ["], [\\"])"])
	416	AS_ECHO()
	417	AS_ECHO(["m4_bpatsubst(V_DESC, ["], [\\"])"])
	418
	419	# Report on the configuration options
	420	AS_ECHO()
	421	AS_ECHO(["LTTng-UST will be built with the following options:"])
	422
	423	AS_ECHO()
	424
	425	AS_ECHO_N(["Java agent (JUL support): "])
	426	AS_IF([test "x$java_agent_jul" = "xyes"], [AS_ECHO(["Enabled"])], [AS_ECHO(["Disabled"])])
	427
	428	AS_ECHO_N(["Java agent (Log4j support): "])
	429	AS_IF([test "x$java_agent_log4j" = "xyes"], [AS_ECHO(["Enabled"])], [AS_ECHO(["Disabled"])])
	430
	431	AS_ECHO_N(["JNI interface (JNI): "])
	432	AS_IF([test "x$jni_interface" = "xyes"], [AS_ECHO(["Enabled"])], [AS_ECHO(["Disabled"])])
	433
	434	AS_ECHO_N(["Python ($PYTHON) agent: "])
	435	AS_IF([test "x$python_agent" = "xyes"], [AS_ECHO(["Enabled"])], [AS_ECHO(["Disabled"])])
	436
	437	AS_ECHO_N(["sdt.h integration: "])
	438	AS_IF([test "x$with_sdt" = "xyes"], [AS_ECHO(["Enabled"])], [AS_ECHO(["Disabled"])])
	439
	440	AS_ECHO(["Architecture: $host_cpu"])
	441	AS_ECHO_N(["Efficient unaligned memory access: "])
	442	AS_IF([test "x$NO_UNALIGNED_ACCESS" != "x1"], [AS_ECHO(["yes"])], [AS_IF([test "x$UNSUPPORTED_ARCH" != "x1"], [AS_ECHO(["no"])], [AS_ECHO(["unknown"])])])
	443	AS_IF([test "x$UNSUPPORTED_ARCH" = "x1"], [AC_MSG_WARN([Your architecture ($host_cpu) is unsupported, using safe default of no unaligned access])])
	444	AS_ECHO()
	445
	446	AS_ECHO(["Type 'make' to compile."])
	447