[lttng-ust.git] / configure.ac

#                                               -*- Autoconf -*-
# Process this file with autoconf to produce a configure script.

AC_INIT([lttng-ust],[2.4.0],[mathieu dot desnoyers at efficios dot com])

# Following the numbering scheme proposed by libtool for the library version
# http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
# This is the library version of liblttng-ust.
AC_SUBST([LTTNG_UST_LIBRARY_VERSION], [0:0:0])
# note: remember to update tracepoint.h dlopen() to match this version
# number. TODO: eventually automate by exporting the major number.

# This is the library version of liblttng-ust-ctl, used internally by
# liblttng-ust, lttng-sessiond, and lttng-consumerd.
AC_SUBST([LTTNG_UST_CTL_LIBRARY_VERSION], [2:0:0])

AC_CONFIG_AUX_DIR([config])
AC_CANONICAL_TARGET
AC_CANONICAL_HOST
AC_CONFIG_MACRO_DIR([config])
AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip])
AM_MAINTAINER_MODE([enable])
m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
AC_CONFIG_SRCDIR([include/lttng/tracepoint.h])

# Configuration options, which will be installed in the config.h
AC_CONFIG_HEADERS([config.h include/lttng/ust-config.h])
AH_TEMPLATE([LTTNG_UST_HAVE_EFFICIENT_UNALIGNED_ACCESS], [Use efficient unaligned access.])
AH_TEMPLATE([LTTNG_UST_HAVE_SDT_INTEGRATION], [SystemTap integration via sdt.h])

# Compute minor/major/patchlevel version numbers
AC_PROG_SED
major_version=$(echo AC_PACKAGE_VERSION | sed 's/^\([[0-9]]\)*\.[[0-9]]*\.[[0-9]]*.*$/\1/')
minor_version=$(echo AC_PACKAGE_VERSION | sed 's/^[[0-9]]*\.\([[0-9]]*\)\.[[0-9]]*.*$/\1/')
patchlevel_version=$(echo AC_PACKAGE_VERSION | sed 's/^[[0-9]]*\.[[0-9]]*\.\([[0-9]]*\).*$/\1/')
AC_SUBST([MAJOR_VERSION], [$major_version])
AC_SUBST([MINOR_VERSION], [$minor_version])
AC_SUBST([PATCHLEVEL_VERSION], [$patchlevel_version])
AC_DEFINE_UNQUOTED([VERSION_MAJOR], $major_version, [UST major version number])
AC_DEFINE_UNQUOTED([VERSION_MINOR], $minor_version, [UST minor version number])
AC_DEFINE_UNQUOTED([VERSION_PATCHLEVEL], $patchlevel_version, [UST patchlevel version number])

version_name="Époque Opaque"
version_description="The Époque Opaque is a black IPA from Trou du Diable brewery. The nose is eerily reminiscent of the coffee crisp candy from of our childhood. These strong mocha accents are present on the palate, which are quickly subdued by Japanese and Australian hops leading to a final state of satisfaction enjoyable for any fan of bitter beer."

AC_DEFINE_UNQUOTED([VERSION_NAME], ["$version_name"], [UST version name])
AC_DEFINE_UNQUOTED([VERSION_DESCRIPTION], ["$version_description"], [UST version description])

AC_PROG_GREP
# libtool link_all_deplibs fixup. See http://bugs.lttng.org/issues/321.
AC_ARG_ENABLE(libtool-linkdep-fixup,
	AS_HELP_STRING([--disable-libtool-linkdep-fixup],
			[disable the libtool fixup for linking all dependent libraries (link_all_deplibs)]),
	libtool_fixup=$enableval,
	libtool_fixup=yes)

AS_IF([test "x$libtool_fixup" = "xyes"],
	    [
	    libtool_m4="$srcdir/config/libtool.m4"
	    libtool_flag_pattern=".*link_all_deplibs\s*,\s*\$1\s*)"
	    AC_MSG_CHECKING([for occurence(s) of link_all_deplibs = no in $libtool_m4])
	    libtool_flag_pattern_count=$(grep -c "$libtool_flag_pattern\s*=\s*no" $libtool_m4)
	    AS_IF([test $libtool_flag_pattern_count -ne 0],
	    [
		  AC_MSG_RESULT([$libtool_flag_pattern_count])
		  AC_MSG_WARN([the detected libtool will not link all dependencies, forcing link_all_deplibs = unknown])
		  sed -i "s/\($libtool_flag_pattern\)\s*=\s*no/\1=unknown/g" $libtool_m4
		  ],
		  [
		  AC_MSG_RESULT([none])
		  ])
	    ])

