[lttng-ust.git] / configure.ac

dnl -*- Autoconf -*-
dnl Process this file with autoconf to produce a configure script.

dnl Version infos
m4_define([V_MAJOR], [2])
m4_define([V_MINOR], [9])
m4_define([V_PATCH], [0])
m4_define([V_EXTRA], [pre])
m4_define([V_STRING], [V_MAJOR.V_MINOR.V_PATCH])
m4_ifdef([V_EXTRA], [m4_append([V_STRING], [-V_EXTRA])])
m4_define([V_NAME], [[J-TBD]])
m4_define([V_DESC], [[]])

AC_INIT([lttng-ust], V_STRING, [mathieu dot desnoyers at efficios dot com])

# Following the numbering scheme proposed by libtool for the library version
# http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
# This is the library version of liblttng-ust.
AC_SUBST([LTTNG_UST_LIBRARY_VERSION], [0:0:0])
# note: remember to update tracepoint.h dlopen() to match this version
# number. TODO: eventually automate by exporting the major number.

# This is the library version of liblttng-ust-ctl, used internally by
# liblttng-ust, lttng-sessiond, and lttng-consumerd.
AC_SUBST([LTTNG_UST_CTL_LIBRARY_VERSION], [2:0:0])

AC_CONFIG_AUX_DIR([config])
AC_CANONICAL_TARGET
AC_CANONICAL_HOST
AC_CONFIG_MACRO_DIR([config])
AM_INIT_AUTOMAKE([1.9 foreign dist-bzip2 no-dist-gzip tar-ustar])
AM_MAINTAINER_MODE([enable])
m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
AC_CONFIG_SRCDIR([include/lttng/tracepoint.h])

AC_REQUIRE_AUX_FILE([tap-driver.sh])

# Configuration options, which will be installed in the config.h
AC_CONFIG_HEADERS([config.h include/lttng/ust-config.h])
AH_TEMPLATE([LTTNG_UST_HAVE_EFFICIENT_UNALIGNED_ACCESS], [Use efficient unaligned access.])
AH_TEMPLATE([LTTNG_UST_HAVE_SDT_INTEGRATION], [SystemTap integration via sdt.h])
AH_TEMPLATE([LTTNG_UST_HAVE_PERF_EVENT], [Perf event integration via perf_event.h])

dnl Substitute minor/major/patchlevel version numbers
AC_SUBST([MAJOR_VERSION], [V_MAJOR])
AC_SUBST([MINOR_VERSION], [V_MINOR])
AC_SUBST([PATCHLEVEL_VERSION], [V_PATCH])

AC_PROG_SED
AC_PROG_GREP
AC_PROG_LN_S
AC_PROG_MKDIR_P

# libtool link_all_deplibs fixup. See http://bugs.lttng.org/issues/321.
AC_ARG_ENABLE([libtool-linkdep-fixup], [
	AS_HELP_STRING([--disable-libtool-linkdep-fixup], [disable the libtool fixup for linking all dependent libraries (link_all_deplibs)])
], [
	libtool_fixup=$enableval
], [
	libtool_fixup=yes
])

AS_IF([test "x$libtool_fixup" = "xyes"], [
	libtool_m4="$srcdir/config/libtool.m4"
	libtool_flag_pattern=".*link_all_deplibs\s*,\s*\$1\s*)"
	AC_MSG_CHECKING([for occurence(s) of link_all_deplibs = no in $libtool_m4])
	libtool_flag_pattern_count=$(grep -c "$libtool_flag_pattern\s*=\s*no" $libtool_m4)

	AS_IF([test $libtool_flag_pattern_count -ne 0], [
	AC_MSG_RESULT([$libtool_flag_pattern_count])
	AC_MSG_WARN([the detected libtool will not link all dependencies, forcing link_all_deplibs = unknown])
		sed -i "s/\($libtool_flag_pattern\)\s*=\s*no/\1=unknown/g" $libtool_m4
	], [
		AC_MSG_RESULT([none])
	])
])

AM_CONDITIONAL([NO_SHARED], [test "x$enable_shared" = "xno"])

# Checks for programs.
AC_PROG_CC
AC_PROG_CXX
AM_CONDITIONAL([HAVE_CXX], [test "x$CXX" != "x"])
AC_CHECK_PROG([HAVE_CMAKE], [cmake], ["yes"])
AM_CONDITIONAL([HAVE_CMAKE], [test "x$HAVE_CMAKE" = "xyes"])
AC_PROG_MAKE_SET
LT_INIT

# rw_PROG_CXX_WORKS
# Check whether the C++ compiler works.
AC_CACHE_CHECK([whether the C++ compiler works], [rw_cv_prog_cxx_works], [
	AC_LANG_PUSH([C++])

	AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])], [
		check_cxx_designated_initializers=yes
	], [
		rw_cv_prog_cxx_works=no
	])

	AS_IF([test "x$check_cxx_designated_initializers" = "xyes"], [
		AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
			struct foo { int a; int b; };
			void fct(void)
			{
				struct foo f = { .a = 0, .b = 1 };
			}
		]])], [
			rw_cv_prog_cxx_works=yes
		], [
			rw_cv_prog_cxx_works=no
		])
	])

	AC_LANG_POP([C++])
])

AM_CONDITIONAL([CXX_WORKS], [test "x$rw_cv_prog_cxx_works" = "xyes"])

# Check if the compiler support weak symbols
AX_SYS_WEAK_ALIAS

