configure.ac

   1 dnl Version infos
   2 m4_define([V_MAJOR], [2])
   3 m4_define([V_MINOR], [13])
   4 m4_define([V_PATCH], [0])
   5 m4_define([V_EXTRA], [pre])
   6 m4_define([V_NAME], [[Codename TBD]])
   7 m4_define([V_DESC], [[Description TBD]])
   8
   9 m4_define([V_STRING], [V_MAJOR.V_MINOR.V_PATCH])
  10 m4_ifdef([V_EXTRA], [m4_append([V_STRING], [-V_EXTRA])])
  11
  12 AC_PREREQ(2.59)
  13 AC_INIT([lttng-ust], V_STRING, [mathieu dot desnoyers at efficios dot com], [], [https://lttng.org])
  14
  15 dnl Substitute minor/major/patchlevel version numbers
  16 AC_SUBST([MAJOR_VERSION], [V_MAJOR])
  17 AC_SUBST([MINOR_VERSION], [V_MINOR])
  18 AC_SUBST([PATCHLEVEL_VERSION], [V_PATCH])
  19
  20 # Following the numbering scheme proposed by libtool for the library version
  21 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
  22 # This is the library version of liblttng-ust.
  23 m4_define([UST_LIB_V_MAJOR], [0])
  24 m4_define([UST_LIB_V_MINOR], [0])
  25 m4_define([UST_LIB_V_PATCH], [0])
  26
  27 AC_SUBST([LTTNG_UST_LIBRARY_VERSION], [UST_LIB_V_MAJOR:UST_LIB_V_MINOR:UST_LIB_V_PATCH])
  28 AC_DEFINE([CONFIG_LTTNG_UST_LIBRARY_VERSION_MAJOR], [UST_LIB_V_MAJOR], [Major SONAME number of the ust library])
  29 # note: remember to update tracepoint.h dlopen() to match this version
  30 # number. TODO: eventually automate by exporting the major number.
  31
  32 # This is the library version of liblttng-ust-ctl, used internally by
  33 # liblttng-ust, lttng-sessiond, and lttng-consumerd.
  34 AC_SUBST([LTTNG_UST_CTL_LIBRARY_VERSION], [4:0:0])
  35
  36 AC_CONFIG_HEADERS([include/config.h include/lttng/ust-config.h])
  37 AC_CONFIG_AUX_DIR([config])
  38 AC_CONFIG_MACRO_DIR([m4])
  39 AC_CONFIG_SRCDIR([include/lttng/tracepoint.h])
  40
  41 AC_CANONICAL_TARGET
  42 AC_CANONICAL_HOST
  43
  44 AM_INIT_AUTOMAKE([1.12 foreign dist-bzip2 no-dist-gzip tar-ustar nostdinc])
  45 AM_MAINTAINER_MODE([enable])
  46
  47 # Enable silent rules if available (Introduced in AM 1.11)
  48 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  49
  50 AC_REQUIRE_AUX_FILE([tap-driver.sh])
  51
  52 # Checks for C compiler
  53 AC_USE_SYSTEM_EXTENSIONS
  54 AC_SYS_LARGEFILE
  55 AC_PROG_CC
  56 AC_PROG_CC_STDC
  57 AC_PROG_CXX
  58 AX_CXX_COMPILE_STDCXX([11])
  59 RW_PROG_CXX_WORKS
  60 AM_CONDITIONAL([CXX_WORKS], [test "x$rw_cv_prog_cxx_works" = "xyes"])
  61
  62 # Check if the compiler support weak symbols
  63 AX_SYS_WEAK_ALIAS
  64
  65 AS_IF([test "x${ax_cv_sys_weak_alias}" = "xno"], [
  66         AC_MSG_ERROR([Your platform doesn't support weak symbols.])
  67 ])
  68
  69 # Checks for programs.
  70 AM_PROG_AR
  71 AC_PROG_SED
  72 AC_PROG_GREP
  73 AC_PROG_LN_S
  74 AC_PROG_MKDIR_P
  75 AC_PROG_MAKE_SET
  76 AC_CHECK_PROG([HAVE_CMAKE], [cmake], ["yes"])
  77 AM_CONDITIONAL([HAVE_CMAKE], [test "x$HAVE_CMAKE" = "xyes"])
  78
  79 # libtool link_all_deplibs fixup. See http://bugs.lttng.org/issues/321.
  80 AC_ARG_ENABLE([libtool-linkdep-fixup], [
  81 AS_HELP_STRING([--disable-libtool-linkdep-fixup], [disable the libtool fixup for linking all dependent libraries (link_all_deplibs)])
  82 ], [
  83         libtool_fixup=$enableval
  84 ], [
  85         libtool_fixup=yes
  86 ])
  87
  88 AS_IF([test "x$libtool_fixup" = "xyes"], [
  89         libtool_m4="$srcdir/m4/libtool.m4"
  90         libtool_flag_pattern=".*link_all_deplibs\s*,\s*\$1\s*)"
  91         AC_MSG_CHECKING([for occurence(s) of link_all_deplibs = no in $libtool_m4])
  92         libtool_flag_pattern_count=$(grep -c "$libtool_flag_pattern\s*=\s*no" $libtool_m4)
  93
  94         AS_IF([test $libtool_flag_pattern_count -ne 0], [
  95         AC_MSG_RESULT([$libtool_flag_pattern_count])
  96         AC_MSG_WARN([the detected libtool will not link all dependencies, forcing link_all_deplibs = unknown])
  97                 $SED -i "s/\($libtool_flag_pattern\)\s*=\s*no/\1=unknown/g" $libtool_m4
  98         ], [
  99                 AC_MSG_RESULT([none])
 100         ])
 101 ])
 102 LT_INIT([disable-static])
 103
 104 AC_MSG_CHECKING([whether shared libraries are enabled])
 105 AS_IF([test "x$enable_shared" = "xyes"], [
 106         AC_MSG_RESULT([yes])
 107 ], [
 108         AC_MSG_RESULT([no])
 109         AC_MSG_ERROR([LTTng-UST requires shared libraries to be enabled])
 110 ])
 111
 112 # Checks for typedefs, structures, and compiler characteristics.
 113 AC_C_INLINE
 114 AC_TYPE_INT8_T
 115 AC_TYPE_INT16_T
 116 AC_TYPE_INT32_T
 117 AC_TYPE_INT64_T
 118 AC_TYPE_MODE_T
 119 AC_TYPE_OFF_T
 120 AC_TYPE_PID_T
 121 AC_TYPE_SIZE_T
 122 AC_TYPE_SSIZE_T
 123 AC_TYPE_UID_T
 124 AC_TYPE_UINT8_T
 125 AC_TYPE_UINT16_T
 126 AC_TYPE_UINT32_T
 127 AC_TYPE_UINT64_T
 128 AC_CHECK_TYPES([ptrdiff_t])
 129
 130 AX_C___ATTRIBUTE__
 131 AS_IF([test "x$ax_cv___attribute__" = "xyes"],
 132         [:],
 133         [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])
 134
 135 AX_PTHREAD(,[AC_MSG_ERROR([Could not configure pthreads support])])
 136
 137 # Checks for library functions.
 138 AC_FUNC_CHOWN
 139 AC_FUNC_FORK
 140 AC_FUNC_MMAP
 141 AC_FUNC_REALLOC
 142 AC_FUNC_STRERROR_R
 143 AC_FUNC_STRNLEN
 144 AC_CHECK_FUNCS([ \
 145         atexit \
 146         clock_gettime \
 147         ftruncate \
 148         getpagesize \
 149         gettimeofday \
 150         localeconv \
 151         memchr \
 152         memmove \
 153         memset \
 154         mkdir \
 155         munmap \
 156         realpath \
 157         sched_getcpu \
 158         socket \
 159         strchr \
 160         strdup \
 161         strerror \
 162         strtol \
 163         sysconf \
 164 ])
 165
 166 # Check for pthread_setname_np and its signature
 167 LTTNG_PTHREAD_SETNAME_NP
 168
 169 # AC_FUNC_MALLOC causes problems when cross-compiling.
 170 #AC_FUNC_MALLOC
 171
 172 # Checks for header files.
 173 AC_HEADER_STDBOOL
 174 AC_CHECK_HEADERS([ \
 175         arpa/inet.h \
 176         fcntl.h \
 177         float.h \
 178         limits.h \
 179         locale.h \
 180         stddef.h \
 181         sys/socket.h \
 182         sys/time.h \
 183         wchar.h \
 184 ])
 185
 186 # Set architecture specific options
 187 AS_CASE([$host_cpu],
 188         [i[[3456]]86], [],
 189         [x86_64], [],
 190         [amd64], [],
 191         [powerpc], [],
 192         [ppc64], [],
 193         [ppc64le], [],
 194         [powerpc64], [],
 195         [powerpc64le], [],
 196         [s390], [NO_UNALIGNED_ACCESS=1],
 197         [s390x], [NO_UNALIGNED_ACCESS=1],
 198         [arm*], [
 199                 NO_UNALIGNED_ACCESS=1
 200                 NO_NUMA=1
 201                 ],
 202         [aarch64*], [NO_UNALIGNED_ACCESS=1],
 203         [mips*], [NO_UNALIGNED_ACCESS=1],
 204         [tile*], [NO_UNALIGNED_ACCESS=1],
 205         [
 206                 UNSUPPORTED_ARCH=1
 207                 NO_UNALIGNED_ACCESS=1
 208         ])
 209
 210 # Set os specific options
 211 AS_CASE([$host_os],
 212         [freebsd*], [NO_NUMA=1]
 213 )
 214
 215 # Configuration options, which will be installed in the config.h
 216 AH_TEMPLATE([LTTNG_UST_HAVE_EFFICIENT_UNALIGNED_ACCESS], [Use efficient unaligned access.])
 217 AH_TEMPLATE([LTTNG_UST_HAVE_SDT_INTEGRATION], [SystemTap integration via sdt.h])
 218 AH_TEMPLATE([LTTNG_UST_HAVE_PERF_EVENT], [Perf event integration via perf_event.h])
 219
 220 # Checks for libraries.
 221 AC_CHECK_LIB([dl], [dlopen], [
 222         libdl_name=dl
 223         DL_LIBS="-ldl"
 224 ], [
 225         #libdl not found, check for dlopen in libc.
 226         AC_CHECK_LIB([c], [dlopen], [
 227                 libdl_name=c
 228                 DL_LIBS="-lc"
 229         ], [
 230                 AC_MSG_ERROR([Cannot find dlopen in libdl nor libc. Use [LDFLAGS]=-Ldir to specify their location.])
 231         ])
 232 ])
 233 AC_SUBST(DL_LIBS)
 234
 235 # Check if libdl has dlmopen support.
 236 AH_TEMPLATE([HAVE_DLMOPEN], ["Define to 1 if dlmopen is available."])
 237 AC_CHECK_LIB([$libdl_name], [dlmopen],
 238         [AC_DEFINE([HAVE_DLMOPEN], [1])]
 239 )
 240
 241 # Check for dlfcn.h
 242 AC_CHECK_HEADER([dlfcn.h])
 243 AS_IF([test "x${ac_cv_header_dlfcn_h}" = "xyes"], [
 244         AC_CHECK_DECLS([RTLD_DI_LINKMAP], [], [], [
 245                 #include <dlfcn.h>
 246         ])
 247 ], [
 248         ac_cv_have_decl_RTLD_DI_LINKMAP="no"
 249 ])
 250
 251 AM_CONDITIONAL([HAVE_DLINFO], [test "x${ac_cv_have_decl_RTLD_DI_LINKMAP}" = "xyes"])
 252
 253 # URCU
 254
 255 AC_MSG_CHECKING([DEFINE_URCU_TLS_INIT()])
 256 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 257         #include <urcu/tls-compat.h>
 258         DEFINE_URCU_TLS_INIT(int, a, 1);
 259 ]])], [
 260         AC_MSG_RESULT([yes])
 261 ], [
 262         AC_MSG_RESULT([no])
 263         AC_MSG_ERROR([Please upgrade your version of liburcu to 0.12.0 or better])
 264 ])
 265
 266 # urcu - check if we just find the headers it out of the box.
 267 AC_CHECK_HEADERS([urcu-bp.h], [], [AC_MSG_ERROR([Cannot find [URCU] headers (urcu-bp.h). Use [CPPFLAGS]=-Idir to specify their location.
 268 This error can also occur when the liburcu package's configure script has not been run.])])
 269
 270 # urcu-cds - check that URCU Concurrent Data Structure lib is available to compilation
 271 # Part of Userspace RCU library 0.7.2 or better.
 272 AC_CHECK_LIB([urcu-cds], [_cds_lfht_new], [], [AC_MSG_ERROR([Cannot find
 273 liburcu-cds lib, part of Userspace RCU 0.7 or better. Use [LDFLAGS]=-Ldir to specify its location.])])
 274
 275 AC_MSG_CHECKING([caa_likely()])
 276 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 277         #include <urcu/compiler.h>
 278         void fct(void)
 279         {
 280                 if (caa_likely(1)) {
 281                 }
 282         }
 283 ]])], [
 284         AC_MSG_RESULT([yes])
 285 ], [
 286         AC_MSG_RESULT([no])
 287         AC_MSG_ERROR([Please upgrade your version of liburcu to 0.6.6 or better])
 288 ])
 289
 290 # urcu - check that URCU lib is available to compilation
 291 AC_CHECK_LIB([urcu-bp], [urcu_bp_synchronize_rcu], [], [AC_MSG_ERROR([Cannot find liburcu-bp 0.11 or newer. Use [LDFLAGS]=-Ldir to specify its location.])])
 292
 293 # urcu - check that URCU lib is at least version 0.11
 294 AC_CHECK_LIB([urcu-bp], [urcu_bp_call_rcu], [], [AC_MSG_ERROR([liburcu 0.11 or newer is needed, please update your version or use [LDFLAGS]=-Ldir to specify the right location.])])
 295
 296 # numa.h integration
 297 AS_IF([test "x$NO_NUMA" = "x1"],[
 298       AS_IF([test "x$enable_numa" = "x" ], [enable_numa=no])
 299 ])
 300
 301 AC_ARG_ENABLE([numa], [
 302 AS_HELP_STRING([--disable-numa], [disable NUMA support])
 303 ], [
 304         enable_numa=$enableval
 305 ], [
 306         enable_numa=yes
 307 ])
 308
 309 AS_IF([test "x$enable_numa" = "xyes"], [
 310         # numa - check that numa lib is available
 311         AC_CHECK_LIB([numa], [numa_available], [],
 312 [AC_MSG_ERROR([libnuma is not available. Please either install it (e.g. libnuma-dev) or use [LDFLAGS]=-Ldir to specify the right location, or use --disable-numa configure argument to disable NUMA support.])])
 313         have_libnuma=yes
 314 ])
 315 AM_CONDITIONAL([HAVE_LIBNUMA], [test "x$have_libnuma" = "xyes"])
 316
 317 # optional linux/perf_event.h
 318 AC_CHECK_HEADERS([linux/perf_event.h], [have_perf_event=yes], [])
 319
 320 # Perf event counters are supported on all architectures supported by
 321 # perf, using the read system call as fallback.
 322 AM_CONDITIONAL([HAVE_PERF_EVENT], [test "x$have_perf_event" = "xyes"])
 323
 324 AS_IF([test "x$have_perf_event" = "xyes"], [
 325         AC_DEFINE([LTTNG_UST_HAVE_PERF_EVENT], [1])
 326 ])
 327
 328 AS_IF([test "x$NO_UNALIGNED_ACCESS" = "x"], [
 329         AC_DEFINE([LTTNG_UST_HAVE_EFFICIENT_UNALIGNED_ACCESS], [1])
 330 ])
 331
 332 # Check for JNI header files if requested
 333 AC_ARG_ENABLE([jni-interface], [
 334 AS_HELP_STRING([--enable-jni-interface], [build JNI interface between C and Java. Needs Java include files [default=no]])
 335 ], [
 336         jni_interface=$enableval
 337 ], [
 338         jni_interface=no
 339 ])
 340
 341 AM_CONDITIONAL([BUILD_JNI_INTERFACE], [test "x$jni_interface" = "xyes"])
 342
 343
 344 AC_ARG_ENABLE([java-agent-jul], [
 345 AS_HELP_STRING([--enable-java-agent-jul], [build the LTTng UST Java agent with JUL support [default=no]])
 346 ], [
 347         java_agent_jul=$enableval
 348 ], [
 349         java_agent_jul=no
 350 ])
 351
 352 AC_ARG_ENABLE([java-agent-log4j], [
 353 AS_HELP_STRING([--enable-java-agent-log4j], [build the LTTng UST Java agent with Log4j support [default=no]])
 354 ], [
 355         java_agent_log4j=$enableval
 356 ], [
 357         java_agent_log4j=no
 358 ])
 359
 360 AC_ARG_ENABLE([java-agent-all], [
 361 AS_HELP_STRING([--enable-java-agent-all], [build the LTTng UST Java agent with all supported backends [default=no]])
 362 ], [
 363         java_agent_jul=$enableval
 364         java_agent_log4j=$enableval
 365 ], [:])
 366
 367 AM_CONDITIONAL([BUILD_JAVA_AGENT], [test "x$java_agent_jul" = "xyes" || test "x$java_agent_log4j" = "xyes"])
 368 AM_CONDITIONAL([BUILD_JAVA_AGENT_WITH_JUL], [test "x$java_agent_jul" = "xyes"])
 369 AM_CONDITIONAL([BUILD_JAVA_AGENT_WITH_LOG4J], [test "x$java_agent_log4j" = "xyes"])
 370
 371 AS_IF([test "x$jni_interface" = "xyes" || test "x$java_agent_jul" = "xyes" || test "x$java_agent_log4j" = "xyes"], [
 372         AX_JAVA_OPTIONS
 373         AX_PROG_JAVAC
 374         AX_PROG_JAVA
 375         AX_PROG_JAR
 376         AC_ARG_VAR([CLASSPATH], [Java class path])
 377
 378         AX_JNI_INCLUDE_DIR
 379         for JNI_INCLUDE_DIR in $JNI_INCLUDE_DIRS
 380         do
 381                 JNI_CPPFLAGS="$JNI_CPPFLAGS -I$JNI_INCLUDE_DIR"
 382         done
 383
 384         saved_CPPFLAGS="$CPPFLAGS"
 385         CPPFLAGS="$CPPFLAGS $JNI_CPPFLAGS"
 386         AX_PROG_JAVAH
 387         CPPFLAGS="$saved_CPPFLAGS"
 388 ])
 389
 390 AM_CONDITIONAL([HAVE_JAVAH], [test "x$JAVAH" != "x"])
 391
 392 AS_IF([test "x$java_agent_log4j" = "xyes"], [
 393         AX_CHECK_CLASSPATH
 394         AX_CHECK_CLASS([org.apache.log4j.Logger])
 395         AS_IF([test "x$ac_cv_class_org_apache_log4j_Logger" = "xno"], [
 396                 AC_MSG_ERROR([The UST Java agent support for log4j was requested but the Log4j classes were not found. Please specify the location of the Log4j jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/log4j.jar"])
 397         ])
 398 ])
 399
 400 # Option to build the python agent
 401 AC_ARG_ENABLE([python-agent], [
 402 AS_HELP_STRING([--enable-python-agent], [build the LTTng UST Python agent [default=no]])
 403 ], [
 404         python_agent=$enableval
 405 ], [:])
 406 AM_CONDITIONAL([BUILD_PYTHON_AGENT], [test "x$python_agent" = "xyes"])
 407 AS_IF([test "x$python_agent" = "xyes"], [
 408         AM_PATH_PYTHON([2.7])
 409 ])
 410
 411 # sdt.h integration
 412 AC_ARG_WITH([sdt], [
 413 AS_HELP_STRING([--with-sdt], [provide SystemTap integration via sdt.h [default=no]])
 414 ], [
 415         with_sdt=$withval
 416 ], [
 417         with_sdt="no"
 418 ])
 419
 420 AS_IF([test "x$with_sdt" = "xyes"], [
 421         AC_MSG_CHECKING([STAP_PROBEV()])
 422         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 423                 #define SDT_USE_VARIADIC
 424                 #include <sys/sdt.h>
 425                 void fct(void)
 426                 {
 427                         STAP_PROBEV(provider,name,1,2,3,4,5,6,7,8,9,10);
 428                 }
 429         ]])], [
 430                 AC_MSG_RESULT([yes])
 431                 AC_DEFINE([LTTNG_UST_HAVE_SDT_INTEGRATION], [1])
 432         ], [
 433                 AC_MSG_RESULT([no])
 434                 AC_MSG_ERROR([The sdt.h integration was requested but the STAP_PROBEV define cannot be used. Make sure it is installed, and up to date, or use CPPFLAGS=-I/path/ to specify a non-standard path to sys/sdt.h])
 435         ])
 436 ])
 437
 438 AC_ARG_WITH([lttng-system-rundir], [
 439 AS_HELP_STRING([--with-lttng-system-rundir], [Location of the system directory where LTTng-UST expects the system-wide lttng-sessiond runtime files. The default is "/var/run/lttng".]),
 440 ], [
 441         lttng_system_rundir="$withval"
 442 ], [
 443         lttng_system_rundir="/var/run/lttng"
 444 ])
 445 AC_DEFINE_UNQUOTED([LTTNG_SYSTEM_RUNDIR], ["$lttng_system_rundir"],
 446                 [LTTng system runtime directory])
 447
 448 AC_CHECK_PROG([BUILD_GEN_TP_EXAMPLES], [python], ["yes"])
 449 AM_CONDITIONAL([BUILD_GEN_TP_EXAMPLES], [test "x$BUILD_GEN_TP_EXAMPLES" = "xyes"])
 450
 451 # Enable building examples
 452 AC_ARG_ENABLE(
 453         examples,
 454         AS_HELP_STRING(
 455                 [--disable-examples],
 456                 [Do not build and install examples]
 457         ),
 458         [enable_examples=$enableval],
 459         [enable_examples=yes]
 460 )
 461
 462 AM_CONDITIONAL([ENABLE_EXAMPLES], [test "x$enable_examples" != "xno"])
 463
 464 # Set $IN_GIT_REPO if we're in the Git repository; the `bootstrap` file
 465 # is not distributed in tarballs.
 466 AS_IF([test -f "$srcdir/bootstrap"], [in_git_repo=yes], [in_git_repo=no])
 467 AM_CONDITIONAL([IN_GIT_REPO], [test "x$in_git_repo" = "xyes"])
 468
 469 # Enable building man pages (user's intention).
 470 AC_ARG_ENABLE(
 471         man-pages,
 472         AS_HELP_STRING(
 473                 [--disable-man-pages],
 474                 [Do not build and install man pages (already built in a distributed tarball)]
 475         ),
 476         [man_pages_opt=$enableval],
 477         [man_pages_opt=yes]
 478 )
 479
 480 # Check for asciidoc and xmlto if we enabled building the man pages.
 481 have_asciidoc_xmlto=no
 482 warn_prebuilt_man_pages=no
 483
 484 AS_IF([test "x$man_pages_opt" = "xyes"], [
 485         AC_PATH_PROG([ASCIIDOC], [asciidoc], [no])
 486         AC_PATH_PROG([XMLTO], [xmlto], [no])
 487
 488         AS_IF([test "x$ASCIIDOC" = "xno" || test "x$XMLTO" = "xno"], [
 489                 AS_IF([test "x$in_git_repo" = "xyes"], [
 490                         # This is an error because we're in the Git repo, which
 491                         # means the man pages are not already generated for us,
 492                         # thus asciidoc/xmlto are required because we were asked
 493                         # to build the man pages.
 494                         AC_MSG_ERROR([
 495 Both asciidoc and xmlto are needed to build the LTTng-UST man pages. Use
 496 --disable-man-pages to disable building the man pages, in which case
 497 they will not be installed.
 498                         ])
 499                 ], [
 500                         # Only warn here: since we're in the tarball, the man
 501                         # pages should already be generated at this point, thus
 502                         # asciidoc/xmlto are not strictly required.
 503                         warn_prebuilt_man_pages=yes
 504                 ])
 505         ], [
 506                 have_asciidoc_xmlto=yes
 507         ])
 508 ])
 509
 510 # Export man page build condition: build the man pages if the user
 511 # asked for it, and if the tools are available.
 512 AM_CONDITIONAL([MAN_PAGES_OPT], [test "x$man_pages_opt" != "xno"])
 513 AM_CONDITIONAL([HAVE_ASCIIDOC_XMLTO], [test "x$have_asciidoc_xmlto" = "xyes"])
 514
 515 # Default values
 516 AC_DEFUN([_AC_DEFINE_AND_SUBST], [
 517         AC_DEFINE_UNQUOTED([CONFIG_$1], [$2], [$1])
 518         $1="$2"
 519         AC_SUBST([$1])
 520 ])
 521
 522 _AC_DEFINE_AND_SUBST([LTTNG_UST_DEFAULT_CONSTRUCTOR_TIMEOUT_MS], [3000])
 523
 524 AM_CFLAGS="-Wall $PTHREAD_CFLAGS"
 525 AC_SUBST(AM_CFLAGS)
 526
 527 # The order in which the include folders are searched is important.
 528 # The top_builddir should always be searched first in the event that a build
 529 # time generated file is included.
 530 AM_CPPFLAGS="-I\$(top_builddir)/include -I\$(top_srcdir)/include -include config.h"
 531 AC_SUBST(AM_CPPFLAGS)
 532
 533 AC_SUBST(JNI_CPPFLAGS)
 534
 535 AC_CONFIG_FILES([
 536         Makefile
 537         doc/Makefile
 538         doc/examples/Makefile
 539         doc/man/Makefile
 540         include/Makefile
 541         include/lttng/ust-version.h
 542         snprintf/Makefile
 543         libringbuffer/Makefile
 544         liblttng-ust-comm/Makefile
 545         liblttng-ust/Makefile
 546         liblttng-ust-ctl/Makefile
 547         liblttng-ust-fork/Makefile
 548         liblttng-ust-dl/Makefile
 549         liblttng-ust-fd/Makefile
 550         liblttng-ust-java/Makefile
 551         liblttng-ust-java-agent/Makefile
 552         liblttng-ust-java-agent/java/Makefile
 553         liblttng-ust-java-agent/java/lttng-ust-agent-all/Makefile
 554         liblttng-ust-java-agent/java/lttng-ust-agent-common/Makefile
 555         liblttng-ust-java-agent/java/lttng-ust-agent-jul/Makefile
 556         liblttng-ust-java-agent/java/lttng-ust-agent-log4j/Makefile
 557         liblttng-ust-java-agent/jni/Makefile
 558         liblttng-ust-java-agent/jni/common/Makefile
 559         liblttng-ust-java-agent/jni/jul/Makefile
 560         liblttng-ust-java-agent/jni/log4j/Makefile
 561         liblttng-ust-libc-wrapper/Makefile
 562         liblttng-ust-cyg-profile/Makefile
 563         liblttng-ust-python-agent/Makefile
 564         python-lttngust/Makefile
 565         python-lttngust/setup.py
 566         python-lttngust/lttngust/__init__.py
 567         tools/Makefile
 568         tests/Makefile
 569         tests/ctf-types/Makefile
 570         tests/hello/Makefile
 571         tests/hello-many/Makefile
 572         tests/hello.cxx/Makefile
 573         tests/same_line_tracepoint/Makefile
 574         tests/snprintf/Makefile
 575         tests/ust-elf/Makefile
 576         tests/benchmark/Makefile
 577         tests/pthread_name/Makefile
 578         tests/utils/Makefile
 579         tests/test-app-ctx/Makefile
 580         tests/gcc-weak-hidden/Makefile
 581         lttng-ust.pc
 582         lttng-ust-ctl.pc
 583 ])
 584
 585 # Create link for python agent for the VPATH guru.
 586 AC_CONFIG_LINKS([
 587         python-lttngust/lttngust/agent.py:python-lttngust/lttngust/agent.py
 588         python-lttngust/lttngust/cmd.py:python-lttngust/lttngust/cmd.py
 589         python-lttngust/lttngust/compat.py:python-lttngust/lttngust/compat.py
 590         python-lttngust/lttngust/debug.py:python-lttngust/lttngust/debug.py
 591         python-lttngust/lttngust/loghandler.py:python-lttngust/lttngust/loghandler.py
 592 ])
 593
 594 AC_CONFIG_FILES([tests/ust-elf/test_ust_elf],[chmod +x tests/ust-elf/test_ust_elf])
 595
 596 AC_OUTPUT
 597
 598
 599 #
 600 # Mini-report on what will be built.
 601 #
 602
 603 PPRINT_INIT
 604 PPRINT_SET_INDENT(1)
 605 PPRINT_SET_TS(38)
 606
 607 AS_ECHO
 608 AS_ECHO("${PPRINT_COLOR_BLDBLU}LTTng-ust $PACKAGE_VERSION \"V_NAME\"$PPRINT_COLOR_RST")
 609 AS_ECHO
 610
 611 AS_ECHO("V_DESC")
 612
 613 AS_ECHO
 614 PPRINT_SUBTITLE([System])
 615
 616 PPRINT_PROP_STRING([Target architecture], $host_cpu)
 617
 618 test "x$NO_UNALIGNED_ACCESS" != "x1" && value=1 || value=0
 619 PPRINT_PROP_BOOL([Efficient unaligned memory access], $value)
 620
 621 AS_IF([test "x$UNSUPPORTED_ARCH" = "x1"],[
 622        PPRINT_WARN([Your architecture ($host_cpu) is unsupported, using safe default of no unaligned access.])
 623 ])
 624
 625 AS_ECHO
 626 PPRINT_SUBTITLE([Features])
 627 PPRINT_SET_INDENT(1)
 628
 629 test "x$with_sdt" = "xyes" && value=1 || value=0
 630 PPRINT_PROP_BOOL_CUSTOM([sdt.h integration], $value, [use --with-sdt])
 631
 632 test "x$java_agent_jul" = xyes && value=1 || value=0
 633 PPRINT_PROP_BOOL_CUSTOM([Java agent (JUL support)], $value, [use --enable-java-agent-jul])
 634
 635 test "x$java_agent_log4j" = xyes && value=1 || value=0
 636 PPRINT_PROP_BOOL_CUSTOM([Java agent (Log4j support)], $value, [use --enable-java-agent-log4j])
 637
 638 test "x$jni_interface" = xyes && value=1 || value=0
 639 PPRINT_PROP_BOOL_CUSTOM([JNI interface (JNI)], $value, [use --enable-jni-interface])
 640
 641 test "x$python_agent" = xyes && value=1 || value=0
 642 PPRINT_PROP_BOOL_CUSTOM([Python agent], $value, [use --enable-python-agent])
 643
 644 test "x$have_perf_event" = "xyes" && value=1 || value=0
 645 PPRINT_PROP_BOOL_CUSTOM([Perf event integration], $value)
 646
 647 test "x$enable_numa" = xyes && value=1 || value=0
 648 PPRINT_PROP_BOOL([NUMA], $value)
 649
 650 AS_ECHO
 651 PPRINT_SET_INDENT(0)
 652
 653 test "x$enable_examples" = xyes && value=1 || value=0
 654 PPRINT_PROP_BOOL([Build and install examples], $value, $PPRINT_COLOR_SUBTITLE)
 655
 656 # man pages build enabled/disabled
 657 m4_pushdef([build_man_pages_msg], [Build and install man pages])
 658
 659 AS_IF([test "x$man_pages_opt" != "xno"], [
 660         AS_IF([test "x$in_git_repo" = "xyes"], [
 661                 PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
 662         ], [
 663                 AS_IF([test "x$have_asciidoc_xmlto" = "xyes"], [
 664                         PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
 665                 ], [
 666                         PPRINT_PROP_STRING([build_man_pages_msg],
 667                                 [${PPRINT_COLOR_BLDGRN}yes (already built)],
 668                                 $PPRINT_COLOR_SUBTITLE)
 669                 ])
 670         ])
 671 ], [
 672         PPRINT_PROP_BOOL([build_man_pages_msg], 0, $PPRINT_COLOR_SUBTITLE)
 673 ])
 674
 675 m4_popdef([build_man_pages_msg])
 676
 677 PPRINT_SET_INDENT(1)
 678
 679 report_bindir="`eval eval echo $bindir`"
 680 report_libdir="`eval eval echo $libdir`"
 681
 682 # Print the bindir and libdir this `make install' will install into.
 683 AS_ECHO
 684 PPRINT_SUBTITLE([Install directories])
 685 PPRINT_PROP_STRING([Binaries], [$report_bindir])
 686 PPRINT_PROP_STRING([Libraries], [$report_libdir])
 687
 688 AS_ECHO
 689 PPRINT_SUBTITLE([System directories])
 690
 691 PPRINT_PROP_STRING([lttng-sessiond rundir], [$lttng_system_rundir])
 692
 693 PPRINT_SET_INDENT(0)
 694
 695 AS_IF([test "x$warn_prebuilt_man_pages" = "xyes" ], [
 696         AS_ECHO
 697         PPRINT_WARN([Both asciidoc and xmlto are needed to build the LTTng-UST man pages.
 698
 699 Note that the man pages are already built in this distribution tarball,
 700 therefore asciidoc and xmlto are only needed if you intend to modify
 701 their sources.
 702
 703 Use --disable-man-pages to completely disable building and installing
 704 the man pages.])
 705 ])