AM_CONDITIONAL([NO_SHARED], [test "x$enable_shared" = "xno"])

# Checks for programs.
AC_PROG_CC
AC_PROG_CXX
AC_PROG_MAKE_SET
LT_INIT

# rw_PROG_CXX_WORKS
# Check whether the C++ compiler works.
AC_CACHE_CHECK([whether the C++ compiler works],
		[rw_cv_prog_cxx_works],
		[AC_LANG_PUSH([C++])
		AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
				[check_cxx_designated_initializers=yes],
				[rw_cv_prog_cxx_works=no])
		if test "$check_cxx_designated_initializers" = "yes"; then
			AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
				struct foo { int a; int b; };
				void fct(void)
				{
					struct foo f = { .a = 0, .b = 1 };
				}
			]])],[
				rw_cv_prog_cxx_works=yes
			],[
				rw_cv_prog_cxx_works=no
			])
		fi
		AC_LANG_POP([C++])])

AM_CONDITIONAL([CXX_WORKS], [test "x$rw_cv_prog_cxx_works" = "xyes"])

## Checks for libraries.
AC_CHECK_LIB([dl], [dlopen],
[
	have_libdl=yes
],
[
	#libdl not found, check for dlopen in libc.
	AC_CHECK_LIB([c], [dlopen],
	[
		have_libc_dl=yes
	],
	[
		AC_MSG_ERROR([Cannot find dlopen in libdl nor libc. Use [LDFLAGS]=-Ldir to specify their location.])
	])
])
AM_CONDITIONAL([LTTNG_UST_BUILD_WITH_LIBDL], [test "x$have_libdl" = "xyes"])
AM_CONDITIONAL([LTTNG_UST_BUILD_WITH_LIBC_DL], [test "x$have_libc_dl" = "xyes"])

AC_CHECK_LIB([pthread], [pthread_create])

# Checks for header files.
#AC_CHECK_HEADERS([fcntl.h stdint.h stdlib.h string.h sys/socket.h sys/time.h unistd.h])

# Checks for typedefs, structures, and compiler characteristics.
AC_C_INLINE
#AC_TYPE_INT16_T
#AC_TYPE_INT32_T
#AC_TYPE_INT64_T
#AC_TYPE_INT8_T
#AC_TYPE_PID_T
#AC_TYPE_SIZE_T
#AC_TYPE_SSIZE_T
#AC_TYPE_UINT16_T
#AC_TYPE_UINT32_T
#AC_TYPE_UINT64_T
#AC_TYPE_UINT8_T
#AC_CHECK_TYPES([ptrdiff_t])

# Checks for library functions.
AC_FUNC_MALLOC
AC_CHECK_FUNCS([gettimeofday munmap socket strerror strtol sched_getcpu sysconf])

CFLAGS="-Wall $CFLAGS"

# URCU

# urcu - check if we just find the headers it out of the box.
AC_CHECK_HEADERS([urcu-bp.h], [], [AC_MSG_ERROR([Cannot find [URCU] headers (urcu-bp.h). Use [CPPFLAGS]=-Idir to specify their location.
This error can also occur when the liburcu package's configure script has not been run.])])

# urcu-cds - check that URCU Concurrent Data Structure lib is available to compilation
# Part of Userspace RCU library 0.7.2 or better.
AC_CHECK_LIB([urcu-cds], [_cds_lfht_new], [], [AC_MSG_ERROR([Cannot find
liburcu-cds lib, part of Userspace RCU 0.7 or better. Use [LDFLAGS]=-Ldir to specify its location.])])

AC_MSG_CHECKING([caa_likely()])
AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
#include <urcu/compiler.h>
void fct(void)
{
	if (caa_likely(1)) {
	}
}
]])],[
	AC_MSG_RESULT([yes])
],[
	AC_MSG_RESULT([no])
	AC_MSG_ERROR([Please upgrade your version of liburcu to 0.6.6 or better])

])

# urcu - check that URCU lib is available to compilation
AC_CHECK_LIB([urcu-bp], [synchronize_rcu_bp], [], [AC_MSG_ERROR([Cannot find liburcu-bp lib. Use [LDFLAGS]=-Ldir to specify its location.])])

# urcu - check that URCU lib is at least version 0.6
AC_CHECK_LIB([urcu-bp], [call_rcu_bp], [], [AC_MSG_ERROR([liburcu 0.6 or newer is needed, please update your version or use [LDFLAGS]=-Ldir to specify the right location.])])