AS_IF([test "x${ax_cv_sys_weak_alias}" = "xno"], [
	AC_MSG_ERROR([Your platform doesn't support weak symbols.])
])

# Checks for libraries.
AC_CHECK_LIB([dl], [dlopen], [
	have_libdl=yes
], [
	#libdl not found, check for dlopen in libc.
	AC_CHECK_LIB([c], [dlopen], [
		have_libc_dl=yes
	], [
		AC_MSG_ERROR([Cannot find dlopen in libdl nor libc. Use [LDFLAGS]=-Ldir to specify their location.])
	])
])

AM_CONDITIONAL([LTTNG_UST_BUILD_WITH_LIBDL], [test "x$have_libdl" = "xyes"])
AM_CONDITIONAL([LTTNG_UST_BUILD_WITH_LIBC_DL], [test "x$have_libc_dl" = "xyes"])

AC_CHECK_LIB([pthread], [pthread_create])
AC_CHECK_LIB([pthread], [pthread_setname_np],
	AC_DEFINE([HAVE_PTHREAD_SETNAME_NP], [1], [Define to 1 if pthread_setname_np is available.]),
	AC_CHECK_LIB([pthread], [pthread_set_name_np],
		AC_DEFINE([HAVE_PTHREAD_SET_NAME_NP], [1], [Define to 1 if pthread_set_name_np is available.]),
		AC_MSG_RESULT([pthread setname/set_name not found.])))

# Check for dlfcn.h
AC_CHECK_HEADER([dlfcn.h])
AS_IF([test "x${ac_cv_header_dlfcn_h}" = "xyes"], [
	AC_CHECK_DECLS([RTLD_DI_LINKMAP], [], [], [
		#define _GNU_SOURCE /* Required on Linux to get GNU extensions */
		#include <dlfcn.h>
	])
], [
	ac_cv_have_decl_RTLD_DI_LINKMAP="no"
])

AM_CONDITIONAL([HAVE_DLINFO], [test "x${ac_cv_have_decl_RTLD_DI_LINKMAP}" = "xyes"])

# Checks for header files.
dnl AC_CHECK_HEADERS([fcntl.h stdint.h stdlib.h string.h sys/socket.h sys/time.h unistd.h])

# Checks for typedefs, structures, and compiler characteristics.
AC_C_INLINE
dnl AC_TYPE_INT16_T
dnl AC_TYPE_INT32_T
dnl AC_TYPE_INT64_T
dnl AC_TYPE_INT8_T
dnl AC_TYPE_PID_T
dnl AC_TYPE_SIZE_T
dnl AC_TYPE_SSIZE_T
dnl AC_TYPE_UINT16_T
dnl AC_TYPE_UINT32_T
dnl AC_TYPE_UINT64_T
dnl AC_TYPE_UINT8_T
dnl AC_CHECK_TYPES([ptrdiff_t])

# Checks for library functions.
AC_FUNC_MALLOC
AC_CHECK_FUNCS([gettimeofday munmap socket strerror strtol sched_getcpu sysconf])

CFLAGS="-Wall $CFLAGS"

# URCU

# urcu - check if we just find the headers it out of the box.
AC_CHECK_HEADERS([urcu-bp.h], [], [AC_MSG_ERROR([Cannot find [URCU] headers (urcu-bp.h). Use [CPPFLAGS]=-Idir to specify their location.
This error can also occur when the liburcu package's configure script has not been run.])])

# urcu-cds - check that URCU Concurrent Data Structure lib is available to compilation
# Part of Userspace RCU library 0.7.2 or better.
AC_CHECK_LIB([urcu-cds], [_cds_lfht_new], [], [AC_MSG_ERROR([Cannot find
liburcu-cds lib, part of Userspace RCU 0.7 or better. Use [LDFLAGS]=-Ldir to specify its location.])])

AC_MSG_CHECKING([caa_likely()])
AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
	#include <urcu/compiler.h>
	void fct(void)
	{
		if (caa_likely(1)) {
		}
	}
]])], [
	AC_MSG_RESULT([yes])
], [
	AC_MSG_RESULT([no])
	AC_MSG_ERROR([Please upgrade your version of liburcu to 0.6.6 or better])
])

# urcu - check that URCU lib is available to compilation
AC_CHECK_LIB([urcu-bp], [synchronize_rcu_bp], [], [AC_MSG_ERROR([Cannot find liburcu-bp lib. Use [LDFLAGS]=-Ldir to specify its location.])])

# urcu - check that URCU lib is at least version 0.6
AC_CHECK_LIB([urcu-bp], [call_rcu_bp], [], [AC_MSG_ERROR([liburcu 0.6 or newer is needed, please update your version or use [LDFLAGS]=-Ldir to specify the right location.])])

# optional linux/perf_event.h
AC_CHECK_HEADERS([linux/perf_event.h], [have_perf_event=yes], [])

# Perf event counters are supported on all architectures supported by
# perf, using the read system call as fallback.
AM_CONDITIONAL([HAVE_PERF_EVENT], [test "x$have_perf_event" = "xyes"])

AS_IF([test "x$have_perf_event" = "xyes"], [
	AC_DEFINE([LTTNG_UST_HAVE_PERF_EVENT], [1])
])

AC_MSG_CHECKING([host system alignment requirements])
AS_CASE([$host_cpu],
	[i[[3456]]86], [],
	[x86_64], [],
	[amd64], [],
	[powerpc], [],
	[ppc64], [],
	[ppc64le], [],
	[powerpc64], [],
	[powerpc64le], [],
	[s390], [NO_UNALIGNED_ACCESS=1],
	[s390x], [NO_UNALIGNED_ACCESS=1],
	[arm*], [NO_UNALIGNED_ACCESS=1],
	[aarch64*], [NO_UNALIGNED_ACCESS=1],
	[mips*], [NO_UNALIGNED_ACCESS=1],
	[tile*], [NO_UNALIGNED_ACCESS=1],
	[
		UNSUPPORTED_ARCH=1
		NO_UNALIGNED_ACCESS=1
	])
AC_MSG_RESULT([$host_cpu])

AS_IF([test "x$NO_UNALIGNED_ACCESS" = "x"], [
	AC_DEFINE([LTTNG_UST_HAVE_EFFICIENT_UNALIGNED_ACCESS], [1])
])

# Check for JNI header files if requested
AC_ARG_ENABLE([jni-interface], [
	AS_HELP_STRING([--enable-jni-interface], [build JNI interface between C and Java. Needs Java include files [default=no]])
], [
	jni_interface=$enableval
], [
	jni_interface=no
])

AM_CONDITIONAL([BUILD_JNI_INTERFACE], [test "x$jni_interface" = "xyes"])


AC_ARG_ENABLE([java-agent-jul], [
	AS_HELP_STRING([--enable-java-agent-jul], [build the LTTng UST Java agent with JUL support [default=no]])
], [
	java_agent_jul=$enableval
], [
	java_agent_jul=no
])

AC_ARG_ENABLE([java-agent-log4j], [
	AS_HELP_STRING([--enable-java-agent-log4j], [build the LTTng UST Java agent with Log4j support [default=no]])
], [
	java_agent_log4j=$enableval
], [
	java_agent_log4j=no
])

AC_ARG_ENABLE([java-agent-all], [
	AS_HELP_STRING([--enable-java-agent-all], [build the LTTng UST Java agent with all supported backends [default=no]])
], [
	java_agent_jul=$enableval
	java_agent_log4j=$enableval
], [:])

AM_CONDITIONAL([BUILD_JAVA_AGENT], [test "x$java_agent_jul" = "xyes" || test "x$java_agent_log4j" = "xyes"])
AM_CONDITIONAL([BUILD_JAVA_AGENT_WITH_JUL], [test "x$java_agent_jul" = "xyes"])
AM_CONDITIONAL([BUILD_JAVA_AGENT_WITH_LOG4J], [test "x$java_agent_log4j" = "xyes"])

AS_IF([test "x$jni_interface" = "xyes" || test "x$java_agent_jul" = "xyes" || test "x$java_agent_log4j" = "xyes"], [
	AX_JAVA_OPTIONS
	AX_PROG_JAVAC
	AX_PROG_JAVA
	AX_PROG_JAR

	AX_JNI_INCLUDE_DIR
	for JNI_INCLUDE_DIR in $JNI_INCLUDE_DIRS
	do
		CPPFLAGS="$CPPFLAGS -I$JNI_INCLUDE_DIR"
	done

	AX_PROG_JAVAH
])

AS_IF([test "x$java_agent_log4j" = "xyes"], [
	AX_CHECK_CLASSPATH
	AX_CHECK_CLASS([org.apache.log4j.Logger])
	AS_IF([test "x$ac_cv_class_org_apache_log4j_Logger" = "xno"], [
		AC_MSG_ERROR([The UST Java agent support for log4j was requested but the Log4j classes were not found. Please specify the location of the Log4j jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/log4j.jar"])
	])
])

# Option to build the python agent
AC_ARG_ENABLE([python-agent], [
	AS_HELP_STRING([--enable-python-agent], [build the LTTng UST Python agent [default=no]])
], [
	python_agent=$enableval
], [:])
AM_CONDITIONAL([BUILD_PYTHON_AGENT], [test "x$python_agent" = "xyes"])
AS_IF([test "x$python_agent" = "xyes"], [
	AM_PATH_PYTHON([2.7])
])

# sdt.h integration
AC_ARG_WITH([sdt], [
	AS_HELP_STRING([--with-sdt], [provide SystemTap integration via sdt.h [default=no]])
], [
	with_sdt=$withval
], [
	with_sdt="no"
])

AS_IF([test "x$with_sdt" = "xyes"], [
	AC_MSG_CHECKING([STAP_PROBEV()])
	AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
		#define SDT_USE_VARIADIC
		#include <sys/sdt.h>
		void fct(void)
		{
			STAP_PROBEV(provider,name,1,2,3,4,5,6,7,8,9,10);
		}
	]])], [
		AC_MSG_RESULT([yes])
		AC_DEFINE([LTTNG_UST_HAVE_SDT_INTEGRATION], [1])
	], [
		AC_MSG_RESULT([no])
		AC_MSG_ERROR([The sdt.h integration was requested but the STAP_PROBEV define cannot be used. Make sure it is installed, and up to date, or use CPPFLAGS=-I/path/ to specify a non-standard path to sys/sdt.h])
	])
])

