configure.ac

   1 AC_PREREQ([2.64])
   2 AC_INIT([lttng-tools],[2.6.2],[jeremie.galarneau@efficios.com],[],[https://lttng.org])
   3 AC_CONFIG_AUX_DIR([config])
   4 AC_CANONICAL_TARGET
   5 AC_CANONICAL_HOST
   6 AC_CONFIG_MACRO_DIR([config])
   7 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip])
   8 AM_MAINTAINER_MODE([enable])
   9 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  10
  11 # Compute minor/major/patchlevel version numbers
  12 AC_PROG_SED
  13 major_version=$(echo AC_PACKAGE_VERSION | sed 's/^\([[0-9]]\)*\.[[0-9]]*\.[[0-9]]*.*$/\1/')
  14 minor_version=$(echo AC_PACKAGE_VERSION | sed 's/^[[0-9]]*\.\([[0-9]]*\)\.[[0-9]]*.*$/\1/')
  15 patchlevel_version=$(echo AC_PACKAGE_VERSION | sed 's/^[[0-9]]*\.[[0-9]]*\.\([[0-9]]*\).*$/\1/')
  16 AC_SUBST([MAJOR_VERSION], [$major_version])
  17 AC_SUBST([MINOR_VERSION], [$minor_version])
  18 AC_SUBST([PATCHLEVEL_VERSION], [$patchlevel_version])
  19 AC_DEFINE_UNQUOTED([VERSION_MAJOR], $major_version, [LTTng-Tools major version number])
  20 AC_DEFINE_UNQUOTED([VERSION_MINOR], $minor_version, [LTTng-Tools minor version number])
  21 AC_DEFINE_UNQUOTED([VERSION_PATCHLEVEL], $patchlevel_version, [LTTng-Tools patchlevel version number])
  22
  23 version_name="Gaia"
  24 version_description="From Benelux brewery in Montreal, the Gaia is a witbier with a cloudy light amber ale color. Aroma of coriander with floral hay notes is enchanting. Taste is also dominated by the very floral coriander note and some medium sweet malt notes."
  25
  26 AC_DEFINE_UNQUOTED([VERSION_NAME], ["$version_name"], "")
  27 AC_DEFINE_UNQUOTED([VERSION_DESCRIPTION], ["$version_description"], "")
  28
  29 AC_CONFIG_HEADERS([include/config.h])
  30
  31 AC_PROG_GREP
  32 # libtool link_all_deplibs fixup. See http://bugs.lttng.org/issues/321.
  33 AC_ARG_ENABLE(libtool-linkdep-fixup,
  34         AS_HELP_STRING([--disable-libtool-linkdep-fixup],
  35                         [disable the libtool fixup for linking all dependent libraries (link_all_deplibs)]),
  36         libtool_fixup=$enableval,
  37         libtool_fixup=yes)
  38
  39 AS_IF([test "x$libtool_fixup" = "xyes"],
  40             [
  41             libtool_m4="$srcdir/config/libtool.m4"
  42             libtool_flag_pattern=".*link_all_deplibs\s*,\s*\$1\s*)"
  43             AC_MSG_CHECKING([for occurence(s) of link_all_deplibs = no in $libtool_m4])
  44             libtool_flag_pattern_count=$(grep -c "$libtool_flag_pattern\s*=\s*no" $libtool_m4)
  45             AS_IF([test $libtool_flag_pattern_count -ne 0],
  46             [
  47                   AC_MSG_RESULT([$libtool_flag_pattern_count])
  48                   AC_MSG_WARN([the detected libtool will not link all dependencies, forcing link_all_deplibs = unknown])
  49                   sed -i "s/\($libtool_flag_pattern\)\s*=\s*no/\1=unknown/g" $libtool_m4
  50                   ],
  51                   [
  52                   AC_MSG_RESULT([none])
  53                   ])
  54             ])
  55
  56 AM_CONDITIONAL([NO_SHARED], [test x$enable_shared = xno])
  57
  58 AC_CHECK_HEADERS([ \
  59         sys/types.h unistd.h fcntl.h string.h pthread.h limits.h \
  60         signal.h stdlib.h sys/un.h sys/socket.h stdlib.h stdio.h \
  61         getopt.h sys/ipc.h sys/shm.h popt.h grp.h \
  62 ])
  63
  64 # Babeltrace viewer check
  65 AC_ARG_WITH([babeltrace-bin],
  66         AS_HELP_STRING([--with-babeltrace-bin],
  67         [Location of the babeltrace viewer executable (including the filename)]),
  68         [BABELTRACE_BIN="$withval"],
  69         [BABELTRACE_BIN=''])
  70 AC_SUBST([BABELTRACE_BIN])
  71
  72 # lttv-gui
  73 AC_ARG_WITH([lttv-gui-bin],
  74         AS_HELP_STRING([--with-lttv-gui-bin],
  75    [Location of the lttv GUI viewer executable (including the filename)]),
  76    [LTTV_GUI_BIN="$withval"],
  77    [LTTV_GUI_BIN=''])
  78 AC_SUBST([LTTV_GUI_BIN])
  79
  80 AC_ARG_WITH([consumerd32-bin],
  81         AS_HELP_STRING([--with-consumerd32-bin],
  82         [Location of the 32-bit consumerd executable (including the filename)]),
  83         [CONSUMERD32_BIN="$withval"],
  84         [CONSUMERD32_BIN=''])
  85 AC_SUBST([CONSUMERD32_BIN])
  86
  87 AC_ARG_WITH([consumerd64-bin],
  88         AS_HELP_STRING([--with-consumerd64-bin],
  89         [Location of the 64-bit consumerd executable (including the filename)]),
  90         [CONSUMERD64_BIN="$withval"],
  91         [CONSUMERD64_BIN=''])
  92 AC_SUBST([CONSUMERD64_BIN])
  93
  94 AC_ARG_WITH([consumerd32-libdir],
  95         AS_HELP_STRING([--with-consumerd32-libdir],
  96         [Directory containing the 32-bit consumerd libraries]),
  97         [CONSUMERD32_LIBDIR="$withval"],
  98         [CONSUMERD32_LIBDIR=''])
  99 AC_SUBST([CONSUMERD32_LIBDIR])
 100
 101 AC_ARG_WITH([consumerd64-libdir],
 102         AS_HELP_STRING([--with-consumerd64-libdir],
 103         [Directory containing the 64-bit consumerd libraries]),
 104         [CONSUMERD64_LIBDIR="$withval"],
 105         [CONSUMERD64_LIBDIR=''])
 106 AC_SUBST([CONSUMERD64_LIBDIR])
 107
 108 AC_ARG_WITH([sessiond-bin],
 109         AS_HELP_STRING([--with-sessiond-bin],
 110         [Location of the sessiond executable (including the filename)]),
 111         [SESSIOND_BIN="$withval"],
 112         [SESSIOND_BIN=''])
 113 AC_SUBST([SESSIOND_BIN])
 114
 115 AC_ARG_WITH([lttng-system-rundir],
 116         AS_HELP_STRING([--with-lttng-system-rundir],
 117         [Location of the system directory where the system-wide lttng-sessiond runtime files are kept. The default is "/var/run/lttng".]),
 118         [LTTNG_SYSTEM_RUNDIR="$withval"],
 119         [LTTNG_SYSTEM_RUNDIR="/var/run/lttng"])
 120 AC_SUBST([LTTNG_SYSTEM_RUNDIR])
 121
 122 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_BIN], "$CONSUMERD32_BIN", [Location of the 32-bit consumerd executable.])
 123 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_BIN], "$CONSUMERD64_BIN", [Location of the 64-bit consumerd executable])
 124 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_LIBDIR], "$CONSUMERD32_LIBDIR", [Search for consumerd 32-bit libraries in this location.])
 125 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_LIBDIR], "$CONSUMERD64_LIBDIR", [Search for consumerd 64-bit libraries in this location.])
 126 AC_DEFINE_UNQUOTED([CONFIG_BABELTRACE_BIN], "$BABELTRACE_BIN", [Location of the babeltrace viewer executable.])
 127 AC_DEFINE_UNQUOTED([CONFIG_LTTV_GUI_BIN], "$LTTV_GUI_BIN", [Location of the lttv GUI viewer executable.])
 128 AC_DEFINE_UNQUOTED([CONFIG_SESSIOND_BIN], "$SESSIOND_BIN", [Location of the sessiond executable.])
 129 AC_DEFINE_UNQUOTED([CONFIG_LTTNG_SYSTEM_RUNDIR], ["$LTTNG_SYSTEM_RUNDIR"], [LTTng system runtime directory])
 130
 131 if test "x$prefix" = "xNONE"; then
 132         prefix=$ac_default_prefix
 133 fi
 134 CONFDIR=`eval echo $sysconfdir`
 135 AC_SUBST(CONFDIR)
 136 AC_DEFINE_UNQUOTED([CONFIG_LTTNG_SYSTEM_CONFIGDIR],"$CONFDIR", [LTTng system configuration directory.])
 137
 138 AC_DEFINE_DIR([CONFIG_LTTNG_SYSTEM_DATADIR],[datadir], [LTTng system data directory.])
 139
 140 #
 141 # Check for pthread
 142 AC_CHECK_LIB([pthread], [pthread_create], [],
 143         [AC_MSG_ERROR([Cannot find libpthread. Use LDFLAGS=-Ldir to specify its location.])]
 144 )
 145
 146 # Check libpopt
 147 PKG_CHECK_MODULES([POPT], [popt],
 148         [LIBS="$LIBS $POPT_LIBS"],
 149         [
 150                 AC_MSG_WARN([pkg-config was unable to find a valid .pc for libpopt. Set PKG_CONFIG_PATH to specify the pkgconfig configuration file location])
 151                 AC_MSG_WARN([Finding libpopt without pkg-config.])
 152                 AC_CHECK_LIB([popt],
 153                         [poptGetContext],
 154                         [],
 155                         [
 156                                  AC_MSG_ERROR([Cannot find libpopt. Either set PKG_CONFIG_PATH to the configuration file location or use LDFLAGS=-Ldir to specify the library location])
 157                         ]
 158                 )
 159         ]
 160 )
 161
 162 AM_PATH_XML2(2.7.6, true, AC_MSG_ERROR(No supported version of libxml2 found.))
 163
 164 # Check for libuuid
 165 PKG_CHECK_MODULES([UUID], [uuid],
 166 [
 167         LIBS="$LIBS $UUID_LIBS"
 168         AC_DEFINE_UNQUOTED([LTTNG_HAVE_LIBUUID], 1, [Has libuuid support.])
 169         have_libuuid=yes
 170 ],
 171 [
 172         AC_MSG_WARN([pkg-config was unable to find a valid .pc for libuuid. Set PKG_CONFIG_PATH to specify the pkgconfig configuration file location])
 173         AC_MSG_WARN([Finding libuuid without pkg-config.])
 174         AC_CHECK_LIB([uuid],
 175                 [uuid_generate],
 176                 [
 177                         AC_DEFINE_UNQUOTED([LTTNG_HAVE_LIBUUID], 1, [Has libuuid support.])
 178                         have_libuuid=yes
 179                 ],
 180                 [
 181                         # libuuid not found, check for uuid_create in libc.
 182                         AC_CHECK_LIB([c],
 183                                 [uuid_create],
 184                                 [
 185                                         AC_DEFINE_UNQUOTED([LTTNG_HAVE_LIBC_UUID], 1, [Has libc uuid support.])
 186                                         have_libc_uuid=yes
 187                                 ],
 188                                 [
 189                                         AC_MSG_ERROR([Cannot find libuuid uuid_generate nor libc uuid_create. Either set PKG_CONFIG_PATH to the configuration file location or use LDFLAGS=-Ldir to specify the library location])
 190                                 ]
 191                         )
 192                 ]
 193         )
 194 ])
 195 AM_CONDITIONAL([LTTNG_BUILD_WITH_LIBUUID], [test "x$have_libuuid" = "xyes"])
 196 AM_CONDITIONAL([LTTNG_BUILD_WITH_LIBC_UUID], [test "x$have_libc_uuid" = "xyes"])
 197
 198 # URCU library version needed or newer
 199 m4_define([WRONG_LIBURCU_MSG], [Userspace RCU (liburcu) >= 0.8.0 is needed])
 200
 201 # Check liburcu needed function calls
 202 AC_CHECK_DECL([cds_list_add], [],
 203         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/list.h>]])
 204 AC_CHECK_DECL([cds_wfcq_init], [],
 205         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/wfcqueue.h>]])
 206 AC_CHECK_DECL([cds_wfcq_dequeue_blocking], [],
 207         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/wfcqueue.h>]])
 208 AC_CHECK_DECL([futex_async], [],
 209         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/futex.h>]])
 210 AC_CHECK_DECL([rcu_thread_offline], [],
 211         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]])
 212 AC_CHECK_DECL([rcu_thread_online], [],
 213         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]])
 214 AC_CHECK_DECL([caa_likely], [],
 215         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]])
 216 AC_CHECK_LIB([urcu-cds], [_cds_lfht_new], [],
 217         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])])
 218
 219 #Function added in urcu 0.7.0
 220 AC_CHECK_DECL([cmm_smp_mb__before_uatomic_or], [],
 221         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]]
 222 )
 223
 224 # Check kmod library
 225 AC_ARG_WITH(kmod-prefix,
 226   AS_HELP_STRING([--with-kmod-prefix=PATH],
 227                 [Specify the installation prefix of the kmod library.
 228                 Headers must be in PATH/include; libraries in PATH/lib.]),
 229                 [
 230                         CPPFLAGS="$CPPFLAGS -I${withval}/include"
 231                         LDFLAGS="$LDFLAGS -L${withval}/lib64 -L${withval}/lib"
 232                 ])
 233
 234 AC_ARG_ENABLE(kmod,
 235         AS_HELP_STRING([--disable-kmod],[build without kmod support]),
 236         kmod_support=zz$enableval, kmod_support=yes)
 237
 238 AS_IF([test "x$kmod_support" = "xyes"], [
 239         AC_CHECK_LIB([kmod], [kmod_module_probe_insert_module],
 240                 [
 241                         AC_DEFINE([HAVE_KMOD], [1], [has kmod support])
 242                         LIBS="$LIBS -lkmod"
 243                         kmod_found=yes
 244                 ],
 245                 kmod_found=no
 246         )
 247 ])
 248 AM_CONDITIONAL([HAVE_KMOD], [test "x$kmod_found" = xyes])
 249
 250 AC_ARG_WITH(lttng-ust-prefix,
 251   AS_HELP_STRING([--with-lttng-ust-prefix=PATH],
 252                  [Specify the installation prefix of the lttng-ust library.
 253                   Headers must be in PATH/include; libraries in PATH/lib.]),
 254                   [
 255                     CPPFLAGS="$CPPFLAGS -I${withval}/include"
 256                     LDFLAGS="$LDFLAGS -L${withval}/lib64 -L${withval}/lib"
 257                   ])
 258
 259 # Check liblttng-ust-ctl library
 260 AC_ARG_ENABLE(lttng-ust,
 261         AS_HELP_STRING([--disable-lttng-ust],[build without LTTng-UST (Userspace Tracing) support]),
 262         lttng_ust_support=$enableval, lttng_ust_support=yes)
 263
 264 AS_IF([test "x$lttng_ust_support" = "xyes"], [
 265         AC_CHECK_LIB([lttng-ust-ctl], [ustctl_recv_channel_from_consumer],
 266                 [
 267                         AC_DEFINE([HAVE_LIBLTTNG_UST_CTL], [1], [has LTTng-UST control support])
 268                         lttng_ust_ctl_found=yes
 269                 ],
 270                 [AC_MSG_ERROR([Cannot find LTTng-UST >= 2.2.x. Use --with-lttng-ust-prefix=PREFIX to specify its location, or specify --disable-lttng-ust to build lttng-tools without LTTng-UST support.])],
 271                 [-lurcu-common -lurcu-bp -lurcu-cds -lrt]
 272         )
 273 ])
 274 AM_CONDITIONAL([HAVE_LIBLTTNG_UST_CTL], [test "x$lttng_ust_ctl_found" = xyes])
 275 AC_CHECK_FUNCS([sched_getcpu sysconf sync_file_range])
 276
 277 # check for dlopen
 278 AC_CHECK_LIB([dl], [dlopen],
 279 [
 280         have_libdl=yes
 281 ],
 282 [
 283         #libdl not found, check for dlopen in libc.
 284         AC_CHECK_LIB([c], [dlopen],
 285         [
 286                 have_libc_dl=yes
 287         ],
 288         [
 289                 AC_MSG_ERROR([Cannot find dlopen in libdl nor libc. Use [LDFLAGS]=-Ldir to specify their location.])
 290         ])
 291 ])
 292 AM_CONDITIONAL([LTTNG_TOOLS_BUILD_WITH_LIBDL], [test "x$have_libdl" = "xyes"])
 293 AM_CONDITIONAL([LTTNG_TOOLS_BUILD_WITH_LIBC_DL], [test "x$have_libc_dl" = "xyes"])
 294
 295 # Check for fmemopen
 296 AC_CHECK_LIB([c], [fmemopen],
 297 [
 298         AC_DEFINE_UNQUOTED([LTTNG_HAVE_FMEMOPEN], 1, [Has fmemopen support.])
 299 ]
 300 )
 301
 302 # Check for open_memstream
 303 AC_CHECK_LIB([c], [open_memstream],
 304 [
 305         AC_DEFINE_UNQUOTED([LTTNG_HAVE_OPEN_MEMSTREAM], 1, [Has open_memstream support.])
 306 ]
 307 )
 308
 309 AC_ARG_ENABLE([git-version],
 310               [AC_HELP_STRING([--disable-git-version],
 311                               [Do not use the git version for the build])],
 312               [have_git_version=$enableval], [have_git_version=yes]
 313 )
 314
 315 AM_CONDITIONAL([LTTNG_TOOLS_BUILD_GIT_SOURCE],
 316         [test "x${have_git_version}" = "xyes"])
 317
 318 # For Python
 319 # SWIG version needed or newer:
 320 swig_version=2.0.0
 321
 322 AC_ARG_ENABLE([python-bindings],
 323               [AC_HELP_STRING([--enable-python-bindings],
 324                               [compile Python bindings])],
 325               [enable_python=yes], [enable_python=no])
 326
 327 AM_CONDITIONAL([USE_PYTHON], [test "x${enable_python:-yes}" = xyes])
 328
 329 if test "x${enable_python:-yes}" = xyes; then
 330   AX_PKG_SWIG($swig_version, [], [ AC_MSG_ERROR([SWIG $swig_version or newer is needed]) ])
 331   AM_PATH_PYTHON
 332
 333   AC_ARG_VAR([PYTHON_INCLUDE], [Include flags for python, bypassing python-config])
 334   AC_ARG_VAR([PYTHON_CONFIG], [Path to python-config])
 335   AS_IF([test -z "$PYTHON_INCLUDE"], [
 336     AS_IF([test -z "$PYTHON_CONFIG"], [
 337       AC_PATH_PROGS([PYTHON_CONFIG],
 338                     [python$PYTHON_VERSION-config python-config],
 339                     [no],
 340                     [`dirname $PYTHON`])
 341       AS_IF([test "$PYTHON_CONFIG" = no], [AC_MSG_ERROR([cannot find python-config for $PYTHON. Do you have python-dev installed?])])
 342     ])
 343     AC_MSG_CHECKING([python include flags])
 344     PYTHON_INCLUDE=`$PYTHON_CONFIG --includes`
 345     AC_MSG_RESULT([$PYTHON_INCLUDE])
 346   ])
 347
 348 else
 349     AC_MSG_NOTICE([You may configure with --enable-python-bindings ]dnl
 350 [if you want Python bindings.])
 351
 352 fi
 353
 354 # Epoll check. If not present, the build will fallback on poll() API
 355 AX_HAVE_EPOLL(
 356         [AX_CONFIG_FEATURE_ENABLE(epoll)],
 357         [AX_CONFIG_FEATURE_DISABLE(epoll)]
 358 )
 359 AX_CONFIG_FEATURE(
 360         [epoll], [This platform supports epoll(7)],
 361         [HAVE_EPOLL], [This platform supports epoll(7).],
 362         [enable_epoll="yes"], [enable_epoll="no"]
 363 )
 364 AM_CONDITIONAL([COMPAT_EPOLL], [ test "$enable_epoll" = "yes" ])
 365
 366 # Set compile flags to java include files if given. This is only used to
 367 # compile java agent tests.
 368 AC_ARG_WITH([java-jdk],
 369         [AS_HELP_STRING([--with-java-jdk=DIR],[use the Java JDK in DIR. Ex : $JAVA_HOME.])],
 370         [JAVA_JDK=$withval],
 371         [JAVA_JDK=""]
 372 )
 373 AM_CONDITIONAL([HAVE_JAVA_JDK], [test $JAVA_JDK], [Java JDK path])
 374 AC_SUBST([JAVA_JDK])
 375
 376 AS_IF([test $JAVA_JDK],[
 377         AS_IF([test -d $JAVA_JDK],
 378                 [
 379                         AC_MSG_RESULT([using Java includes in $JAVA_SDK])
 380                         SUBDIRS=`find $JAVA_JDK/include -type d`
 381                         CPPFLAGS+=" "
 382                         CPPFLAGS+=`for x in $SUBDIRS; do echo -n "-I$x "; done`
 383                         CPPFLAGS+=" "
 384         ],[AC_MSG_ERROR(Unable to find Java include files in $JAVA_JDK)]
 385         )
 386 ])
 387
 388 # Check for the UST agent jar file in the system. Hardcoded path is added here
 389 # since we have *no* idea where this could be installed. Note that this is only
 390 # used for agent testing.
 391 AC_MSG_CHECKING(Java UST agent jar file)
 392 java_agent_jar_path="${prefix}/share/java/liblttng-ust-agent.jar"
 393 if test -f $java_agent_jar_path; then
 394         build_java_agent=yes
 395         AC_MSG_RESULT(found)
 396 else
 397         build_java_agent=no
 398         AC_MSG_RESULT(not found)
 399 fi
 400 AM_CONDITIONAL([BUILD_JAVA_AGENT], [test "x$build_java_agent" = "xyes"])
 401 AC_SUBST([java_agent_jar_path])
 402
 403 # Check for log4j support on the system to know if we can build or not the
 404 # log4j tests.
 405 if test "x$build_java_agent" = "xyes"; then
 406         AC_MSG_CHECKING(Java agent support for log4j)
 407         AX_JAVA_OPTIONS
 408         AX_PROG_JAR
 409         AX_PROG_JAVA
 410         AX_PROG_JAVAC
 411
 412         # By default, use a commonly used classpath on the system to ease things up
 413         # for the Java testing in this directory.
 414         LOG4J_CLASSPATH="$java_agent_jar_path:$CLASSPATH:.:/usr/share/java/*"
 415         JAVAFLAGS="-cp $LOG4J_CLASSPATH"
 416         JAVACFLAGS="$JAVAFLAGS"
 417         AX_CHECK_CLASS(org.apache.log4j.Logger)
 418
 419         if test "x$ac_cv_class_org_apache_log4j_Logger" = "xno"; then
 420                 build_java_log4j_agent=no
 421         else
 422                 build_java_log4j_agent=yes
 423         fi
 424 fi
 425 AM_CONDITIONAL([BUILD_JAVA_LOG4J_AGENT], [test "x$build_java_log4j_agent" = "xyes"])
 426
 427 AC_SYS_LARGEFILE
 428 AC_PROG_CC
 429 LT_INIT
 430 AC_PROG_YACC
 431 AC_PROG_LEX
 432
 433 if test ! -f "$srcdir/src/lib/lttng-ctl/filter/filter-parser.h"; then
 434         if test x"$YACC" != "xbison -y"; then
 435                 AC_MSG_ERROR([[bison not found and is required when building from git.
 436                 Please install bison]])
 437         fi
 438         AC_PATH_PROG([BISON],[bison])
 439         AX_PROG_BISON_VERSION([2.4], [],[
 440                 AC_MSG_ERROR([[Bison >= 2.4 is required when building from git]])
 441         ])
 442 fi
 443
 444 if test ! -f "$srcdir/src/lib/lttng-ctl/filter/filter-lexer.c"; then
 445         if test x"$LEX" != "xflex"; then
 446                 AC_MSG_ERROR([[flex not found and is required when building from git.
 447                 Please install flex]])
 448         fi
 449         AC_PATH_PROG([FLEX],[flex])
 450         AX_PROG_FLEX_VERSION([2.5.35], [],[
 451                 AC_MSG_ERROR([[Flex >= 2.5.35 is required when building from git]])
 452         ])
 453 fi
 454
 455 CFLAGS="-Wall $CFLAGS -g -fno-strict-aliasing"
 456
 457 DEFAULT_INCLUDES="-I\$(top_srcdir) -I\$(top_builddir) -I\$(top_builddir)/src -I\$(top_builddir)/include -include config.h"
 458
 459 lttngincludedir="${includedir}/lttng"
 460
 461 AC_SUBST(lttngincludedir)
 462 AC_SUBST(DEFAULT_INCLUDES)
 463
 464 lttnglibexecdir="${libdir}/lttng/libexec"
 465 AC_SUBST(lttnglibexecdir)
 466
 467 AC_CONFIG_FILES([
 468         Makefile
 469         doc/Makefile
 470         doc/man/Makefile
 471         include/Makefile
 472         extras/Makefile
 473         extras/bindings/Makefile
 474         extras/bindings/swig/Makefile
 475         extras/bindings/swig/python/Makefile
 476         extras/core-handler/Makefile
 477         src/Makefile
 478         src/common/Makefile
 479         src/common/kernel-ctl/Makefile
 480         src/common/kernel-consumer/Makefile
 481         src/common/ust-consumer/Makefile
 482         src/common/hashtable/Makefile
 483         src/common/sessiond-comm/Makefile
 484         src/common/compat/Makefile
 485         src/common/relayd/Makefile
 486         src/common/testpoint/Makefile
 487         src/common/index/Makefile
 488         src/common/health/Makefile
 489         src/common/config/Makefile
 490         src/lib/Makefile
 491         src/lib/lttng-ctl/Makefile
 492         src/lib/lttng-ctl/filter/Makefile
 493         src/lib/lttng-ctl/lttng-ctl.pc
 494         src/bin/Makefile
 495         src/bin/lttng-consumerd/Makefile
 496         src/bin/lttng-sessiond/Makefile
 497         src/bin/lttng-relayd/Makefile
 498         src/bin/lttng/Makefile
 499         tests/Makefile
 500         tests/regression/Makefile
 501         tests/regression/kernel/Makefile
 502         tests/regression/tools/Makefile
 503         tests/regression/tools/streaming/Makefile
 504         tests/regression/tools/filtering/Makefile
 505         tests/regression/tools/health/Makefile
 506         tests/regression/tools/tracefile-limits/Makefile
 507         tests/regression/tools/snapshots/Makefile
 508         tests/regression/tools/live/Makefile
 509         tests/regression/tools/exclusion/Makefile
 510         tests/regression/tools/save-load/Makefile
 511         tests/regression/tools/mi/Makefile
 512         tests/regression/ust/Makefile
 513         tests/regression/ust/nprocesses/Makefile
 514         tests/regression/ust/high-throughput/Makefile
 515         tests/regression/ust/low-throughput/Makefile
 516         tests/regression/ust/before-after/Makefile
 517         tests/regression/ust/buffers-pid/Makefile
 518         tests/regression/ust/periodical-metadata-flush/Makefile
 519         tests/regression/ust/multi-session/Makefile
 520         tests/regression/ust/overlap/Makefile
 521         tests/regression/ust/overlap/demo/Makefile
 522         tests/regression/ust/linking/Makefile
 523         tests/regression/ust/daemon/Makefile
 524         tests/regression/ust/exit-fast/Makefile
 525         tests/regression/ust/fork/Makefile
 526         tests/regression/ust/libc-wrapper/Makefile
 527         tests/regression/ust/java-jul/Makefile
 528         tests/regression/ust/java-log4j/Makefile
 529         tests/stress/Makefile
 530         tests/unit/Makefile
 531         tests/unit/ini_config/Makefile
 532         tests/utils/Makefile
 533         tests/utils/tap/Makefile
 534         tests/utils/testapp/Makefile
 535         tests/utils/testapp/gen-ust-events/Makefile
 536         tests/utils/testapp/gen-ust-nevents/Makefile
 537         tests/utils/testapp/gen-ust-tracef/Makefile
 538 ])
 539
 540 AC_OUTPUT
 541
 542 #
 543 # Mini-report on what will be built
 544 #
 545 AS_ECHO()
 546
 547 AS_ECHO("Version name: $version_name")
 548 AS_ECHO("$version_description")
 549
 550 AS_ECHO()
 551
 552 # Target architecture we're building for
 553 target_arch=$host_cpu
 554 [
 555 for f in $CFLAGS; do
 556         if test $f = "-m32"; then
 557                         target_arch="32-bit"
 558         elif test $f = "-m64"; then
 559                         target_arch="64-bit"
 560         fi
 561 done
 562 ]
 563 AS_ECHO_N("Target architecture: ")
 564 AS_ECHO($target_arch)
 565
 566 # kmod enabled/disabled
 567 AS_ECHO_N("libkmod support: ")
 568 AS_IF([test "x$kmod_found" = "xyes"],[
 569         AS_ECHO("Enabled")
 570 ],[
 571         AS_ECHO("Disabled")
 572 ])
 573
 574 # LTTng-UST enabled/disabled
 575 AS_ECHO_N("Lttng-UST support: ")
 576 AS_IF([test "x$lttng_ust_support" = "xyes"],[
 577         AS_ECHO("Enabled")
 578 ],[
 579         AS_ECHO("Disabled")
 580 ])
 581
 582 #Python binding enabled/disabled
 583 AS_ECHO_N("Python binding: ")
 584 AS_IF([test "x${enable_python:-yes}" = xyes], [
 585         AS_ECHO("Enabled")
 586 ],[
 587         AS_ECHO("Disabled")
 588 ])
 589
 590 # Do we build only the consumerd, or everything
 591 AS_IF([test "x$consumerd_only" = "xyes"],[
 592         AS_ECHO("Only the consumerd daemon will be built.")
 593 ],[
 594         AS_ECHO("All binaries will be built.")
 595 ])
 596
 597 # Print the bindir and libdir this `make install' will install into.
 598 AS_ECHO()
 599 AS_ECHO_N("Binaries will be installed in:  ")
 600 AS_ECHO("`eval eval echo $bindir`")
 601 AS_ECHO_N("Libraries will be installed in: ")
 602 AS_ECHO("`eval eval echo $libdir`")
 603
 604 # If we build the sessiond, print the paths it will use
 605 AS_IF([test "x$consumerd_only" = "xno"],[
 606         AS_ECHO()
 607         AS_ECHO_N("The lttng command will look for the lttng-sessiond executable at: ")
 608         AS_IF([test "$SESSIOND_BIN" = ""],[
 609                 AS_ECHO_N("`eval eval echo $bindir`")
 610                 AS_ECHO("/lttng-sessiond")
 611         ],[
 612                 AS_ECHO("$SESSIOND_BIN")
 613         ])
 614
 615         AS_ECHO()
 616         AS_ECHO("The sessiond daemon will look in the following directories: ")
 617         AS_ECHO_N("32-bit consumerd executable at: ")
 618         AS_IF([test "$CONSUMERD32_BIN" = ""],[
 619                 AS_ECHO_N("`eval eval echo $lttnglibexecdir`")
 620                 AS_ECHO("/lttng-consumerd")
 621         ],[
 622                 AS_ECHO("$CONSUMERD32_BIN")
 623         ])
 624
 625         AS_ECHO_N("32-bit consumer libraries in:   ")
 626         AS_IF([test "$CONSUMERD32_LIBDIR" = ""],[
 627                 AS_ECHO("`eval eval echo $libdir`")
 628         ],[
 629                 AS_ECHO("$CONSUMERD32_LIBDIR")
 630         ])
 631
 632         AS_ECHO_N("64-bit consumerd executable at: ")
 633         AS_IF([test "$CONSUMERD64_BIN" = ""],[
 634                 AS_ECHO_N("`eval eval echo $lttnglibexecdir`")
 635                 AS_ECHO("/lttng-consumerd")
 636         ],[
 637                 AS_ECHO("$CONSUMERD64_BIN")
 638         ])
 639
 640         AS_ECHO_N("64-bit consumer libraries in:   ")
 641         AS_IF([test "$CONSUMERD64_LIBDIR" = ""],[
 642                 AS_ECHO("`eval eval echo $libdir`")
 643         ],[
 644                 AS_ECHO("$CONSUMERD64_LIBDIR")
 645         ])
 646 ])
 647
 648 AS_ECHO()
 649