AC_MSG_CHECKING([host system alignment requirements])
case $host_cpu in
changequote(,)dnl
	i[3456]86)
changequote([,])dnl
	  ;;
	x86_64) ;;
	amd64) ;;
	powerpc) ;;
	ppc64) ;;
	powerpc64) ;;
	s390) NO_UNALIGNED_ACCESS=1 ;;
	s390x) NO_UNALIGNED_ACCESS=1 ;;
        arm*) NO_UNALIGNED_ACCESS=1 ;;
	mips*) NO_UNALIGNED_ACCESS=1 ;;
	tile*) NO_UNALIGNED_ACCESS=1 ;;
	*) AC_MSG_ERROR([unable to detect alignment requirements (unsupported architecture ($host_cpu)?)]) ;;
esac
AC_MSG_RESULT([$host_cpu])

if test x$NO_UNALIGNED_ACCESS = x ; then
AC_DEFINE([LTTNG_UST_HAVE_EFFICIENT_UNALIGNED_ACCESS], [1])
fi

# Set compile flags to java include files if given
AC_ARG_WITH([java-jdk],
	[AS_HELP_STRING([--with-java-jdk=DIR],[use the Java JDK in DIR. Ex : $JAVA_HOME.])],
	[JAVA_JDK=$withval],
	[JAVA_JDK=""]
)
AM_CONDITIONAL([HAVE_JAVA_JDK], [test $JAVA_JDK], [Java JDK path])
AC_SUBST([JAVA_JDK])

AS_IF([test $JAVA_JDK],[
	AS_IF([test -d $JAVA_JDK],[
                AC_MSG_RESULT([using Java includes in $JAVA_SDK])
                SUBDIRS=`find $JAVA_JDK/include -type d`
		CPPFLAGS+=" "
                CPPFLAGS+=`for x in $SUBDIRS; do echo -n "-I$x "; done`
		CPPFLAGS+=" "
        ],[
                AC_MSG_ERROR(Unable to find Java include files in $JAVA_JDK)
        ])
])

# Check for JNI header files if requested
AC_ARG_WITH([jni-interface],
	[AS_HELP_STRING([--with-jni-interface],[build JNI interface between C and Java. Needs Java include files [default=no]])],
	[jni_interface=$withval],
	[jni_interface=no]
)

AS_IF([test "x$jni_interface" = "xyes"],[
        AC_CHECK_HEADERS([jni.h],[],[
        AC_MSG_ERROR([missing jni.h
Make sure Sun Java, OpenJDK or GCJ is installed and that this header file exists in the system path.
Use the --with-java-jdk=DIR flag to point to your Java include files, or disable the JNI interface.])
	])
])
AM_CONDITIONAL([BUILD_JNI_INTERFACE], [test "x$jni_interface" = "xyes"])

# sdt.h integration
AC_ARG_WITH([sdt],
	[AS_HELP_STRING([--with-sdt],[provide SystemTap integration via sdt.h [default=no]])],
	[with_sdt=$withval],
	[with_sdt="no"]
)

AS_IF([test "x$with_sdt" = "xyes"],[
	AC_MSG_CHECKING([STAP_PROBEV()])
	AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
	#define SDT_USE_VARIADIC
	#include <sys/sdt.h>
	void fct(void)
	{
		STAP_PROBEV(provider,name,1,2,3,4,5,6,7,8,9,10);
	}
	]])],[
		AC_MSG_RESULT([yes])
		AC_DEFINE([LTTNG_UST_HAVE_SDT_INTEGRATION], [1])
	],[
		AC_MSG_RESULT([no])
		AC_MSG_ERROR([The sdt.h integration was requested but the STAP_PROBEV define cannot be used. Make sure it is installed, and up to date, or use CPPFLAGS=-I/path/ to specify a non-standard path to sys/sdt.h])
	])
])

AC_MSG_CHECKING([whether shared libraries are enabled])
AS_IF([test "x$enable_shared" = "xyes"],
	[
		AC_MSG_RESULT([yes])
	],
	[
		AC_MSG_RESULT([no])
		AC_MSG_ERROR([LTTng-UST requires shared libraries to be enabled])
	])

AC_ARG_WITH([lttng-system-rundir],
	AS_HELP_STRING([--with-lttng-system-rundir],
	[Location of the system directory where LTTng-UST expects the system-wide lttng-sessiond runtime files. The default is "/var/run/lttng".]),
	[lttng_system_rundir="$withval"],
	[lttng_system_rundir="/var/run/lttng"])