AC_MSG_CHECKING([whether shared libraries are enabled])
AS_IF([test "x$enable_shared" = "xyes"], [
	AC_MSG_RESULT([yes])
], [
	AC_MSG_RESULT([no])
	AC_MSG_ERROR([LTTng-UST requires shared libraries to be enabled])
])

AC_ARG_WITH([lttng-system-rundir], [
	AS_HELP_STRING([--with-lttng-system-rundir], [Location of the system directory where LTTng-UST expects the system-wide lttng-sessiond runtime files. The default is "/var/run/lttng".]),
], [
	lttng_system_rundir="$withval"
], [
	lttng_system_rundir="/var/run/lttng"
])
AC_DEFINE_UNQUOTED([LTTNG_SYSTEM_RUNDIR], ["$lttng_system_rundir"],
		[LTTng system runtime directory])

AC_CHECK_PROG([BUILD_GEN_TP_EXAMPLES], [python], ["yes"])
AM_CONDITIONAL([BUILD_GEN_TP_EXAMPLES], [test "x$BUILD_GEN_TP_EXAMPLES" = "xyes"])

# Set $IN_GIT_REPO if we're in the Git repository; the `bootstrap` file
# is not distributed in tarballs.
AS_IF([test -f "$srcdir/bootstrap"], [in_git_repo=yes], [in_git_repo=no])
AM_CONDITIONAL([IN_GIT_REPO], [test "x$in_git_repo" = "xyes"])

# Enable building man pages (user's intention).
AC_ARG_ENABLE(
	man-pages,
	AS_HELP_STRING(
		[--disable-man-pages],
		[Do not build and install man pages (already built in a distributed tarball)]
	),
	[man_pages_opt=$enableval],
	[man_pages_opt=yes]
)

# Check for asciidoc and xmlto if we enabled building the man pages.
have_asciidoc_xmlto=no

AS_IF([test "x$man_pages_opt" = "xyes"], [
	AC_PATH_PROG([ASCIIDOC], [asciidoc], [no])
	AC_PATH_PROG([XMLTO], [xmlto], [no])

	AS_IF([test "x$ASCIIDOC" = "xno" || test "x$XMLTO" = "xno"], [
		AS_IF([test "x$in_git_repo" = "xyes"], [
			# This is an error because we're in the Git repo, which
			# means the man pages are not already generated for us,
			# thus asciidoc/xmlto are required because we were asked
			# to build the man pages.
			AC_MSG_ERROR([
Both asciidoc and xmlto are needed to build the LTTng-UST man pages. Use
--disable-man-pages to disable building the man pages, in which case
they will not be installed.
			])
		], [
			# Only warn here: since we're in the tarball, the man
			# pages should already be generated at this point, thus
			# asciidoc/xmlto are not strictly required.
			AC_MSG_WARN([
Both asciidoc and xmlto are needed to build the LTTng-UST man pages.
Note that the man pages are already built in this distribution tarball,
so asciidoc and xmlto are only needed if you intend to modify their
sources. Use --disable-man-pages to completely disable building
and installing the man pages.
			])
		])
	], [
		have_asciidoc_xmlto=yes
	])
])

# Export man page build condition: build the man pages if the user
# asked for it, and if the tools are available.
AM_CONDITIONAL([MAN_PAGES_OPT], [test "x$man_pages_opt" != "xno"])
AM_CONDITIONAL([HAVE_ASCIIDOC_XMLTO], [test "x$have_asciidoc_xmlto" = "xyes"])

# Default values
AC_DEFUN([_AC_DEFINE_AND_SUBST], [
	AC_DEFINE_UNQUOTED([CONFIG_$1], [$2], [$1])
	$1="$2"
	AC_SUBST([$1])
])