AC_DEFINE_UNQUOTED([LTTNG_SYSTEM_RUNDIR], ["$lttng_system_rundir"],
	[LTTng system runtime directory])

lttnglibjavadir="${libdir}/lttng/java"
AC_SUBST(lttnglibjavadir)

AM_PATH_PYTHON([2.7],BUILD_GEN_TP_EXAMPLES=1,[:])
AM_CONDITIONAL([BUILD_GEN_TP_EXAMPLES], [test $BUILD_GEN_TP_EXAMPLES], [Build examples requiring lttng-gen-tp])

AC_CONFIG_FILES([
	Makefile
	doc/Makefile
	doc/examples/Makefile
	include/Makefile
	include/lttng/ust-version.h
	snprintf/Makefile
	libringbuffer/Makefile
	liblttng-ust-comm/Makefile
	liblttng-ust/Makefile
	liblttng-ust-ctl/Makefile
	liblttng-ust-fork/Makefile
	liblttng-ust-dl/Makefile
	liblttng-ust-java/Makefile
	liblttng-ust-jul/Makefile
	liblttng-ust-libc-wrapper/Makefile
	liblttng-ust-cyg-profile/Makefile
	tools/Makefile
	tests/Makefile
	tests/hello/Makefile
	tests/hello.cxx/Makefile
	tests/same_line_tracepoint/Makefile
	tests/snprintf/Makefile
	tests/benchmark/Makefile
	tests/utils/Makefile
	tests/java-jul/Makefile
	lttng-ust.pc
])

AC_OUTPUT

AS_ECHO()
AS_ECHO("Version name: $version_name")
AS_ECHO("$version_description")

# Report on the configuration options
AS_ECHO()
AS_ECHO("LTTng-UST will be built with the following options:")

AS_ECHO()
AS_ECHO_N("Java support (JNI): ")
AS_IF([test "x$jni_interface" = "xyes"], [AS_ECHO("Enabled")], [AS_ECHO("Disabled")])

AS_ECHO_N("sdt.h integration:  ")
AS_IF([test "x$with_sdt" = "xyes"], [AS_ECHO("Enabled")], [AS_ECHO("Disabled")])

AS_ECHO()
AS_ECHO("Type 'make' to compile.")
Commit	Line	Data
1304f3df PMF	1	# -- Autoconf --
	2	# Process this file with autoconf to produce a configure script.
	3
5ba5bf7f	4	AC_INIT([lttng-ust],[2.4.0],[mathieu dot desnoyers at efficios dot com])
a334646a MD	5
	6	# Following the numbering scheme proposed by libtool for the library version
	7	# http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
41a2a9aa	8	# This is the library version of liblttng-ust.
a334646a MD	9	AC_SUBST([LTTNG_UST_LIBRARY_VERSION], [0:0:0])
	10	# note: remember to update tracepoint.h dlopen() to match this version
	11	# number. TODO: eventually automate by exporting the major number.
	12
41a2a9aa MD	13	# This is the library version of liblttng-ust-ctl, used internally by
41a2a9aa MD	14	# liblttng-ust, lttng-sessiond, and lttng-consumerd.
76bacff6	15	AC_SUBST([LTTNG_UST_CTL_LIBRARY_VERSION], [2:0:0])
41a2a9aa	16
55355fa5	17	AC_CONFIG_AUX_DIR([config])
9441df61 PMF	18	AC_CANONICAL_TARGET
9441df61 PMF	19	AC_CANONICAL_HOST
50f3dba0	20	AC_CONFIG_MACRO_DIR([config])
76ceb8db	21	AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip])
846154aa	22	AM_MAINTAINER_MODE([enable])
50f3dba0	23	m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
4318ae1b	24	AC_CONFIG_SRCDIR([include/lttng/tracepoint.h])
4846fadc AM	25
4846fadc AM	26	# Configuration options, which will be installed in the config.h
562c813a MD	27	AC_CONFIG_HEADERS([config.h include/lttng/ust-config.h])
562c813a MD	28	AH_TEMPLATE([LTTNG_UST_HAVE_EFFICIENT_UNALIGNED_ACCESS], [Use efficient unaligned access.])
02120ddf	29	AH_TEMPLATE([LTTNG_UST_HAVE_SDT_INTEGRATION], [SystemTap integration via sdt.h])
23c8854a	30
b728d87e	31	# Compute minor/major/patchlevel version numbers
23c8854a	32	AC_PROG_SED
2694975d MD	33	major_version=$(echo AC_PACKAGE_VERSION \| sed 's/^\([[0-9]]\)\.[[0-9]]\.[[0-9]].$/\1/')
	34	minor_version=$(echo AC_PACKAGE_VERSION \| sed 's/^[[0-9]]\.\([[0-9]]\)\.[[0-9]].$/\1/')
	35	patchlevel_version=$(echo AC_PACKAGE_VERSION \| sed 's/^[[0-9]]\.[[0-9]]\.\([[0-9]]\).$/\1/')
161239e0 YB	36	AC_SUBST([MAJOR_VERSION], [$major_version])
161239e0 YB	37	AC_SUBST([MINOR_VERSION], [$minor_version])
b728d87e	38	AC_SUBST([PATCHLEVEL_VERSION], [$patchlevel_version])
161239e0 YB	39	AC_DEFINE_UNQUOTED([VERSION_MAJOR], $major_version, [UST major version number])
161239e0 YB	40	AC_DEFINE_UNQUOTED([VERSION_MINOR], $minor_version, [UST minor version number])
b728d87e	41	AC_DEFINE_UNQUOTED([VERSION_PATCHLEVEL], $patchlevel_version, [UST patchlevel version number])
161239e0	42
48de55ad MD	43	version_name="Époque Opaque"
48de55ad MD	44	version_description="The Époque Opaque is a black IPA from Trou du Diable brewery. The nose is eerily reminiscent of the coffee crisp candy from of our childhood. These strong mocha accents are present on the palate, which are quickly subdued by Japanese and Australian hops leading to a final state of satisfaction enjoyable for any fan of bitter beer."
0ff43c44	45
1c59f149 MD	46	AC_DEFINE_UNQUOTED([VERSION_NAME], ["$version_name"], [UST version name])
1c59f149 MD	47	AC_DEFINE_UNQUOTED([VERSION_DESCRIPTION], ["$version_description"], [UST version description])
1304f3df	48
faebb418 CB	49	AC_PROG_GREP
	50	# libtool link_all_deplibs fixup. See http://bugs.lttng.org/issues/321.
	51	AC_ARG_ENABLE(libtool-linkdep-fixup,
	52	AS_HELP_STRING([--disable-libtool-linkdep-fixup],
	53	[disable the libtool fixup for linking all dependent libraries (link_all_deplibs)]),
	54	libtool_fixup=$enableval,
	55	libtool_fixup=yes)
	56
	57	AS_IF([test "x$libtool_fixup" = "xyes"],
	58	[
	59	libtool_m4="$srcdir/config/libtool.m4"
	60	libtool_flag_pattern=".link_all_deplibs\s,\s\$1\s)"
	61	AC_MSG_CHECKING([for occurence(s) of link_all_deplibs = no in $libtool_m4])
	62	libtool_flag_pattern_count=$(grep -c "$libtool_flag_pattern\s=\sno" $libtool_m4)
	63	AS_IF([test $libtool_flag_pattern_count -ne 0],
	64	[
	65	AC_MSG_RESULT([$libtool_flag_pattern_count])
	66	AC_MSG_WARN([the detected libtool will not link all dependencies, forcing link_all_deplibs = unknown])
	67	sed -i "s/\($libtool_flag_pattern\)\s=\sno/\1=unknown/g" $libtool_m4
	68	],
	69	[
	70	AC_MSG_RESULT([none])
	71	])
	72	])
	73
824a00a7 MD	74	AM_CONDITIONAL([NO_SHARED], [test "x$enable_shared" = "xno"])
824a00a7 MD	75
1304f3df PMF	76	# Checks for programs.
1304f3df PMF	77	AC_PROG_CC
6b79f035	78	AC_PROG_CXX
1304f3df	79	AC_PROG_MAKE_SET
fa1c6efe	80	LT_INIT
1304f3df	81
340f7763 SM	82	# rw_PROG_CXX_WORKS
	83	# Check whether the C++ compiler works.
	84	AC_CACHE_CHECK([whether the C++ compiler works],
	85	[rw_cv_prog_cxx_works],
	86	[AC_LANG_PUSH([C++])
	87	AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
8481f7a0	88	[check_cxx_designated_initializers=yes],
340f7763	89	[rw_cv_prog_cxx_works=no])
8481f7a0 ZT	90	if test "$check_cxx_designated_initializers" = "yes"; then
	91	AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
	92	struct foo { int a; int b; };
	93	void fct(void)
	94	{
	95	struct foo f = { .a = 0, .b = 1 };
	96	}
	97	]])],[
	98	rw_cv_prog_cxx_works=yes
	99	],[
	100	rw_cv_prog_cxx_works=no
	101	])
	102	fi