_AC_DEFINE_AND_SUBST([LTTNG_UST_DEFAULT_CONSTRUCTOR_TIMEOUT_MS], [3000])

AC_CONFIG_FILES([
	Makefile
	doc/Makefile
	doc/examples/Makefile
	doc/man/Makefile
	include/Makefile
	include/lttng/ust-version.h
	snprintf/Makefile
	libringbuffer/Makefile
	liblttng-ust-comm/Makefile
	liblttng-ust/Makefile
	liblttng-ust-ctl/Makefile
	liblttng-ust-fork/Makefile
	liblttng-ust-dl/Makefile
	liblttng-ust-java/Makefile
	liblttng-ust-java-agent/Makefile
	liblttng-ust-java-agent/java/Makefile
	liblttng-ust-java-agent/java/lttng-ust-agent-all/Makefile
	liblttng-ust-java-agent/java/lttng-ust-agent-common/Makefile
	liblttng-ust-java-agent/java/lttng-ust-agent-jul/Makefile
	liblttng-ust-java-agent/java/lttng-ust-agent-log4j/Makefile
	liblttng-ust-java-agent/jni/Makefile
	liblttng-ust-java-agent/jni/common/Makefile
	liblttng-ust-java-agent/jni/jul/Makefile
	liblttng-ust-java-agent/jni/log4j/Makefile
	liblttng-ust-libc-wrapper/Makefile
	liblttng-ust-cyg-profile/Makefile
	liblttng-ust-python-agent/Makefile
	python-lttngust/Makefile
	python-lttngust/setup.py
	python-lttngust/lttngust/__init__.py
	tools/Makefile
	tests/Makefile
	tests/ctf-types/Makefile
	tests/hello/Makefile
	tests/hello.cxx/Makefile
	tests/same_line_tracepoint/Makefile
	tests/snprintf/Makefile
	tests/ust-elf/Makefile
	tests/benchmark/Makefile
	tests/utils/Makefile
	tests/test-app-ctx/Makefile
	tests/gcc-weak-hidden/Makefile
	lttng-ust.pc
])

# Create link for python agent for the VPATH guru.
AC_CONFIG_LINKS([
	python-lttngust/lttngust/agent.py:python-lttngust/lttngust/agent.py
	python-lttngust/lttngust/cmd.py:python-lttngust/lttngust/cmd.py
	python-lttngust/lttngust/debug.py:python-lttngust/lttngust/debug.py
	python-lttngust/lttngust/loghandler.py:python-lttngust/lttngust/loghandler.py
])

AC_OUTPUT

AS_ECHO
AS_ECHO(["m4_bpatsubst(V_NAME, ["], [\\"])"])
AS_ECHO
AS_ECHO(["m4_bpatsubst(V_DESC, ["], [\\"])"])

# Report on the configuration options
AS_ECHO
AS_ECHO(["LTTng-UST will be built with the following options:"])

AS_ECHO

AS_ECHO_N(["Java agent (JUL support): "])
AS_IF([test "x$java_agent_jul" = "xyes"], [AS_ECHO(["Enabled"])], [AS_ECHO(["Disabled (Use --enable-java-agent-jul)"])])

AS_ECHO_N(["Java agent (Log4j support): "])
AS_IF([test "x$java_agent_log4j" = "xyes"], [AS_ECHO(["Enabled"])], [AS_ECHO(["Disabled (Use --enable-java-agent-log4j)"])])

AS_ECHO_N(["JNI interface (JNI): "])
AS_IF([test "x$jni_interface" = "xyes"], [AS_ECHO(["Enabled"])], [AS_ECHO(["Disabled (Use --enable-jni-interface)"])])

AS_ECHO_N(["Python ($PYTHON) agent: "])
AS_IF([test "x$python_agent" = "xyes"], [AS_ECHO(["Enabled"])], [AS_ECHO(["Disabled (Use --enable-python-agent)"])])

AS_ECHO_N(["sdt.h integration: "])
AS_IF([test "x$with_sdt" = "xyes"], [AS_ECHO(["Enabled"])], [AS_ECHO(["Disabled"])])

AS_ECHO(["Architecture: $host_cpu"])
AS_ECHO_N(["Efficient unaligned memory access: "])
AS_IF([test "x$NO_UNALIGNED_ACCESS" != "x1"], [AS_ECHO(["yes"])], [AS_IF([test "x$UNSUPPORTED_ARCH" != "x1"], [AS_ECHO(["no"])], [AS_ECHO(["unknown"])])])
AS_IF([test "x$UNSUPPORTED_ARCH" = "x1"], [AC_MSG_WARN([Your architecture ($host_cpu) is unsupported, using safe default of no unaligned access])])
AS_ECHO