340f7763 SM	103	AC_LANG_POP([C++])])
	104
	105	AM_CONDITIONAL([CXX_WORKS], [test "x$rw_cv_prog_cxx_works" = "xyes"])
	106
1304f3df	107	## Checks for libraries.
c6c454ab MD	108	AC_CHECK_LIB([dl], [dlopen],
	109	[
	110	have_libdl=yes
	111	],
	112	[
	113	#libdl not found, check for dlopen in libc.
	114	AC_CHECK_LIB([c], [dlopen],
	115	[
	116	have_libc_dl=yes
	117	],
	118	[
	119	AC_MSG_ERROR([Cannot find dlopen in libdl nor libc. Use [LDFLAGS]=-Ldir to specify their location.])
	120	])
	121	])
	122	AM_CONDITIONAL([LTTNG_UST_BUILD_WITH_LIBDL], [test "x$have_libdl" = "xyes"])
	123	AM_CONDITIONAL([LTTNG_UST_BUILD_WITH_LIBC_DL], [test "x$have_libc_dl" = "xyes"])
	124
e26c8207	125	AC_CHECK_LIB([pthread], [pthread_create])
1304f3df PMF	126
	127	# Checks for header files.
	128	#AC_CHECK_HEADERS([fcntl.h stdint.h stdlib.h string.h sys/socket.h sys/time.h unistd.h])
	129
	130	# Checks for typedefs, structures, and compiler characteristics.
	131	AC_C_INLINE
	132	#AC_TYPE_INT16_T
	133	#AC_TYPE_INT32_T
	134	#AC_TYPE_INT64_T
	135	#AC_TYPE_INT8_T
	136	#AC_TYPE_PID_T
	137	#AC_TYPE_SIZE_T
	138	#AC_TYPE_SSIZE_T
	139	#AC_TYPE_UINT16_T
	140	#AC_TYPE_UINT32_T
	141	#AC_TYPE_UINT64_T
	142	#AC_TYPE_UINT8_T
	143	#AC_CHECK_TYPES([ptrdiff_t])
	144
	145	# Checks for library functions.
	146	AC_FUNC_MALLOC
e9d165be	147	AC_CHECK_FUNCS([gettimeofday munmap socket strerror strtol sched_getcpu sysconf])
1304f3df	148
fbae86d6 MD	149	CFLAGS="-Wall $CFLAGS"
fbae86d6 MD	150
8624c549 PMF	151	# URCU
	152
	153	# urcu - check if we just find the headers it out of the box.
135987a5	154	AC_CHECK_HEADERS([urcu-bp.h], [], [AC_MSG_ERROR([Cannot find [URCU] headers (urcu-bp.h). Use [CPPFLAGS]=-Idir to specify their location.
cacb7fbe	155	This error can also occur when the liburcu package's configure script has not been run.])])
bf956ec0 MD	156
	157	# urcu-cds - check that URCU Concurrent Data Structure lib is available to compilation
	158	# Part of Userspace RCU library 0.7.2 or better.
	159	AC_CHECK_LIB([urcu-cds], [_cds_lfht_new], [], [AC_MSG_ERROR([Cannot find
	160	liburcu-cds lib, part of Userspace RCU 0.7 or better. Use [LDFLAGS]=-Ldir to specify its location.])])
8624c549	161
b5a3dfa5	162	AC_MSG_CHECKING([caa_likely()])
31b07350	163	AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
b5a3dfa5	164	#include <urcu/compiler.h>
b5a3dfa5 MD	165	void fct(void)
	166	{
	167	if (caa_likely(1)) {
	168	}
	169	}
727bb6cb	170	]])],[
b5a3dfa5	171	AC_MSG_RESULT([yes])
727bb6cb	172	],[
b5a3dfa5 MD	173	AC_MSG_RESULT([no])
b5a3dfa5 MD	174	AC_MSG_ERROR([Please upgrade your version of liburcu to 0.6.6 or better])
727bb6cb MD	175
727bb6cb MD	176	])
b5a3dfa5	177
8624c549	178	# urcu - check that URCU lib is available to compilation
cfa0520d	179	AC_CHECK_LIB([urcu-bp], [synchronize_rcu_bp], [], [AC_MSG_ERROR([Cannot find liburcu-bp lib. Use [LDFLAGS]=-Ldir to specify its location.])])
e3073410	180
a6830b14 MD	181	# urcu - check that URCU lib is at least version 0.6
a6830b14 MD	182	AC_CHECK_LIB([urcu-bp], [call_rcu_bp], [], [AC_MSG_ERROR([liburcu 0.6 or newer is needed, please update your version or use [LDFLAGS]=-Ldir to specify the right location.])])
e3073410	183
dca6e79f	184	AC_MSG_CHECKING([host system alignment requirements])
8fb0c941	185	case $host_cpu in
8c98245f PA	186	changequote(,)dnl
	187	i[3456]86)
	188	changequote([,])dnl
8c98245f	189	;;
dca6e79f MD	190	x86_64) ;;
	191	amd64) ;;
	192	powerpc) ;;
	193	ppc64) ;;
	194	powerpc64) ;;
	195	s390) NO_UNALIGNED_ACCESS=1 ;;
	196	s390x) NO_UNALIGNED_ACCESS=1 ;;
	197	arm*) NO_UNALIGNED_ACCESS=1 ;;
bdac72fd SM	198	mips*) NO_UNALIGNED_ACCESS=1 ;;
bdac72fd SM	199	tile*) NO_UNALIGNED_ACCESS=1 ;;
dca6e79f	200	*) AC_MSG_ERROR([unable to detect alignment requirements (unsupported architecture ($host_cpu)?)]) ;;
9441df61	201	esac
f039c6b0	202	AC_MSG_RESULT([$host_cpu])
ed452f03	203
2699970a	204	if test x$NO_UNALIGNED_ACCESS = x ; then
562c813a	205	AC_DEFINE([LTTNG_UST_HAVE_EFFICIENT_UNALIGNED_ACCESS], [1])
2699970a JW	206	fi
2699970a JW	207
2b6f8df9	208	# Set compile flags to java include files if given
b2263155 AM	209	AC_ARG_WITH([java-jdk],
	210	[AS_HELP_STRING([--with-java-jdk=DIR],[use the Java JDK in DIR. Ex : $JAVA_HOME.])],
	211	[JAVA_JDK=$withval],
	212	[JAVA_JDK=""]
	213	)
43e5396b DG	214	AM_CONDITIONAL([HAVE_JAVA_JDK], [test $JAVA_JDK], [Java JDK path])
	215	AC_SUBST([JAVA_JDK])
	216
b2263155 AM	217	AS_IF([test $JAVA_JDK],[
	218	AS_IF([test -d $JAVA_JDK],[
	219	AC_MSG_RESULT([using Java includes in $JAVA_SDK])
	220	SUBDIRS=`find $JAVA_JDK/include -type d`
135987a5 MD	221	CPPFLAGS+=" "
	222	CPPFLAGS+=`for x in $SUBDIRS; do echo -n "-I$x "; done`
	223	CPPFLAGS+=" "
b2263155 AM	224	],[
	225	AC_MSG_ERROR(Unable to find Java include files in $JAVA_JDK)
	226	])
	227	])
2b6f8df9 MD	228
2b6f8df9 MD	229	# Check for JNI header files if requested
b2263155 AM	230	AC_ARG_WITH([jni-interface],
	231	[AS_HELP_STRING([--with-jni-interface],[build JNI interface between C and Java. Needs Java include files [default=no]])],
	232	[jni_interface=$withval],
	233	[jni_interface=no]
	234	)
2b6f8df9	235
b2263155 AM	236	AS_IF([test "x$jni_interface" = "xyes"],[
	237	AC_CHECK_HEADERS([jni.h],[],[
	238	AC_MSG_ERROR([missing jni.h
	239	Make sure Sun Java, OpenJDK or GCJ is installed and that this header file exists in the system path.
	240	Use the --with-java-jdk=DIR flag to point to your Java include files, or disable the JNI interface.])
	241	])
	242	])
	243	AM_CONDITIONAL([BUILD_JNI_INTERFACE], [test "x$jni_interface" = "xyes"])
2b6f8df9	244
4846fadc AM	245	# sdt.h integration
4846fadc AM	246	AC_ARG_WITH([sdt],
02120ddf	247	[AS_HELP_STRING([--with-sdt],[provide SystemTap integration via sdt.h [default=no]])],
4846fadc AM	248	[with_sdt=$withval],
	249	[with_sdt="no"]
	250	)
	251
	252	AS_IF([test "x$with_sdt" = "xyes"],[
491f30fe MD	253	AC_MSG_CHECKING([STAP_PROBEV()])
	254	AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
	255	#define SDT_USE_VARIADIC
	256	#include <sys/sdt.h>
	257	void fct(void)
	258	{
	259	STAP_PROBEV(provider,name,1,2,3,4,5,6,7,8,9,10);
	260	}
	261	]])],[
	262	AC_MSG_RESULT([yes])
562c813a	263	AC_DEFINE([LTTNG_UST_HAVE_SDT_INTEGRATION], [1])
4846fadc	264	],[
491f30fe	265	AC_MSG_RESULT([no])
135987a5	266	AC_MSG_ERROR([The sdt.h integration was requested but the STAP_PROBEV define cannot be used. Make sure it is installed, and up to date, or use CPPFLAGS=-I/path/ to specify a non-standard path to sys/sdt.h])
4846fadc AM	267	])
	268	])
	269