AS_ECHO(["Type 'make' to compile."])
Commit	Line	Data
	1	dnl -- Autoconf --
	2	dnl Process this file with autoconf to produce a configure script.
	3
	4	dnl Version infos
	5	m4_define([V_MAJOR], [2])
	6	m4_define([V_MINOR], [9])
	7	m4_define([V_PATCH], [0])
	8	m4_define([V_EXTRA], [pre])
	9	m4_define([V_STRING], [V_MAJOR.V_MINOR.V_PATCH])
	10	m4_ifdef([V_EXTRA], [m4_append([V_STRING], [-V_EXTRA])])
	11	m4_define([V_NAME], [[J-TBD]])
	12	m4_define([V_DESC], [[]])
	13
	14	AC_INIT([lttng-ust], V_STRING, [mathieu dot desnoyers at efficios dot com])
	15
	16	# Following the numbering scheme proposed by libtool for the library version
	17	# http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
	18	# This is the library version of liblttng-ust.
	19	AC_SUBST([LTTNG_UST_LIBRARY_VERSION], [0:0:0])
	20	# note: remember to update tracepoint.h dlopen() to match this version
	21	# number. TODO: eventually automate by exporting the major number.
	22
	23	# This is the library version of liblttng-ust-ctl, used internally by
	24	# liblttng-ust, lttng-sessiond, and lttng-consumerd.
	25	AC_SUBST([LTTNG_UST_CTL_LIBRARY_VERSION], [2:0:0])
	26
	27	AC_CONFIG_AUX_DIR([config])
	28	AC_CANONICAL_TARGET
	29	AC_CANONICAL_HOST
	30	AC_CONFIG_MACRO_DIR([config])
	31	AM_INIT_AUTOMAKE([1.9 foreign dist-bzip2 no-dist-gzip tar-ustar])
	32	AM_MAINTAINER_MODE([enable])
	33	m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
	34	AC_CONFIG_SRCDIR([include/lttng/tracepoint.h])
	35
	36	AC_REQUIRE_AUX_FILE([tap-driver.sh])
	37
	38	# Configuration options, which will be installed in the config.h
	39	AC_CONFIG_HEADERS([config.h include/lttng/ust-config.h])
	40	AH_TEMPLATE([LTTNG_UST_HAVE_EFFICIENT_UNALIGNED_ACCESS], [Use efficient unaligned access.])
	41	AH_TEMPLATE([LTTNG_UST_HAVE_SDT_INTEGRATION], [SystemTap integration via sdt.h])
	42	AH_TEMPLATE([LTTNG_UST_HAVE_PERF_EVENT], [Perf event integration via perf_event.h])
	43
	44	dnl Substitute minor/major/patchlevel version numbers
	45	AC_SUBST([MAJOR_VERSION], [V_MAJOR])
	46	AC_SUBST([MINOR_VERSION], [V_MINOR])
	47	AC_SUBST([PATCHLEVEL_VERSION], [V_PATCH])
	48
	49	AC_PROG_SED
	50	AC_PROG_GREP
	51	AC_PROG_LN_S
	52	AC_PROG_MKDIR_P
	53
	54	# libtool link_all_deplibs fixup. See http://bugs.lttng.org/issues/321.
	55	AC_ARG_ENABLE([libtool-linkdep-fixup], [
	56	AS_HELP_STRING([--disable-libtool-linkdep-fixup], [disable the libtool fixup for linking all dependent libraries (link_all_deplibs)])
	57	], [
	58	libtool_fixup=$enableval
	59	], [
	60	libtool_fixup=yes
	61	])
	62
	63	AS_IF([test "x$libtool_fixup" = "xyes"], [
	64	libtool_m4="$srcdir/config/libtool.m4"
	65	libtool_flag_pattern=".link_all_deplibs\s,\s\$1\s)"
	66	AC_MSG_CHECKING([for occurence(s) of link_all_deplibs = no in $libtool_m4])
	67	libtool_flag_pattern_count=$(grep -c "$libtool_flag_pattern\s=\sno" $libtool_m4)
	68
	69	AS_IF([test $libtool_flag_pattern_count -ne 0], [
	70	AC_MSG_RESULT([$libtool_flag_pattern_count])
	71	AC_MSG_WARN([the detected libtool will not link all dependencies, forcing link_all_deplibs = unknown])
	72	sed -i "s/\($libtool_flag_pattern\)\s=\sno/\1=unknown/g" $libtool_m4
	73	], [
	74	AC_MSG_RESULT([none])
	75	])
	76	])
	77
	78	AM_CONDITIONAL([NO_SHARED], [test "x$enable_shared" = "xno"])
	79
	80	# Checks for programs.
	81	AC_PROG_CC
	82	AC_PROG_CXX
	83	AM_CONDITIONAL([HAVE_CXX], [test "x$CXX" != "x"])
	84	AC_CHECK_PROG([HAVE_CMAKE], [cmake], ["yes"])
	85	AM_CONDITIONAL([HAVE_CMAKE], [test "x$HAVE_CMAKE" = "xyes"])
	86	AC_PROG_MAKE_SET
	87	LT_INIT
	88
	89	# rw_PROG_CXX_WORKS
	90	# Check whether the C++ compiler works.
	91	AC_CACHE_CHECK([whether the C++ compiler works], [rw_cv_prog_cxx_works], [
	92	AC_LANG_PUSH([C++])
	93
	94	AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])], [
	95	check_cxx_designated_initializers=yes
	96	], [
	97	rw_cv_prog_cxx_works=no
	98	])
	99
	100	AS_IF([test "x$check_cxx_designated_initializers" = "xyes"], [
	101	AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
	102	struct foo { int a; int b; };
	103	void fct(void)
	104	{
	105	struct foo f = { .a = 0, .b = 1 };
	106	}
	107	]])], [
	108	rw_cv_prog_cxx_works=yes
	109	], [
	110	rw_cv_prog_cxx_works=no
	111	])
	112	])
	113
	114	AC_LANG_POP([C++])
	115	])
	116
	117	AM_CONDITIONAL([CXX_WORKS], [test "x$rw_cv_prog_cxx_works" = "xyes"])
	118
	119	# Check if the compiler support weak symbols
	120	AX_SYS_WEAK_ALIAS
	121
	122	AS_IF([test "x${ax_cv_sys_weak_alias}" = "xno"], [
	123	AC_MSG_ERROR([Your platform doesn't support weak symbols.])
	124	])
	125
	126	# Checks for libraries.
	127	AC_CHECK_LIB([dl], [dlopen], [
	128	have_libdl=yes
	129	], [
	130	#libdl not found, check for dlopen in libc.
	131	AC_CHECK_LIB([c], [dlopen], [
	132	have_libc_dl=yes
	133	], [
	134	AC_MSG_ERROR([Cannot find dlopen in libdl nor libc. Use [LDFLAGS]=-Ldir to specify their location.])
	135	])
	136	])
	137
	138	AM_CONDITIONAL([LTTNG_UST_BUILD_WITH_LIBDL], [test "x$have_libdl" = "xyes"])
	139	AM_CONDITIONAL([LTTNG_UST_BUILD_WITH_LIBC_DL], [test "x$have_libc_dl" = "xyes"])
	140
	141	AC_CHECK_LIB([pthread], [pthread_create])
	142	AC_CHECK_LIB([pthread], [pthread_setname_np],
	143	AC_DEFINE([HAVE_PTHREAD_SETNAME_NP], [1], [Define to 1 if pthread_setname_np is available.]),
	144	AC_CHECK_LIB([pthread], [pthread_set_name_np],
	145	AC_DEFINE([HAVE_PTHREAD_SET_NAME_NP], [1], [Define to 1 if pthread_set_name_np is available.]),
	146	AC_MSG_RESULT([pthread setname/set_name not found.])))
	147
	148	# Check for dlfcn.h
	149	AC_CHECK_HEADER([dlfcn.h])
	150	AS_IF([test "x${ac_cv_header_dlfcn_h}" = "xyes"], [
	151	AC_CHECK_DECLS([RTLD_DI_LINKMAP], [], [], [
	152	#define _GNU_SOURCE /* Required on Linux to get GNU extensions */
	153	#include <dlfcn.h>
	154	])
	155	], [
	156	ac_cv_have_decl_RTLD_DI_LINKMAP="no"
	157	])
	158
	159	AM_CONDITIONAL([HAVE_DLINFO], [test "x${ac_cv_have_decl_RTLD_DI_LINKMAP}" = "xyes"])
	160
	161	# Checks for header files.
	162	dnl AC_CHECK_HEADERS([fcntl.h stdint.h stdlib.h string.h sys/socket.h sys/time.h unistd.h])
	163
	164	# Checks for typedefs, structures, and compiler characteristics.
	165	AC_C_INLINE
	166	dnl AC_TYPE_INT16_T
	167	dnl AC_TYPE_INT32_T
	168	dnl AC_TYPE_INT64_T
	169	dnl AC_TYPE_INT8_T
	170	dnl AC_TYPE_PID_T
	171	dnl AC_TYPE_SIZE_T
	172	dnl AC_TYPE_SSIZE_T
	173	dnl AC_TYPE_UINT16_T
	174	dnl AC_TYPE_UINT32_T
	175	dnl AC_TYPE_UINT64_T
	176	dnl AC_TYPE_UINT8_T
	177	dnl AC_CHECK_TYPES([ptrdiff_t])
	178
	179	# Checks for library functions.
	180	AC_FUNC_MALLOC
	181	AC_CHECK_FUNCS([gettimeofday munmap socket strerror strtol sched_getcpu sysconf])
	182
	183	CFLAGS="-Wall $CFLAGS"
	184
	185	# URCU
	186
	187	# urcu - check if we just find the headers it out of the box.
	188	AC_CHECK_HEADERS([urcu-bp.h], [], [AC_MSG_ERROR([Cannot find [URCU] headers (urcu-bp.h). Use [CPPFLAGS]=-Idir to specify their location.
	189	This error can also occur when the liburcu package's configure script has not been run.])])
	190
	191	# urcu-cds - check that URCU Concurrent Data Structure lib is available to compilation
	192	# Part of Userspace RCU library 0.7.2 or better.
	193	AC_CHECK_LIB([urcu-cds], [_cds_lfht_new], [], [AC_MSG_ERROR([Cannot find
	194	liburcu-cds lib, part of Userspace RCU 0.7 or better. Use [LDFLAGS]=-Ldir to specify its location.])])
	195
	196	AC_MSG_CHECKING([caa_likely()])
	197	AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
	198	#include <urcu/compiler.h>
	199	void fct(void)
	200	{
	201	if (caa_likely(1)) {
	202	}
	203	}
	204	]])], [
	205	AC_MSG_RESULT([yes])
	206	], [
	207	AC_MSG_RESULT([no])
	208	AC_MSG_ERROR([Please upgrade your version of liburcu to 0.6.6 or better])
	209	])
	210
	211	# urcu - check that URCU lib is available to compilation
	212	AC_CHECK_LIB([urcu-bp], [synchronize_rcu_bp], [], [AC_MSG_ERROR([Cannot find liburcu-bp lib. Use [LDFLAGS]=-Ldir to specify its location.])])
	213
	214	# urcu - check that URCU lib is at least version 0.6
	215	AC_CHECK_LIB([urcu-bp], [call_rcu_bp], [], [AC_MSG_ERROR([liburcu 0.6 or newer is needed, please update your version or use [LDFLAGS]=-Ldir to specify the right location.])])
	216
	217	# optional linux/perf_event.h
	218	AC_CHECK_HEADERS([linux/perf_event.h], [have_perf_event=yes], [])
	219
	220	# Perf event counters are supported on all architectures supported by
	221	# perf, using the read system call as fallback.
	222	AM_CONDITIONAL([HAVE_PERF_EVENT], [test "x$have_perf_event" = "xyes"])
	223
	224	AS_IF([test "x$have_perf_event" = "xyes"], [
	225	AC_DEFINE([LTTNG_UST_HAVE_PERF_EVENT], [1])
	226	])
	227
	228	AC_MSG_CHECKING([host system alignment requirements])
	229	AS_CASE([$host_cpu],
	230	[i[[3456]]86], [],
	231	[x86_64], [],
	232	[amd64], [],
	233	[powerpc], [],
	234	[ppc64], [],
	235	[ppc64le], [],
	236	[powerpc64], [],
	237	[powerpc64le], [],
	238	[s390], [NO_UNALIGNED_ACCESS=1],
	239	[s390x], [NO_UNALIGNED_ACCESS=1],
	240	[arm*], [NO_UNALIGNED_ACCESS=1],
	241	[aarch64*], [NO_UNALIGNED_ACCESS=1],
	242	[mips*], [NO_UNALIGNED_ACCESS=1],
	243	[tile*], [NO_UNALIGNED_ACCESS=1],
	244	[
	245	UNSUPPORTED_ARCH=1
	246	NO_UNALIGNED_ACCESS=1
	247	])
	248	AC_MSG_RESULT([$host_cpu])
	249
	250	AS_IF([test "x$NO_UNALIGNED_ACCESS" = "x"], [
	251	AC_DEFINE([LTTNG_UST_HAVE_EFFICIENT_UNALIGNED_ACCESS], [1])
	252	])
	253
	254	# Check for JNI header files if requested
	255	AC_ARG_ENABLE([jni-interface], [
	256	AS_HELP_STRING([--enable-jni-interface], [build JNI interface between C and Java. Needs Java include files [default=no]])
	257	], [
	258	jni_interface=$enableval
	259	], [
	260	jni_interface=no
	261	])
	262
	263	AM_CONDITIONAL([BUILD_JNI_INTERFACE], [test "x$jni_interface" = "xyes"])
	264
	265
	266	AC_ARG_ENABLE([java-agent-jul], [
	267	AS_HELP_STRING([--enable-java-agent-jul], [build the LTTng UST Java agent with JUL support [default=no]])
	268	], [
	269	java_agent_jul=$enableval
	270	], [
	271	java_agent_jul=no
	272	])
	273
	274	AC_ARG_ENABLE([java-agent-log4j], [
	275	AS_HELP_STRING([--enable-java-agent-log4j], [build the LTTng UST Java agent with Log4j support [default=no]])
	276	], [
	277	java_agent_log4j=$enableval
	278	], [
	279	java_agent_log4j=no
	280	])
	281
	282	AC_ARG_ENABLE([java-agent-all], [
	283	AS_HELP_STRING([--enable-java-agent-all], [build the LTTng UST Java agent with all supported backends [default=no]])
	284	], [
	285	java_agent_jul=$enableval
	286	java_agent_log4j=$enableval
	287	], [:])
	288
	289	AM_CONDITIONAL([BUILD_JAVA_AGENT], [test "x$java_agent_jul" = "xyes" \|\| test "x$java_agent_log4j" = "xyes"])
	290	AM_CONDITIONAL([BUILD_JAVA_AGENT_WITH_JUL], [test "x$java_agent_jul" = "xyes"])
	291	AM_CONDITIONAL([BUILD_JAVA_AGENT_WITH_LOG4J], [test "x$java_agent_log4j" = "xyes"])
	292
	293	AS_IF([test "x$jni_interface" = "xyes" \|\| test "x$java_agent_jul" = "xyes" \|\| test "x$java_agent_log4j" = "xyes"], [
	294	AX_JAVA_OPTIONS
	295	AX_PROG_JAVAC
	296	AX_PROG_JAVA
	297	AX_PROG_JAR
	298
	299	AX_JNI_INCLUDE_DIR
	300	for JNI_INCLUDE_DIR in $JNI_INCLUDE_DIRS
	301	do
	302	CPPFLAGS="$CPPFLAGS -I$JNI_INCLUDE_DIR"
	303	done
	304
	305	AX_PROG_JAVAH
	306	])
	307
	308	AS_IF([test "x$java_agent_log4j" = "xyes"], [
	309	AX_CHECK_CLASSPATH
	310	AX_CHECK_CLASS([org.apache.log4j.Logger])
	311	AS_IF([test "x$ac_cv_class_org_apache_log4j_Logger" = "xno"], [
	312	AC_MSG_ERROR([The UST Java agent support for log4j was requested but the Log4j classes were not found. Please specify the location of the Log4j jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/log4j.jar"])
	313	])
	314	])
	315
	316	# Option to build the python agent
	317	AC_ARG_ENABLE([python-agent], [
	318	AS_HELP_STRING([--enable-python-agent], [build the LTTng UST Python agent [default=no]])
	319	], [
	320	python_agent=$enableval
	321	], [:])
	322	AM_CONDITIONAL([BUILD_PYTHON_AGENT], [test "x$python_agent" = "xyes"])
	323	AS_IF([test "x$python_agent" = "xyes"], [
	324	AM_PATH_PYTHON([2.7])
	325	])
	326
	327	# sdt.h integration
	328	AC_ARG_WITH([sdt], [
	329	AS_HELP_STRING([--with-sdt], [provide SystemTap integration via sdt.h [default=no]])
	330	], [
	331	with_sdt=$withval
	332	], [
	333	with_sdt="no"
	334	])
	335
	336	AS_IF([test "x$with_sdt" = "xyes"], [
	337	AC_MSG_CHECKING([STAP_PROBEV()])
	338	AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
	339	#define SDT_USE_VARIADIC
	340	#include <sys/sdt.h>
	341	void fct(void)
	342	{
	343	STAP_PROBEV(provider,name,1,2,3,4,5,6,7,8,9,10);
	344	}
	345	]])], [
	346	AC_MSG_RESULT([yes])
	347	AC_DEFINE([LTTNG_UST_HAVE_SDT_INTEGRATION], [1])
	348	], [
	349	AC_MSG_RESULT([no])
	350	AC_MSG_ERROR([The sdt.h integration was requested but the STAP_PROBEV define cannot be used. Make sure it is installed, and up to date, or use CPPFLAGS=-I/path/ to specify a non-standard path to sys/sdt.h])
	351	])
	352	])
	353
	354	AC_MSG_CHECKING([whether shared libraries are enabled])
	355	AS_IF([test "x$enable_shared" = "xyes"], [
	356	AC_MSG_RESULT([yes])
	357	], [
	358	AC_MSG_RESULT([no])
	359	AC_MSG_ERROR([LTTng-UST requires shared libraries to be enabled])
	360	])
	361
	362	AC_ARG_WITH([lttng-system-rundir], [
	363	AS_HELP_STRING([--with-lttng-system-rundir], [Location of the system directory where LTTng-UST expects the system-wide lttng-sessiond runtime files. The default is "/var/run/lttng".]),
	364	], [
	365	lttng_system_rundir="$withval"
	366	], [
	367	lttng_system_rundir="/var/run/lttng"
	368	])
	369	AC_DEFINE_UNQUOTED([LTTNG_SYSTEM_RUNDIR], ["$lttng_system_rundir"],
	370	[LTTng system runtime directory])
	371
	372	AC_CHECK_PROG([BUILD_GEN_TP_EXAMPLES], [python], ["yes"])
	373	AM_CONDITIONAL([BUILD_GEN_TP_EXAMPLES], [test "x$BUILD_GEN_TP_EXAMPLES" = "xyes"])
	374
	375	# Set $IN_GIT_REPO if we're in the Git repository; the `bootstrap` file
	376	# is not distributed in tarballs.
	377	AS_IF([test -f "$srcdir/bootstrap"], [in_git_repo=yes], [in_git_repo=no])
	378	AM_CONDITIONAL([IN_GIT_REPO], [test "x$in_git_repo" = "xyes"])
	379
	380	# Enable building man pages (user's intention).
	381	AC_ARG_ENABLE(
	382	man-pages,
	383	AS_HELP_STRING(
	384	[--disable-man-pages],
	385	[Do not build and install man pages (already built in a distributed tarball)]
	386	),
	387	[man_pages_opt=$enableval],
	388	[man_pages_opt=yes]
	389	)
	390
	391	# Check for asciidoc and xmlto if we enabled building the man pages.
	392	have_asciidoc_xmlto=no
	393
	394	AS_IF([test "x$man_pages_opt" = "xyes"], [
	395	AC_PATH_PROG([ASCIIDOC], [asciidoc], [no])
	396	AC_PATH_PROG([XMLTO], [xmlto], [no])
	397
	398	AS_IF([test "x$ASCIIDOC" = "xno" \|\| test "x$XMLTO" = "xno"], [
	399	AS_IF([test "x$in_git_repo" = "xyes"], [
	400	# This is an error because we're in the Git repo, which
	401	# means the man pages are not already generated for us,
	402	# thus asciidoc/xmlto are required because we were asked
	403	# to build the man pages.
	404	AC_MSG_ERROR([
	405	Both asciidoc and xmlto are needed to build the LTTng-UST man pages. Use
	406	--disable-man-pages to disable building the man pages, in which case
	407	they will not be installed.
	408	])
	409	], [
	410	# Only warn here: since we're in the tarball, the man
	411	# pages should already be generated at this point, thus
	412	# asciidoc/xmlto are not strictly required.
	413	AC_MSG_WARN([
	414	Both asciidoc and xmlto are needed to build the LTTng-UST man pages.
	415	Note that the man pages are already built in this distribution tarball,
	416	so asciidoc and xmlto are only needed if you intend to modify their
	417	sources. Use --disable-man-pages to completely disable building
	418	and installing the man pages.
	419	])
	420	])
	421	], [
	422	have_asciidoc_xmlto=yes
	423	])
	424	])
	425
	426	# Export man page build condition: build the man pages if the user
	427	# asked for it, and if the tools are available.
	428	AM_CONDITIONAL([MAN_PAGES_OPT], [test "x$man_pages_opt" != "xno"])
	429	AM_CONDITIONAL([HAVE_ASCIIDOC_XMLTO], [test "x$have_asciidoc_xmlto" = "xyes"])
	430
	431	# Default values
	432	AC_DEFUN([_AC_DEFINE_AND_SUBST], [
	433	AC_DEFINE_UNQUOTED([CONFIG_$1], [$2], [$1])
	434	$1="$2"
	435	AC_SUBST([$1])
	436	])
	437
	438	_AC_DEFINE_AND_SUBST([LTTNG_UST_DEFAULT_CONSTRUCTOR_TIMEOUT_MS], [3000])
	439
	440	AC_CONFIG_FILES([
	441	Makefile
	442	doc/Makefile
	443	doc/examples/Makefile
	444	doc/man/Makefile
	445	include/Makefile
	446	include/lttng/ust-version.h
	447	snprintf/Makefile
	448	libringbuffer/Makefile
	449	liblttng-ust-comm/Makefile
	450	liblttng-ust/Makefile
	451	liblttng-ust-ctl/Makefile
	452	liblttng-ust-fork/Makefile
	453	liblttng-ust-dl/Makefile
	454	liblttng-ust-java/Makefile
	455	liblttng-ust-java-agent/Makefile
	456	liblttng-ust-java-agent/java/Makefile
	457	liblttng-ust-java-agent/java/lttng-ust-agent-all/Makefile
	458	liblttng-ust-java-agent/java/lttng-ust-agent-common/Makefile
	459	liblttng-ust-java-agent/java/lttng-ust-agent-jul/Makefile
	460	liblttng-ust-java-agent/java/lttng-ust-agent-log4j/Makefile
	461	liblttng-ust-java-agent/jni/Makefile
	462	liblttng-ust-java-agent/jni/common/Makefile
	463	liblttng-ust-java-agent/jni/jul/Makefile
	464	liblttng-ust-java-agent/jni/log4j/Makefile
	465	liblttng-ust-libc-wrapper/Makefile
	466	liblttng-ust-cyg-profile/Makefile
	467	liblttng-ust-python-agent/Makefile
	468	python-lttngust/Makefile
	469	python-lttngust/setup.py
	470	python-lttngust/lttngust/__init__.py
	471	tools/Makefile
	472	tests/Makefile
	473	tests/ctf-types/Makefile
	474	tests/hello/Makefile
	475	tests/hello.cxx/Makefile
	476	tests/same_line_tracepoint/Makefile
	477	tests/snprintf/Makefile
	478	tests/ust-elf/Makefile
	479	tests/benchmark/Makefile
	480	tests/utils/Makefile
	481	tests/test-app-ctx/Makefile
	482	tests/gcc-weak-hidden/Makefile
	483	lttng-ust.pc
	484	])
	485
	486	# Create link for python agent for the VPATH guru.
	487	AC_CONFIG_LINKS([
	488	python-lttngust/lttngust/agent.py:python-lttngust/lttngust/agent.py
	489	python-lttngust/lttngust/cmd.py:python-lttngust/lttngust/cmd.py
	490	python-lttngust/lttngust/debug.py:python-lttngust/lttngust/debug.py
	491	python-lttngust/lttngust/loghandler.py:python-lttngust/lttngust/loghandler.py
	492	])
	493
	494	AC_OUTPUT
	495
	496	AS_ECHO
	497	AS_ECHO(["m4_bpatsubst(V_NAME, ["], [\\"])"])
	498	AS_ECHO
	499	AS_ECHO(["m4_bpatsubst(V_DESC, ["], [\\"])"])
	500
	501	# Report on the configuration options
	502	AS_ECHO
	503	AS_ECHO(["LTTng-UST will be built with the following options:"])
	504
	505	AS_ECHO
	506
	507	AS_ECHO_N(["Java agent (JUL support): "])
	508	AS_IF([test "x$java_agent_jul" = "xyes"], [AS_ECHO(["Enabled"])], [AS_ECHO(["Disabled (Use --enable-java-agent-jul)"])])
	509
	510	AS_ECHO_N(["Java agent (Log4j support): "])
	511	AS_IF([test "x$java_agent_log4j" = "xyes"], [AS_ECHO(["Enabled"])], [AS_ECHO(["Disabled (Use --enable-java-agent-log4j)"])])
	512
	513	AS_ECHO_N(["JNI interface (JNI): "])
	514	AS_IF([test "x$jni_interface" = "xyes"], [AS_ECHO(["Enabled"])], [AS_ECHO(["Disabled (Use --enable-jni-interface)"])])
	515
	516	AS_ECHO_N(["Python ($PYTHON) agent: "])
	517	AS_IF([test "x$python_agent" = "xyes"], [AS_ECHO(["Enabled"])], [AS_ECHO(["Disabled (Use --enable-python-agent)"])])
	518
	519	AS_ECHO_N(["sdt.h integration: "])
	520	AS_IF([test "x$with_sdt" = "xyes"], [AS_ECHO(["Enabled"])], [AS_ECHO(["Disabled"])])
	521
	522	AS_ECHO(["Architecture: $host_cpu"])
	523	AS_ECHO_N(["Efficient unaligned memory access: "])
	524	AS_IF([test "x$NO_UNALIGNED_ACCESS" != "x1"], [AS_ECHO(["yes"])], [AS_IF([test "x$UNSUPPORTED_ARCH" != "x1"], [AS_ECHO(["no"])], [AS_ECHO(["unknown"])])])
	525	AS_IF([test "x$UNSUPPORTED_ARCH" = "x1"], [AC_MSG_WARN([Your architecture ($host_cpu) is unsupported, using safe default of no unaligned access])])
	526	AS_ECHO
	527
	528	AS_ECHO(["Type 'make' to compile."])
	529