ccb19569 MD	270	AC_MSG_CHECKING([whether shared libraries are enabled])
	271	AS_IF([test "x$enable_shared" = "xyes"],
	272	[
	273	AC_MSG_RESULT([yes])
	274	],
	275	[
	276	AC_MSG_RESULT([no])
	277	AC_MSG_ERROR([LTTng-UST requires shared libraries to be enabled])
	278	])
	279
751d4e91 MD	280	AC_ARG_WITH([lttng-system-rundir],
	281	AS_HELP_STRING([--with-lttng-system-rundir],
	282	[Location of the system directory where LTTng-UST expects the system-wide lttng-sessiond runtime files. The default is "/var/run/lttng".]),
	283	[lttng_system_rundir="$withval"],
	284	[lttng_system_rundir="/var/run/lttng"])
	285	AC_DEFINE_UNQUOTED([LTTNG_SYSTEM_RUNDIR], ["$lttng_system_rundir"],
	286	[LTTng system runtime directory])
	287
6490eba0 MD	288	lttnglibjavadir="${libdir}/lttng/java"
	289	AC_SUBST(lttnglibjavadir)
	290
dcb6ba25	291	AM_PATH_PYTHON([2.7],BUILD_GEN_TP_EXAMPLES=1,[:])
2b90f1d3 JG	292	AM_CONDITIONAL([BUILD_GEN_TP_EXAMPLES], [test $BUILD_GEN_TP_EXAMPLES], [Build examples requiring lttng-gen-tp])
2b90f1d3 JG	293
55355fa5 JB	294	AC_CONFIG_FILES([
55355fa5 JB	295	Makefile
7ccf75d3 MD	296	doc/Makefile
7ccf75d3 MD	297	doc/examples/Makefile
69400ac4	298	include/Makefile
b728d87e	299	include/lttng/ust-version.h
69400ac4	300	snprintf/Makefile
4931a13e	301	libringbuffer/Makefile
69400ac4 MD	302	liblttng-ust-comm/Makefile
	303	liblttng-ust/Makefile
	304	liblttng-ust-ctl/Makefile
	305	liblttng-ust-fork/Makefile
b13d93c2	306	liblttng-ust-dl/Makefile
69400ac4	307	liblttng-ust-java/Makefile
43e5396b	308	liblttng-ust-jul/Makefile
476037d9	309	liblttng-ust-libc-wrapper/Makefile
70d654f2	310	liblttng-ust-cyg-profile/Makefile
b25c5b37	311	tools/Makefile
6dd969b5 PMF	312	tests/Makefile
6dd969b5 PMF	313	tests/hello/Makefile
6b79f035	314	tests/hello.cxx/Makefile
90c09854	315	tests/same_line_tracepoint/Makefile
d23b20e9	316	tests/snprintf/Makefile
a44af49d	317	tests/benchmark/Makefile
9a4b88ff	318	tests/utils/Makefile
43e5396b	319	tests/java-jul/Makefile
74a6d87b	320	lttng-ust.pc
55355fa5	321	])
1f9eff07	322
1304f3df	323	AC_OUTPUT
1f9eff07	324
649282a8 MD	325	AS_ECHO()
	326	AS_ECHO("Version name: $version_name")
	327	AS_ECHO("$version_description")
	328
1f9eff07 AM	329	# Report on the configuration options
	330	AS_ECHO()
	331	AS_ECHO("LTTng-UST will be built with the following options:")
1f9eff07 AM	332
	333	AS_ECHO()
	334	AS_ECHO_N("Java support (JNI): ")
	335	AS_IF([test "x$jni_interface" = "xyes"], [AS_ECHO("Enabled")], [AS_ECHO("Disabled")])
	336
	337	AS_ECHO_N("sdt.h integration: ")
	338	AS_IF([test "x$with_sdt" = "xyes"], [AS_ECHO("Enabled")], [AS_ECHO("Disabled")])
	339
	340	AS_ECHO()
	341	AS_ECHO("Type 'make' to compile.")
	342